sql server 資料庫中某張表（Person）的資料資訊是：

現在有需求是，將地址資訊顯示形式改成4列 ，即小區名，單元號，樓房號，房間號 分成4列進行顯示

介紹兩種方案：

第一種：最簡單的辦法就是呼叫sql server中自帶函式PARSENAME來進行拆分，但是注意：最多隻能拆分成4個欄位。

針對這個例子的實現：parsename預設是根據'.'進行拆分的，所以首先要做的是將欄位中的‘-’替換成'.'

1 SELECT Address, PARSENAME(REPLACE([Address],'-','.'),4) as 小區名,
2 --如果欄位的內容是 4單元-12幢-203 那麼此時小區名欄位的資訊就是NULL
3 PARSENAME(REPLACE([Address],'-','.'),3) as 單元號,
4 PARSENAME(REPLACE([Address],'-','.'),2) as 樓房號,
5 PARSENAME(REPLACE([Address],'-','.'),1) as 房間號 
6 FROM Person

PARSENAME詳解：

PARSENAME ( 'object_name
 
' , object_piece ) 

'object_name'

要檢索其指定部分的物件的名稱。object_name的資料型別為sysname。此引數是可選的限定物件名稱。如果物件名稱的所有部分都是限定的，則此名稱可包含四部分：伺服器名稱、資料庫名稱、所有者名稱以及物件名稱。

object_piece

要返回的物件部分。object_piece的資料型別為int值，可以為下列值：

1 = 物件名稱

2 = 架構名稱

3 = 資料庫名稱

4 = 伺服器名稱

PARSENAME 函式不指示指定名稱的物件是否存在。PARSENAME 僅返回指定物件名稱的指定部分。

第二種方案：思路：寫一個函式 根據特定的分割符號利用SUBSTRING和CHARINDEX將欄位進行擷取拆分，

--這個函式  返回的是一個表

ALTER FUNCTION [dbo].[f_splitlianxi]
(
@str NVARCHAR(500),--要分割的字串
@fengefu NVARCHAR(20)--進行分割的符號
)RETURNS @table TABLE(id INT,val NVARCHAR(50))
AS
BEGIN 
    DECLARE @index INT,@startsplit INT,@id INT --@index分隔符所在的位置的下標 @startsplit 每次分割開始的位置
    SELECT @index=CHARINDEX(@fengefu,@str),@startsplit=1,@id=1
    WHILE @index>0
    BEGIN
        IF @id>1  --第一次迴圈之後 都執行這個方法體中的程式碼
        BEGIN 
            SELECT @startsplit=@index+LEN(@fengefu) --分割開始位置等於 之前的字元下標位置+字元本身的長度
            SELECT @index=CHARINDEX(@fengefu,@str,@startsplit)
            
        END 
        IF @index>0   --第一次迴圈 擷取位置從@startsplit=1開始  
            BEGIN 
                INSERT INTO @table VALUES (@id,SUBSTRING(@str,@startsplit,@index-@startsplit)) --要擷取的字串   開始位置  要擷取的長度
            END 
        ELSE 
        BEGIN   --最後一次迴圈  此時由於匹配不到分割字元 @index=0 擷取剩餘的字串
            INSERT INTO @table VALUES (@id,SUBSTRING(@str,@startsplit,LEN(@str)-@startsplit+1))
        END 
        SELECT @id=@id+1
    END
    RETURN 
END

呼叫規則：

SELECT [Address],(SELECT val FROM [f_splitlianxi]([Address],'-') WHERE id=1 ) AS 小區名 ,
(SELECT val FROM [f_splitlianxi]([Address],'-') WHERE id=2 )AS 單元號,
(SELECT val FROM [f_splitlianxi]([Address],'-') WHERE id=3 )AS 樓房號,
(SELECT val FROM [f_splitlianxi]([Address],'-') WHERE id=4 )AS 房間號
FROM Person

PS：還有一種更加粗暴的寫法 就是不用另外建立函式 直接select 的時候 就通過擷取字串，來附加新的列

例如：有一個需求是 T_Person表中有欄位Birth 裡面的資訊在輸入的時候 形式不符合規定

ID	Birth
1	1900/2/12
2	1898/2/3
3
4	NULL

現在要求統一形式成：1987-05-03的形式：

下面是具體過程：

UPDATE dbo.T_Person SET Birth=
SUBSTRING(Birth,1,CHARINDEX('/',Birth)-1) --得到年份
+'-'+
CASE WHEN SUBSTRING(Birth,CHARINDEX('/',Birth)+1,CHARINDEX('/',Birth,CHARINDEX('/',Birth)+1)-(CHARINDEX('/',Birth)+1))<10 
--擷取月份與10進行比較 
THEN 
'0'+SUBSTRING(Birth,CHARINDEX('/',Birth)+1,CHARINDEX('/',Birth,CHARINDEX('/',Birth)+1)-(CHARINDEX('/',Birth)+1))
--小於10的時候 在月份前面追加個0 然後返回
ELSE 
SUBSTRING(Birth,CHARINDEX('/',Birth)+1,CHARINDEX('/',Birth,CHARINDEX('/',Birth)+1)-(CHARINDEX('/',Birth)+1))
--大於10的時候 擷取月份返回
END
--得到月份
+'-'
+CASE WHEN SUBSTRING(Birth,CHARINDEX('/',Birth,CHARINDEX('/',Birth)+1)+1,LEN(Birth)-CHARINDEX('/',Birth,CHARINDEX('/',Birth)+1))<10
--擷取日與10進行比較
THEN 
'0'+SUBSTRING(Birth,CHARINDEX('/',Birth,CHARINDEX('/',Birth)+1)+1,LEN(Birth)-CHARINDEX('/',Birth,CHARINDEX('/',Birth)+1))
--小於10的時候 在日前面追加個0 然後返回
ELSE
SUBSTRING(Birth,CHARINDEX('/',Birth,CHARINDEX('/',Birth)+1)+1,LEN(Birth)-CHARINDEX('/',Birth,CHARINDEX('/',Birth)+1))
--大於10的時候 擷取日返回
END
--得到日
WHERE CHARINDEX('/',Birth)>0 --防止沒有/的資訊欄位 在進行字串擷取的時候報錯 沒有'/'的返回0 但是NULL 得到的值是NULL

--註釋
SELECT CHARINDEX('/','123') --結果是 0
SELECT CHARINDEX('/',NULL) --結果是 NULL

執行之後的結果是：

ID	Birth
1	1900-02-12
2	1898-02-03
3
4	NULL