從零開始的DIY智慧家居 - 基於 ESP32 的智慧光照感測器
前言
上週出差有點急,結果家裡燈沒關,開了整整一週的時間(T▽T),整個人都裂開了,準備做一個能夠遠端控制燈的東西,讓我以後出差能遠端把家裡燈關了。
第一步就是做這期的主題 - 智慧光照感測器,因為我逛了一圈發現常見的能遠端控燈的開關都只能單純的開關燈的狀態,並不知道當前燈的狀態,小米智慧燈泡又只能用他們自己的生態,我用不了。
於是我準備使用一個智慧光照感測器來感知家裡的燈有沒有關。
硬體選擇
板子依然用的安信可的 ESP32S ,別問,問就是便宜好用。STM完蛋去吧。
感測器用的 HB1750VI模組 ,這個模組使用 I2C 控制和通訊(連線開發板:SDA->P21,SCL->P22)
伺服器用的翼輝的 Spirit 1 邊緣計算機
Spirit 1 這就是一個前後端部署在一起的伺服器,然後我們手機和電腦就相當於一個遠端桌面。
程式碼解析
獲取程式碼
為了方便講解邏輯,我會打亂程式碼的順序可能還會進行裁剪,要是想直接拿程式碼跑的朋友可以直接去 靈感桌面的祕密寶庫 獲取程式碼,或者直接 clone:
https://gitee.com/inspiration-desktop/DEV-lib-arduino.git
下載或者 clone程式碼後這次用到的是這個三個資料夾:
cjson:我移植的 cjson 庫,就是標準的 cjson 庫,放到 arduino 安裝目錄下的 libraries 資料夾裡,百度一下 cjson 的函式使用就行了。
libsddc:是我移植自官方的SDDC庫和自己寫的 SDK,也是放入 libraries 資料夾裡就行。裡面是 SDDC 協議的處理函式,我們不用管。
demo 資料夾裡面就是我們各種感測器的 demo 程式碼了:
紅圈的 MLX90614_sddc_demo 資料夾裡面就是我們程式碼,點進去就能看見 MLX90614_sddc_sdk_demo.ino 檔案,雙擊檔案會自動啟動 arduino-IDE 開啟程式碼。在工具 -> 埠 選擇對應的 COM 口然後點選上傳就可以把程式碼燒錄到板子裡:
具體 arduino 使用教程可以看我之前的文章 arduino開發指導 和 手把手帶你 arduino 開發:基於ESP32S 的第一個應用-紅外測溫槍(帶引腳圖)
裝置控制命令:
通過 Spirit 1 的應用程式或者嗅探器 向感測器裝置傳送的命令:
{
"method": "get", // 這個命令可以從感測器主動獲取一個光照強度資料
"obj": ["LUX"]
}
裝置和協議初始化流程:
基於官方 demo 寫的不需要做什麼修改,主要是裝置初始化,管腳配置,和協議初始化部分。
/*
* 初始化感測器
*/
void sensor_init()
{
// 建立感測器任務,週期性獲取光照感測器的資料併發送給 EdgerOS
xTaskCreate(periodic_sensor_task, "periodic_sensor_task", ESP_TASK_STACK_SIZE, NULL, ESP_TASK_PRIO, NULL);
}
void setup() {
byte mac[6];
Serial.begin(115200);
Serial.setDebugOutput(true);
Serial.println();
// 初始化感測器
sensor_init();
// 清除一下按鍵狀態機的狀態
button.reset();
// 建立按鍵掃描執行緒,長按 IO0 按鍵,鬆開後 ESP32 將會進入 SmartConfig 模式
sddc_printf("長按按鍵進入 Smartconfig...\n");
button.attachLongPressStop(esp_io0_key_task);
xTaskCreate(esp_tick_task, "button_tick", ESP_TASK_STACK_SIZE, NULL, ESP_TASK_PRIO, NULL);
// 啟動 WiFi 並且連線網路
WiFi.begin(ssid, password);
while (WiFi.status() != WL_CONNECTED)
{
delay(500);
Serial.print(".");
}
// 獲取並列印 IP 地址
Serial.println("");
Serial.println("WiFi connected");
Serial.print("'ip :");
Serial.print(WiFi.localIP());
Serial.println("' to connect");
// sddc協議初始化
sddc_lib_main(&sys_cfg);
// 獲取並列印網絡卡 mac 地址
WiFi.macAddress(mac);
sddc_printf("MAC addr: %02x:%02x:%02x:%02x:%02x:%02x\n",
mac[5], mac[4], mac[3], mac[2], mac[1], mac[0]);
// 使用網絡卡 mac 地址設定裝置唯一標識 UID
sddc_set_uid(G_sddc, mac);
}
void loop() {
// 執行 SDDC 協議迴圈
while (1)
{
sddc_printf("SDDC running...\n");
sddc_run(G_sddc);
sddc_printf("SDDC quit!\n");
}
// 銷燬 SDDC 協議
sddc_destroy(G_sddc);
}
配置裝置資訊
這部分程式碼可以配置 WiFi 名字和 WiFi 密碼,要使用的引腳,並且配置裝置在 Spirit 1 上顯示的資訊:
#define ADDR 0b0100011
#define SDDC_CFG_PORT 680U // SDDC 協議使用的埠號
#define PIN_INPUT 0 // 選擇 IO0 進行控制
#define ESP_TASK_STACK_SIZE 4096
#define ESP_TASK_PRIO 25
static const char* ssid = "EOS-000045"; // WiFi 名
static const char* password = "1234567890"; // WiFi 密碼
OneButton button(PIN_INPUT, true);
/*
* 當前裝置的資訊定義
*/
DEV_INFO dev_info = {
.name = "光照感測器",
.type = "sensor",
.excl = SDDC_FALSE,
.desc = "ESP-32S",
.model = "1",
.vendor = "靈感桌面",
};
/*
* 系統註冊物件匯聚
*/
SDDC_CONFIG_INFO sys_cfg = {
.token = "1234567890", // 裝置密碼
.devinfo = &dev_info,
.io_dev_reg = io_dev,
.io_dev_reg_num = ARRAY_SIZE(io_dev),
.num_dev_reg = num_dev,
.num_dev_reg_num = ARRAY_SIZE(num_dev),
.state_get_reg = dev_state_get_reg,
.state_get_reg_num = ARRAY_SIZE(dev_state_get_reg),
.dis_dev_reg = dis_dev,
.dis_dev_num = ARRAY_SIZE(dis_dev),
};
回撥函式註冊
這是收到命令後回撥函式註冊的位置,在這裡註冊的函式才能被 SDK 正確的呼叫,執行正確的動作。
具體 SDK 的解析可以參考 同人逼死官方系列!基於sddc 協議的SDK框架 sddc_sdk_lib 解析 和 同人逼死官方系列!從 DDC 嗅探器到 sddc_sdk_lib 的資料解析
/*
* 數字量裝置物件函式與處理方法註冊
*/
NUM_DEV_REGINFO num_dev[] = {
};
/*
* 顯示裝置物件函式與處理方法註冊
*/
DIS_DEV_REGINFO dis_dev[] = {
};
/*
* IO裝置物件設定函式與處理方法註冊
*/
IO_DEV_REGINFO io_dev[] = {
};
/*
* 系統物件狀態獲取註冊
*/
DEV_STATE_GET dev_state_get_reg[] = {
{"LUX", DEV_NUM_TYPE, single_get_sensor},
};
資料獲取與傳送流程
這裡是我們自己編寫的處理流程 ,可以根據你的需求自己更改,收到 set 或者 get 後根據前面的註冊的函式,進入對應的處理函式。
裝置會檢測感測器輸出,然後根據設定的上報間隔定時上報水濁度資料,還可以主動傳送 get 命令主動查詢感測器當前資料:
static int esp_sensor_task()
{
int val = 0;
// 獲取光照資料
Wire.beginTransmission(ADDR);
Wire.write(0b00000111);
Wire.endTransmission();
Wire.beginTransmission(ADDR);
Wire.write(0b00100000);
Wire.endTransmission();
// typical read delay 120ms
delay(120);
Wire.requestFrom(ADDR, 2); // 2byte every time
for (val = 0; Wire.available() >= 1; )
{
char c = Wire.read();
val = (val << 8) + (c & 0xFF);
}
val = val / 1.2;
return val;
}
/*
* 單次獲取資料
*/
sddc_bool_t single_get_sensor(char *objvalue, int value_len)
{
int value = esp_sensor_task();
snprintf(objvalue, value_len, "%d", value);
return SDDC_TRUE;
}
程式碼寫完之後燒錄進去就完事了,和之前完全一樣,點一下儲存,然後上傳OK,具體可以看之前的文件,我就懶得再寫一遍啦 (/ω\)
總結
智慧光照感測器完成!現在能通過感知光照感知白天,黑夜,是否開關燈了!之後準備買一個隨意貼來改造,讓我出差也能遠端關燈關裝置!
本文僅個人學習使用,如有錯誤,歡迎指正, ( ੭ ˙ᗜ˙ )੭謝謝老闆!