2. 程式人生 > 其它 >實驗 4 8086標誌暫存器及中斷

實驗 4 8086標誌暫存器及中斷

阿新 • • 發佈：2021-12-13

四、實驗結論

1. 實驗任務 1

  • 驗證性實驗：有些彙編指令會影響到標誌暫存器中的一個或多個狀態標誌位。
    在 debug 環境中，分別實踐、觀察：

    溢位 OV (overflow，OF ＝ 1)
    無溢位 NV (no overflow，OF ＝ 0)

    減量 DN (direction down，DF ＝ 1)
    增量 UP (direction up，DF ＝ 0)

    允許中斷 EI (enable interrupt，IF ＝ 1)
    進制中斷 DI (disable interrupt，IF ＝ 0)

    負 NG (negative，SF ＝ 1)
    正 PL (plus，SF ＝ 0)

    零 ZR (zero，ZF ＝ 1)
    非零 NZ (no zero，ZF ＝ 0)

    輔助進位 AC (auxiliary carry，AF ＝ 1)
    無輔助進位 NA (no auxiliary carry，AF ＝ 0)

    偶校驗 PE (even parity，PF ＝ 1)
    奇校驗 PO (odd parity，PF ＝ 0)

    進位 CY (carry，CF ＝ 1)
    無進位 NC (no carry，CF ＝ 0

    • add 指令對標誌暫存器中的零標誌位 ZF(Zero Flag)、進位標誌位 CF(Carry Flag) 是否有影響？

    • inc 指令對標誌暫存器中的零標誌位 ZF(Zero Flag)、進位標誌位 CF(Carry Flag) 是否有影響？

    結論：add 和 inc 指令均對 ZF 位有影響，但 inc 不改變進位標誌位 CF，而 add 改變進位標誌位 CF，此外兩指令對 8bit 加法運算第三位向第四位做加法時產生半進位標誌 AC 均有影響。

  • task1.asm 原始碼

    assume cs:code, ds:data

data segment
  x dw 1020h, 2240h, 9522h, 5060h, 3359h, 6652h, 2530h, 7031h
  y dw 3210h, 5510h, 6066h, 5121h, 8801h, 6210h, 7119h, 3912h
data ends
code segment
start:
    mov ax, data
    mov ds, ax
    mov si, offset x
    mov di, offset y
    call add128

    mov ah, 4ch
    int 21h

add128:
    push ax
    push cx
    push si
    push di

    sub ax, ax

    mov cx, 8
s:  mov ax, [si]
    adc ax, [di]
    mov [si], ax

    inc si
    inc si
    inc di
    inc di
    loop s

    pop di
    pop si
    pop cx
    pop ax
    ret
code ends
end start

  • 回答問題

    1. line31~line34 的 4 條 inc 指令，能否替換成如下程式碼？你的結論的依據/理由是什麼？

      add si, 2
add di, 2

      不能，此處為 128bit 加法，inc 不改變進位標誌位 CF，而 add 改變進位標誌位 CF，若使用 add 則可能丟失進位資訊。

    2. 在 debug 中除錯，觀察資料段中做 128 位加之前和加之後，資料段的值的變化。給出除錯觀察截圖。

2. 實驗任務 2

  • 程式 task2.asm 原始碼

    assume cs:code, ds:data
data segment
        str db 80 dup(?)
data ends

code segment
start:  
        mov ax, data
        mov ds, ax
        mov si, 0
s1:        
        mov ah, 1
        int 21h
        mov [si], al
        cmp al, '#'
        je next
        inc si
        jmp s1
next:
        mov ah, 2
        mov dl, 0ah
        int 21h
        
        mov cx, si
        mov si, 0
s2:     mov ah, 2
        mov dl, [si]
        int 21h
        inc si
        loop s2

        mov ah, 4ch
        int 21h
code ends
end start

  • 執行測試截圖

  • 回答問題
    執行程式，從鍵盤上輸入一串字元，以#結束（比如，輸入 George Orwell, 1984#)，觀察結果。結合執行結果，理解程式碼並回答問題：

    1. 彙編指令程式碼 line11-18，實現的功能是？
      判斷輸入字元是否等於 #，若不等於存入 data 段， 使用 si 計數，並繼續讀入；若等於則跳轉至 next。
    2. 彙編指令程式碼 line20-22，實現的功能是？
      ASCII 碼中 0ah 為換行符，列印換行符使得輸出字串在下一行開始顯示。
    3. 彙編指令程式碼 line24-30，實現的功能是？
      將讀入字串長度寫入 cx 使用 loop 迴圈列印字串。

3. 實驗任務 3

編寫8086彙編源程式task3.asm，在螢幕上以十進位制形式輸出data段中這一組連續的資料，資料和資料之間以空格間隔。
要求：

  • 編寫子程式printNumber
    功能：以十進位制形式輸出一個任意位數的整數（整數範圍0 ~ 65535）
    入口引數：暫存器ax（待輸出的資料 --> ax）
    出口引數：無
  • 編寫子程式printSpace
    功能：列印一個空格
    入口引數：無
    出口引數：無

在主體程式碼中，綜合應用定址方式和迴圈，呼叫printNumber和printSpace, 實現題目要求。

  • task3.asm原始碼
assume cs:code, ds:data

data segment
    x dw 91, 792, 8536, 65521, 2021
    len equ $ - x
data ends

code segment

; print number in ax (0 <= [ax] <= 65535) to console
; param     :  ax
; return    : none
printNumber:
    push bx
    push cx
    push dx

    mov cx, 0
s1: 
    mov dx, 0
    mov bx, 10
    div bx
    push dx
    inc cx
    cmp ax, 0
    jne s1

s2:
    pop dx
    add dx, 30h
    mov ah, 2
    int 21h
    loop s2

    pop dx
    pop cx
    pop bx
    ret

; print a space to console
; param     : none
; return    : none
printSpace:
    push ax
    push dx

    mov dl, 20h
    mov ah, 02h
    int 21h
    
    pop dx
    pop ax
    ret

main: 
    mov ax, data
    mov ds, ax

    mov cx, len
    mov di, offset x
s:  mov ax, [di]
    call printNumber
    call printSpace
    add di, 2
    sub cx, 1
    loop s

    mov ax, 4c00h
    int 21h

code ends

end main
  • 執行測試截圖

4. 實驗任務 4

針對8086CPU，已知邏輯段定義如下：

data segment
  str db "assembly language, it's not difficult but tedious"
  len equ $ - str
data ends

編寫8086彙編源程式task4.asm，將data段中字串裡的小寫字元轉換成大寫。
要求：

  • 編寫子程式strupr
    功能：將包含任意字元的字串中的小寫字母變成大寫
    入口引數:
    • (ds:si ) 字串首地址的段地址和偏移地址分別送至ds和si
    • (cx) 字串的長度
      出口引數：無

在主體程式碼中，設定入口引數，呼叫strupr, 實現題目要求。

  • task4.asm原始碼
    assume cs:code, ds:data

data segment
    string db "assembly language, it's not difficult but tedious"
    len equ $ - string
data ends

code segment

; change lowercase letter to uppercase letter in string
; param: 
;   (ds:[si]): string ptr 
;   cx: string length
; ret: none
strupr:
s1:
    and byte ptr ds:[si], 11011111b 
    inc si
    loop s1
    ret


main: 
    mov ax, data
    mov ds, ax

    mov si, offset string
    mov cx, len
    call strupr

    mov ax, 4c00h
    int 21h

code ends

end main
  • 在debug中除錯截圖（ call strupr 呼叫之前，資料段的值，以及，呼叫之後，資料段的值）

5. 實驗任務 5

  • task5.asm原始碼
    assume cs:code, ds:data

data segment
    str1 db "yes", '$'
    str2 db "no", '$'
data ends

code segment
start:
    mov ax, data
    mov ds, ax

    mov ah, 1
    int 21h

    mov ah, 2
    mov bh, 0
    mov dh, 24
    mov dl, 70
    int 10h

    cmp al, '7'
    je s1
    mov ah, 9
    mov dx, offset str2
    int 21h

    jmp over

s1: mov ah, 9
    mov dx, offset str1
    int 21h
over:  
    mov ah, 4ch
    int 21h
code ends
end start
  • 程式執行測試截圖（輸入7，以及輸入其他字元，執行結果截圖）
  • 程式的功能是？
    輸入一個字元並判斷輸入的字元是否為 7，若是則呼叫 21h 中斷的第 9 號程式，輸出 yes 否則輸出 no;

6. 實驗任務 6

  • 通過此項實現任務，你對中斷、軟中斷實現機制的理解
    • task6-1.asm 將中斷處理程式寫入記憶體，起始地址 0:200
    • 將中斷處理程式起始地址寫入中斷向量表
    • 當程式產生 42(2ah) 中斷時訪問中斷向量表中儲存的地址，呼叫中斷處理程式
    • iret 指令將 IP CS PSW 依次彈出，恢復程式的執行
  • 自己選一個未被使用的中斷碼，實現一箇中斷例程，並呼叫測試。給出原始碼和執行測試截圖。(選做*)
    assume cs:code

code segment

; print date to console
int43:

    jmp short int43_start

; print number in ax (0 <= [ax] <= 65535) to console
; param     :  ax
; return    : none
printNumber:
    push bx
    push cx
    push dx

    mov cx, 0
s1: 
    mov dx, 0
    mov bx, 10
    div bx
    push dx
    inc cx
    cmp ax, 0
    jne s1

s2:
    pop dx
    add dx, 30h
    mov ah, 2
    int 21h
    loop s2

    pop dx
    pop cx
    pop bx
    ret

; print a space to console
; param     : none
; return    : none
printSpace:
    push ax
    push dx

    mov dl, 20h
    mov ah, 02h
    int 21h

    pop dx
    pop ax
    ret

int43_start:
    push ax

    mov ah, 2ah
    int 21h
    mov ax, cx
    call printNumber
    call printSpace
    mov al, dh
    mov ah, 0
    call printNumber
    call printSpace
    mov al, dl
    mov ah, 0
    call printNumber
    call printSpace

    pop ax
    iret

int43_end:
    nop

main:
    ; 43 interrupt routine install code
    mov ax, cs
    mov ds, ax
    mov si, offset int43  ; set ds:si

    mov ax, 0
    mov es, ax
    mov di, 200h        ; set es:di

    ; set IVT(Interrupt Vector Table)
    mov ax, 0
    mov es, ax
    mov word ptr es:[43*4], 200h
    mov word ptr es:[43*4+2], 0

    mov cx, offset int43_end - offset int43
    cld
    rep movsb

    mov ax, 4c00h
    int 21h

code ends

end main
  • 如選做，請說明你使用的中斷碼，並描述你實現的這個中斷例程的功能。
    • 中斷碼：43(2bh)
    • 功能：將日期列印至控制檯

相關推薦

實驗4 8086標誌暫存器及中斷

實驗4 8086標誌暫存器及中斷 實驗任務1 任務點1 驗證add對ZF和CF的影響 可以看到對ZF和CF都造成了影響

小白都能看懂的實驗4 8086標誌暫存器及中斷

我覺得這應該是本班最詳細的報告, 除了沒有書那麼面面俱到 實驗四 8086標誌暫存器及中斷

實驗 4 8086標誌暫存器及中斷

四、實驗結論 1. 實驗任務 1 驗證性實驗：有些彙編指令會影響到標誌暫存器中的一個或多個狀態標誌位。

實驗4 8086標誌暫存器及中斷

實驗任務1 task4_1.asm原始碼： assume cs:code, ds:data data segment x dw 1020h, 2240h, 9522h, 5060h, 3359h, 6652h, 2530h, 7031h

實驗四 8086標誌暫存器及中斷

實驗任務1 （1） 答:對ZF和CF都有影響。 （2） 答:對ZF有影響，對CF無影響。 assume cs:code, ds:data

【實驗四】8086標誌暫存器及中斷

目錄任務一任務二任務三任務四實驗五任務六 任務一 驗證性實驗：有些彙編指令會影響到標誌暫存器中的一個或多個狀態標誌位。

8086組合語言：標誌暫存器的各個標誌位的詳細介紹

技術標籤：# 8086組合語言8086組合語言標誌暫存器 一、基本介紹： CPU的內部的暫存器中，有一類特殊的暫存器（對於不同的處理機，其個數和結構都可能不同）；它具有以下三種作用！

組合語言裡面繞不開的狀態標誌暫存器和轉移指令

技術標籤：程式語言 首先我們知道8088/8086 CPU的內部共有14個16位暫存器。 按其功能又可分為三大類：通用暫存器，段暫存器，控制暫存器。

[彙編]《組合語言》第11章 標誌暫存器

王爽《組合語言》第四版 超級筆記 目錄王爽《組合語言》第四版 超級筆記第11章 標誌暫存器11.1 ZF標誌、PF標誌、SF標誌11.2 CF標誌、OF標誌11.3 adc指令、sbb指令、cmp指令11.4 檢測比較結果的條件轉移指令、DF標誌

組合語言 第十一章 標誌暫存器

標誌暫存器 flag 標誌暫存器只有一個，16位，有9個標誌位，除第1位為1外，剩餘6個位置預設為0，未被使用。

標誌暫存器

EFLAGS暫存器 進位標誌CF(Carry Flag) 如果運算的最高位產生了一個進位或借位，那麼，其值位1，否則其值為0

組合語言程式設計（十一）標誌暫存器

目錄 引言 flag暫存器標誌位介紹 ZF標誌，零標誌位 PF標誌，奇偶標誌位 SF標誌，符號標誌位

杭電計算機組成實驗4（四）暫存器堆設計實驗

技術標籤：杭電計算機組成實驗 實驗內容 1. 學習使用Verilog HDL 進行時序電路的設計方法 2. 掌握靈活運用Verilog HDL進行各種描述與建模的技巧和方法 3. 學習暫存器堆的資料傳送與讀/寫工作原理，掌握暫存器堆的

4.1程式計數器(PC暫存器)

目錄4.執行時資料區4.1程式計數器(PC暫存器) 4.執行時資料區 4.1程式計數器(PC暫存器)

Linux下的點燈實驗（暫存器）

1. 地址對映 裸機就是直接操作暫存器 Linux下也可以直接操作暫存器，但是不能直接對暫存器的實體地址進行操作，因為linux會使能MMU。

STM32F4暫存器串列埠DMA彙總

1.初始化 //RCC RCC->APB1ENR|=1<<20;//使能串列埠5時鐘 RCC->APB1ENR|=1<<19;//使能串列埠4時鐘

dpdk + ixgbe 通過pci_map_resource 讀寫dma暫存器

一般驅動 https://www.cnblogs.com/codestack/p/12906441.html static int ixgbe_probe(struct pci_dev *pdev, const struct pci_device_id *ent)

龍芯應用層mmap對映暫存器地址

以操作龍芯派為例，龍芯派2代 GPIO39為峰鳴器控制引腳 linux系統下通過info命令檢視mmap使用：

CPU暫存器快取記憶體實際上面的裝置，上層裝置都可以說是下層裝置

從程式碼說起 fn longRunningOperations(){ ... // 很耗時}let result = longRunningOperations();// do other thing

PC暫存器

一、概述 JVM中的程式計數暫存器（Program Counter Register）中，Register的命名源於CPU的暫存器，暫存器儲存指令相關的現場資訊，CPU只有把資料裝載到暫存器才能夠執行。 這裡，並非是廣義上所指的物理暫