有個朋友 做 某種小眾音樂交換站的（他們那個行業的暱圖網），需要用到付費下載。嘗試過 防盜鏈，不太理想，最終使用了 Adodb.Stream 讀取，直接輸出。

解決了 盜版的問題，但是新的問題又來了。Adodb.Stream 這種方式 電腦還好說，大部分電腦瀏覽器都支援。移動端 很多 瀏覽器為了 加速讀取，會多執行緒下載導致 檔案無法正常讀取。

抓包，發現增加了 HTTP頭 HTTP_RANGE。隱約記得 之前讀過 王大（王洪影）的 《深入解析 ASP核心技術》當中提到ASP多執行緒下載的問題，回家翻出來，最終還就真解決了。

為了 方便呼叫，直接寫成了 一個 函式。沒用王大的程式碼，感覺我自己的更美（自戀中…）。如有有需要的朋友需要，直接拿走即可，程式碼如下：

option explicit
 
'inputFile 需要下載的檔案
'outputName 輸出檔名，可以為空，為空時自動根據 inputFile 生成
Sub CreateDownloader(byval inputFile,byval outputName)
  Dim filePath
  filePath = Server.Mappath(inputFile)
  If outputName = "" Then outputName = Split(filePath,"\")(UBound(Split(filePath,"\")))
 
  '下載開始
  Dim AdoStream,bufferSize
  Set AdoStream = Server.CreateObject("Adodb.Stream") 'Adodb.Stream，例項變數名為了方便區分用大寫
  bufferSize   = 2 * 1024 * 1024 '每次讀取大小(byte) 2M
  AdoStream.Mode = 3 '1 讀，2 寫，3 讀寫
  AdoStream.Type = 1 '1 二進位制，2 文字
  AdoStream.Open
  AdoStream.LoadFromFile(filePath) '載入檔案
  Response.AddHeader "Content-Disposition","attachment; filename=" & outputName '檔名
  Response.ContentType = "application/octet-stream" '通知瀏覽器接受的檔案型別(可自己定義,很多種,但一般都用這個
 
  Dim httpRange,rangeStart,fileSize
  '獲取 分段下載 請求
  httpRange = Request.ServerVariables("HTTP_RANGE")
  fileSize = AdoStream.size '檔案總大小
 
  If httpRange = "" Then
    '不支援斷點續傳
    rangeStart = 0
  Else
    '支援斷點續傳
    httpRange = Mid(httpRange,7)
    rangeStart = CLng(Split(httpRange,"-")(0))
 
    If rangeStart < 0 Or rangeStart >= fileSize Then
      '已經下載完畢
      Response.Status = "416 Requested range not satisfiable"
    Else
      Response.Status = "206 Partial Content"
      Response.AddHeader "Content-Range","bytes " & rangeStart & "-" & (fileSize - 1) & "/" & fileSize
      AdoStream.Position = rangeStart
    End If
 
  End If
 
  Dim binaryBlock
 
  If Response.Status <> "416 Requested range not satisfiable" Then
    Response.AddHeader "Content-Length",fileSize - rangeStart '通知瀏覽器接收的檔案大小
    binaryBlock = AdoStream.Read(bufferSize)
 
    Do While Lenb(binaryBlock) > 0 '迴圈讀取直到讀完為止
      Response.BinaryWrite binaryBlock '輸出二進位制資料流
      Response.Flush '立即傳送(要求至少256位元組)，不加的話可能提示超過快取區。
      binaryBlock = AdoStream.Read(bufferSize)
    Loop
 
  End If
 
  AdoStream.Close '關閉檔案物件
  Set AdoStream = Nothing
  Response.End
End Sub

使用也非常簡單，假如上面的程式碼儲存到了 downloader.asp，直接引用即可：

<!--#include file="downloader.asp"-->
<%
  '建立下載
  call CreateDownloader("down/tools.rar","")
   
  '建立下載並自定義檔名
  call CreateDownloader("down/tools.rar","hello.rar")
%>

有圖有真相：

到此這篇關於ASP下通過Adodb.Stream實現多執行緒下載大檔案的文章就介紹到這了,更多相關ASP多執行緒下載大檔案內容請搜尋我們以前的文章或繼續瀏覽下面的相關文章希望大家以後多多支援我們！