獻給彙編初學者－函式呼叫堆疊變化分析
分享一下我老師大神的人工智慧教程！零基礎，通俗易懂！http://blog.csdn.net/jiangjunshow
也歡迎大家轉載本篇文章。分享知識，造福人民，實現我們中華民族偉大復興！
獻給彙編初學者－函式呼叫堆疊變化分析
標 題: 獻給彙編初學者－函式呼叫堆疊變化分析
作 者: 墮落天才
時 間: 2007-01-19,19:20
鏈 接: http://bbs.pediy.com/showthread.php?threadid=38234
跟一個朋友談堆疊的時候 就寫下了這段文字，順便發到這裡給需要的看看吧
彙編初學者比較頭痛的一個問題
////////////////////////////////////////////////////////////////////
比如 我們有這樣一個C函式
#include<stdio.h>
long test(int a,int b)
{
a = a + 1;
b = b + 100;
return a + b;
}
void main()
{
printf("%d",test(1000,2000));
}
寫成32位彙編就是這樣
;//////////////////////////////////////////////////////////////////////////////////////////////////////
.386
.module flat,stdcall ;這裡我們用stdcall 就是函式引數 壓棧的時候從最後一個開始壓，和被呼叫函式負責清棧
option casemap:none ;區分大小寫
includelib msvcrt.lib ;這裡是引入類庫 相當於 #include<stdio.h>了
printf PROTO C:DWORD,:VARARG ;這個就是宣告一下我們要用的函式頭，到時候 彙編程式會自動到msvcrt.lib裡面找的了
;:VARARG 表後面的引數不確定 因為C就是這樣的printf(const char *, ...);
;這樣的函式要注意 不是被呼叫函式負責清棧 因為它本身不知道有多少個引數
;而是有呼叫者負責清棧 下面會詳細說明
.data
szTextFmt BYTE '%d',0 ;這個是用來型別轉換的，跟C的一樣,字元用位元組型別
a dword 1000 ;假設
b dword 2000 ;處理數值都用雙字 沒有int 跟long 的區別
;/////////////////////////////////////////////////////////////////////////////////////////
.code
_test proc A:DWORD,B:DWORD
push ebp
mov ebp,esp
mov eax,dword ptr ss:[ebp+8]
add eax,1
mov edx,dword ptr ss:[ebp+0Ch]
add edx,100
add eax,edx
pop ebp
retn 8
_test endp
_main proc
push dword ptr ds:b ;反彙編我們看到的b就不是b了而是一個[*****]數字 dword ptr 就是我們在ds(資料段)把[*****]
;開始的一個雙字長數值取出來
push dword ptr ds:a ;跟她對應的還有 byte ptr ****就是取一個位元組出來 比如這樣 mov al,byte ptr ds:szTextFmt
;就把 % 取出來 而不包括 d
call _test
push eax ;假設push eax的地址是×××××
push offset szTextFmt
call printf
add esp,8
ret
_main endp
end _main
;////////////////////////////////////////////////////////////// 下面介紹堆疊的變化
首先要明白的是 操作堆疊段 ss 只能用 esp或ebp暫存器 其他的暫存器eax ebx edx等都不能夠用 而 esp永遠指向堆疊棧頂 ebp用來 在堆疊段
裡面定址
push 指令是壓棧 ESP=ESP-4
pop 指令是出棧 ESP=ESP+4
我們假設main函式一開始堆疊定是 ESP=400
push dword ptr ds:b ;ESP-4=396 ->裡面的值就是 2000 就是b的數值
push dword ptr ds:a ;ESP-4=392 ->裡面的值就是 1000 就是a的數值
call test ;ESP-4=388－>裡面的數值是什麼？這個太重要了 就是我們用來找遊戲函式的原理所在。
裡面的數值就是call test 指令下一條指令的地址－>即push eax的地址×××××
到了test函式裡面
push ebp ;ESP-4=384->裡面儲存了當前ebp的值 而不是把ebp清零
mov ebp,esp ;這裡ESP＝384就沒變化了，但是 ebp=esp=384,為什麼要這樣做呢 因為我們要用ebp到堆疊裡面找引數
mov eax,dword ptr ss:[ebp+8] ;反彙編是這樣的 想想為什麼a就是[ebp+8]呢
;我們往上看看堆疊裡地址392處就儲存著a的值 這裡ebp=384 加上8正好就是392了
;這樣就把傳遞過來的1000拿了出來eax=1000
add eax,1 ;相當於 a+1了 eax=1001
mov edx,dword ptr ss:[ebp+0Ch] ; 0Ch=12 一樣道理這裡指向堆疊的地址是384+12=396 就是2000了 edx=2000
add edx,100 ;相當於 b+100 edx=2100
add eax,edx ;eax=eax+edx＝1001＋2100＝3101 這裡eax已經儲存了最終的結果了
;因為win32彙編一般用eax返回結果 所以如果最終結果不是在eax裡面的話 還要把它放到eax
;比如假設我的結果儲存在變數nRet裡面 最後還是要這樣 mov eax,dword ptr nRet
pop ebp ;ESP=384+4=388 而儲存在棧頂384的值 儲存到 ebp中 即恢復ebp原來的值
;因為一開始我們就把ebp的值壓棧了，mov ebp,esp已經改變了ebp的值，這裡恢復就是保證了堆疊平衡
retn 8 ;ESP+8->396 這裡retn是由系統呼叫的 我們不用管 系統會自動把EIP指標指向 原來的call的下一條指令
;由於是系統自動恢復了call那裡的壓棧所以 真正返回到的時候ESP+4就是恢復了call壓棧的堆疊
;到了這個時候 ESP=400 就是函式呼叫開始的堆疊，就是說函式呼叫前跟函式呼叫後的堆疊是一樣的
;這就是堆疊平衡
由於我們用stdcall上面retn 8就是被呼叫者負責恢復堆疊的意思了，函式test是被呼叫者，所以負責把堆疊加8,call 那裡是系統自動恢復的
push eax ;ESP-4=396->裡面儲存了eax的值3101
;上面已經看到了eax儲存著返回值，我們要把它傳給printf也是通過堆疊傳遞
push offset szTextFmt ;ESP-4=392->裡面儲存了szTextFmt的地址 也就是C裡面的指標 實際上沒有什麼把字串傳遞的，我們傳的都是地址
;無論是在彙編或C 所以在彙編裡沒有什麼字串型別 用最多的就是DWORD。嘿嘿遊戲裡面傳遞引數 簡單多了
call printf ;ESP-4=388->裡面儲存了下一條指令的地址
add esp,8 ;ESP+8=400 恢復了呼叫printf前的堆疊狀態
;上面說了由於printf後面引數是:VARARG 這樣的型別是有呼叫者恢復堆疊的 所以printf裡面沒有retn 8之類的指令
;這是由呼叫者負責清棧 main是呼叫者 所以下面一句就是 add esp,8 把堆疊恢復到呼叫printf之前
;而call printf那裡的壓棧 是由系統做的 恢復的工作也是系統完成 我們不用理 只是知道里面儲存是返回地址就夠
;了
ret ;main 函式返回 其他的事情是系統自動搞定 我們不用理 任務完成
給我老師的人工智慧教程打call！http://blog.csdn.net/jiangjunshow
