喵~~~~~的！！！多維引用白學了啊啊啊！！！（Excel函式集團）
這兩天內心一直在徘徊的一句話就是……RT！
原因無它，就因為M365又出了新函式！
弄得本妖這會不知道是想暴走還是想撞牆~~~
============撞牆分隔線============
TEXTSPLIT
=TEXTSPLIT(字串, 分列分隔符, 分行分隔符, 是否忽略空單元格, 填充值)
過去：
{=TRIM(MID(SUBSTITUTE(B6,"/",REPT(" ",99)),COLUMN(A:G)*99-98,99))}
現在：
=TEXTSPLIT(B6,"/")
撞牆指數：★★★☆☆
VSTACK / HSTACK
=VSTACK(陣列1, 陣列2,… , 陣列254
=HSTACK(陣列1, 陣列2,… , 陣列254)
過去：
{=IF(N(OFFSET(A6,MOD(ROW(3:8),3),INT(ROW(3:8)/3)*5-5+COLUMN(A:D))),N(OFFSET($A$6,MOD(ROW(3:8),3),INT(ROW(3:8)/3)*5-5+COLUMN(A:D))),T(OFFSET($A$6,MOD(ROW(3:8),3),INT(ROW(3:8)/3)*5-5+COLUMN(A:D))))}
現在：
=VSTACK(B6:E8,G6:J8)
=HSTACK(B6:E8,G6:J8)
撞牆指數：★★★★★
TOROW / TOCOL
=TOROW(陣列, 是否忽略空或錯誤, 先行後列或先列後行)
=TOCOL(陣列, 是否忽略空或錯誤, 先行後列或先列後行)
過去：
{=IF(N(OFFSET(B5,COLUMN(D:K)/4,MOD(COLUMN(D:K),4))),N(OFFSET(B5,COLUMN(D:K)/4,MOD(COLUMN(D:K),4))),T(OFFSET(B5,COLUMN(D:K)/4,MOD(COLUMN(D:K),4))))}
現在：
=TOROW(B6:E7)
=TOCOL(B6:E7)
撞牆指數：★★★★☆
WRAPROWS / WRAPCOLS
=WRAPROWS(一行或一列陣列, 每行列數
=WRAPCOLS(一行或一列陣列, 每行列數, 不足部分填充)
過去：
{=IF(N(OFFSET(A6,,ROW(1:2)*4-4+COLUMN(A:D))),N(OFFSET(A6,,ROW(1:2)*4-4+COLUMN(A:D))),T(OFFSET(A6,,ROW(1:2)*4-4+COLUMN(A:D))))}
現在：
=WRAPROWS(B6:I6,4)
=WRAPCOLS(B6:I6,2)
撞牆指數：★★★★☆
TAKE / DROP
=TAKE(陣列, 保留的前N行, 保留的前N列)
=DROP(陣列, 去掉的前N行, 去掉的前N列)
過去：
{=OFFSET(B6,,,2,4)}
現在：
=TAKE(B6:E11,2)
=DROP(B6:E11,COUNTA(B6:B11)-2)
撞牆指數：★☆☆☆☆
CHOOSEROWS / CHOOSECOLS
=CHOOSEROWS(陣列, 行數1, 行數2,…, 行數253)
=CHOOSECOLS(陣列, 列數1, 列數2,…, 列數253)
過去：
{=IF(N(OFFSET(A5,{2;5},COLUMN(A:D))),N(OFFSET(A5,{2;5},COLUMN(A:D))),T(OFFSET(A5,{2;5},COLUMN(A:D))))}
現在：
=CHOOSEROWS(B6:E11,2,5)
=CHOOSECOLS(B6:E11,2,4)
撞牆指數：★★★★☆
EXPAND
=EXPAND(陣列, 擴充套件行數, 擴充套件列數, 填充的內容)
過去：
有過去嗎？？？
現在：
=EXPAND(B6:E7,4,5,"")
撞牆指數：☆☆☆☆☆
另，還有兩個函式TEXTBEFORE和TEXTAFTER，目前對漢字處理好像有BUG，以後再說。