任務舉例

在使用了 批量搜尋並複製/剪下檔案的批處理程式 中的批處理程式之後，往往還需要和原有的關鍵字比對，知道搜尋到了多少檔案。這就需要一個工具，能夠批量檢測一批關鍵字是否存在於一堆檔案裡。比如有如下一些檔案：

AA1

BB2

DD3

BBC1

EE2

Abb

希望從中批量搜尋檔名包含

AA

BB

CC

的檔案

希望得到的結果有：AA1，BB2，BBC1，Abb

有點類似Excel裡的vlookup命令，所不同的是用批處理程式可以直接在檔案目錄下操作，而不需要匯出檔名的列表。

實現方法

與批量搜尋類似，實現這個任務，仍然需要強大的for命令，並且結合find命令，就能完成這一任務。同時也能檢測資料夾是否存在。最後將找到和未找到的關鍵詞分別輸出到兩個文字檔案下。

首先把關鍵字儲存在名叫“list.txt”的文字檔案裡，每個關鍵字佔一行。注意不能有空格、空行、空回車。例如：

#list.txt 檔案內容

AA

BB

CC

然後把下面的程式碼儲存成以*.bat為副檔名的批處理檔案：

::Batch search & check
::by lfhacks.com,Apr 1,2009

@echo off
setlocal enabledelayedexpansion
color 1E
echo 本程式檢查當前目錄下是否存在給定關鍵字的檔案（夾）
echo.
echo by www.lfhacks.com
echo.
echo 例如，檢查缺少的檔名
if not exist list.txt (echo.
echo 請先將關鍵字列表儲存為list.txt...
pause > NUL
exit
)
echo.
echo 要檢查檔案還是目錄？
echo.
set /p opt=檔案(f) or 目錄(d):
if %opt% NEQ f if %opt% NEQ d (
echo 迴應錯誤。
pause >NUL
exit
)
if %opt%==d (
dir /AD /B * >tempp
)
if %opt%==f (
set /p ext=指定副檔名（不包括"."，不指定請輸入*）:
dir /A-D /B *.!ext! >tempp
)

if exist result.txt del result.txt 
set count=0
for /f "tokens=*" %%i in (list.txt) do (
find "%%i" tempp >NUL
echo 檢查 %%i... 
if !errorlevel! EQU 1 (
echo --- Not Found ---
echo %%i >> Not_found.txt
set /a count+=1
)ELSE (
echo %%i >> Found.txt
)
)
del tempp
echo.
if %count% NEQ 0 echo 任務完成！共有 %count% 個關鍵字不存在，結果已儲存到Not_found.txt
if %count% EQU 0 echo 列表中的關鍵字都存在
echo 存在的關鍵字儲存到Found.txt

pause >NUL
exit

更多關於Windows效率批處理程式請檢視下面的相關連結