BAT 批處理指令碼教程 BAT 批處理指令碼教程 DOS的重定向命令及在安全方面的應用

阿新 • • 發佈：2018-11-23

BAT 批處理指令碼教程

第一章批處理基礎
第一節常用批處理內部命令簡介

批處理定義：顧名思義，批處理檔案是將一系列命令按一定的順序集合為一個可執行的文字檔案，其副檔名為BAT或者CMD。這些命令統稱批處理命令。
小知識：可以在鍵盤上按下Ctrl+C組合鍵來強行終止一個批處理的執行過程。
瞭解了大概意思後,我們正式開始學習.先看一個簡單的例子!
@echo off
echo "歡迎來到非常BAT!"
pause
把上面的3條命令儲存為檔案test.bat或者test.cmd然後執行,
他就會在螢幕上顯示以下二行話:
歡迎來到非常BAT!
請按任意鍵繼續. . .
這就是一個簡單批處理檔案了，這個批處理檔案一共就用了2條命令 "echo" 和"pause" 還有一個特殊符號"@"
從上面這個簡單的批處理中,我們可以發現其實批處理就是運用一些含有特殊意義的符號和一些完成指定功能的命令組合而成,那麼在批處理中有多少這樣的特殊符號和功能命令呢？我們現在就來仔細瞭解一下一些最常用的!
(以下內容來源網路,請各位仔細閱讀,好進入下節的例項說明)
======================================================

目錄
批處理的常見命令（未列舉的命令還比較多，請查閱幫助資訊）
   1、REM 和 ::
   2、ECHO 和 @
   3、PAUSE
   4、ERRORLEVEL
   5、TITLE
   6、COLOR
   7、mode 配置系統裝置
   8、GOTO 和 :
   9、FIND
   10、START
   11、assoc 和 ftype
   12、pushd 和 popd
   13、CALL
   14、shift
   15、IF
   16、setlocal 與變數延遲
   17、ATTRIB  顯示或更改檔案屬性
======================================================
介紹命令

1、REM 和 ::
REM為註釋命令，一般用來給程式加上註解，該命令後的內容不被執行，但能回顯。
其次, :: 也可以起到rem 的註釋作用, 而且更簡潔有效; 但有兩點需要注意：
第一, 任何以冒號:開頭的字元行, 在批處理中都被視作標號, 而直接忽略其後的所有內容。
有效標號：冒號後緊跟一個以字母數字開頭的字串，goto語句可以識別。
無效標號：冒號後緊跟一個非字母數字的一個特殊符號，goto無法識別的標號，可以起到註釋作用，所以 :: 常被用作註釋符號，其實 :+ 也可起註釋作用。
第二, 與rem 不同的是, ::後的字元行在執行時不會回顯, 無論是否用echo on開啟命令列回顯狀態, 因為命令直譯器不認為他是一個有效的命令列, 就此點來看, rem 在某些場合下將比 :: 更為適用; 另外, rem 可以用於 config.sys 檔案中。

行內註釋格式：%註釋內容% （不常用，慎用）

2、ECHO 和 @

@字元放在命令前將關閉該命令回顯，無論此時echo是否為開啟狀態。
echo命令的作用列舉如下：
（1）打開回顯或關閉回顯功能
格式:echo [{ on|off }]
如果想關閉“ECHO OFF”命令列自身的顯示，則需要在該命令列前加上“@”。
（2）顯示當前ECHO設定狀態
格式:echo
（3）輸出提示資訊
格式：ECHO 資訊內容
上述是ECHO命令常見的三種用法，也是大家熟悉和會用的，但作為DOS命令淘金者你還應該知道下面的技巧：
（4）關閉DOS命令提示符
在DOS提示符狀態下鍵入ECHO OFF，能夠關閉DOS提示符的顯示使螢幕只留下游標，直至鍵入ECHO ON，提示符才會重新出現。
（5）輸出空行，即相當於輸入一個回車
格式：ECHO．
值得注意的是命令列中的“．”要緊跟在ECHO後面中間不能有空格，否則“．”將被當作提示資訊輸出到螢幕。另外“．”可以用，：；”／[\]＋等任一符號替代。
命令ECHO．輸出的回車，經DOS管道轉向可以作為其它命令的輸入，比如echo.|time即相當於在TIME命令執行後給出一個回車。所以執行時系統會在顯示當前時間後，自動返回到DOS提示符狀態
（6）答覆命令中的提問
格式：ECHO 答覆語|命令檔名
上述格式可以用於簡化一些需要人機對話的命令（如：CHKDSK／F；FORMAT Drive:；del *.*）的操作，它是通過DOS管道命令把ECHO命令輸出的預置答覆語作為人機對話命令的輸入。下面的例子就相當於在呼叫的命令出現人機對話時輸入“Y”回車：
C:>ECHO Y|CHKDSK/F
C:>ECHO Y|DEL A :*.*
（7）建立新檔案或增加檔案內容
格式：ECHO 檔案內容>檔名
   ECHO 檔案內容>>檔名
例如：
C:>ECHO @ECHO OFF>AUTOEXEC.BAT建立自動批處理檔案
C:>ECHO C:\CPAV\BOOTSAFE>>AUTOEXEC.BAT向自動批處理檔案中追加內容
C:>TYPE AUTOEXEC.BAT顯示該自動批處理檔案
@ECHO OFF
C:\CPAV\BOOTSAFE
（8）向印表機輸出列印內容或列印控制碼
格式：ECHO 印表機控制碼>;PRN
   ECHO 列印內容>;PRN
下面的例子是向M－1724印表機輸入列印控制碼。＜Alt＞156是按住Alt鍵在小鍵盤鍵入156，類似情況依此類推：
C:>ECHO +156+42+116>;PRN（輸入下劃線命令FS＊t）
C:>ECHO [[email protected]][email protected]>;PRN[/email]（輸入初始化命令[email protected]）
C:>ECHO.>;PRN（換行）
（9）使喇叭鳴響
C:>ECHO ^G
“^G”是在dos視窗中用Ctrl＋G或Alt＋007輸入，輸入多個^G可以產生多聲鳴響。使用方法是直接將其加入批處理檔案中或做成批處理檔案呼叫。
這裡的“^G”屬於特殊符號的使用，請看本文後面的章節

3、PAUSE
PAUSE，玩遊戲的人都知道，暫停的意思
在這裡就是停止系統命令的執行並顯示下面的內容。
例：
PAUSE
執行顯示：
請按任意鍵繼續. . .
要顯示其他提示語，可以這樣用：
Echo 其他提示語 & pause > nul

4、errorlevel
程式返回碼
echo %errorlevel%
每個命令執行結束，可以用這個命令列格式檢視返回碼
用於判斷剛才的命令是否執行成功
預設值為0，一般命令執行出錯會設 errorlevel 為1

5、title
設定cmd視窗的標題
title 新標題       #可以看到cmd視窗的標題欄變了

6、COLOR
設定預設的控制檯前景和背景顏色。
COLOR [attr]
  attr       指定控制檯輸出的顏色屬性
顏色屬性由兩個十六進位制數字指定 -- 第一個為背景，第二個則為
前景。每個數字可以為以下任何值之一:
0 = 黑色    8 = 灰色
1 = 藍色    9 = 淡藍色
2 = 綠色    A = 淡綠色
3 = 湖藍色    B = 淡淺綠色
4 = 紅色    C = 淡紅色
5 = 紫色    D = 淡紫色
6 = 黃色    E = 淡黃色
7 = 白色    F = 亮白色
如果沒有給定任何引數，該命令會將顏色還原到 CMD.EXE 啟動時
的顏色。這個值來自當前控制檯視窗、/T 開關或
DefaultColor 登錄檔值。
如果用相同的前景和背景顏色來執行 COLOR 命令，COLOR 命令
會將 ERRORLEVEL 設定為 1。
例如: "COLOR fc" 在亮白色上產生亮紅色

7、mode 配置系統裝置
配置系統裝置。
序列口:　　　    MODE COMm[:] [BAUD=b] [PARITY=p] [DATA=d] [STOP=s]
                              [to=on|off] [xon=on|off] [odsr=on|off]
                              [octs=on|off] [dtr=on|off|hs]
                              [rts=on|off|hs|tg] [idsr=on|off]
裝置狀態:          MODE [device] [/STATUS]
列印重定向:　　 MODE LPTn[:]=COMm[:]
選定內碼表:　　 MODE CON[:] CP SELECT=yyy
內碼表狀態:　　 MODE CON[:] CP [/STATUS]
顯示模式:　　    MODE CON[:] [COLS=c] [LINES=n]
擊鍵率:　          MODE CON[:] [RATE=r DELAY=d]
例：
mode con cols=113 lines=15 & color 9f
此命令設定DOS視窗大小：15行，113列

8、GOTO 和 :
GOTO會點程式設計的朋友就會知道這是跳轉的意思。
在批處理中允許以“:XXX”來構建一個標號，然後用GOTO XXX跳轉到標號:XXX處，然後執行標號後的命令。
例：
if {%1}=={} goto noparms
if "%2"=="" goto noparms
標籤的名字可以隨便起，但是最好是有意義的字串啦，前加個冒號用來表示這個字串是標籤，goto命令就是根據這個冒號（:）來尋找下一步跳到到那裡。最好有一些說明這樣你別人看起來才會理解你的意圖啊。

例：
@echo off
:start
set /a var+=1
echo %var%
if %var% leq 3 GOTO start
pause
執行顯示：
1
2
3
4

9、find
在檔案中搜索字串。
FIND [/V] [/C] [/N] [/I] [/OFF[LINE]] "string" [[drive:][path]filename[ ...]]
   /V        顯示所有未包含指定字串的行。
   /C        僅顯示包含字串的行數。
   /N        顯示行號。
   /I        搜尋字串時忽略大小寫。
   /OFF[LINE] 不要跳過具有離線屬性集的檔案。
   "string"   指定要搜尋的文字串，
   [drive:][path]filename
         指定要搜尋的檔案。
如果沒有指定路徑，FIND 將搜尋鍵入的或者由另一命令產生的文字。
Find常和type命令結合使用
Type [drive:][path]filename | find "string" [>tmpfile] #挑選包含string的行
Type [drive:][path]filename | find /v "string" #剔除檔案中包含string的行
Type [drive:][path]filename | find /c #顯示檔案行數
以上用法將去除find命令自帶的提示語（檔名提示）

例：
@echo off
echo 111 >test.txt
echo 222 >>test.txt
find "111" test.txt
del test.txt
pause
執行顯示如下：
---------- TEST.TXT
111
請按任意鍵繼續. . .

例：
@echo off
echo 111 >test.txt
echo 222 >>test.txt
type test.txt|find "111"
del test.txt
pause
執行顯示如下：
111
請按任意鍵繼續. . .

10、start 命令
批處理中呼叫外部程式的命令（該外部程式在新視窗中執行，批處理程式繼續往下執行，不理會外部程式的執行狀況），如果直接執行外部程式則必須等外部程式完成後才繼續執行剩下的指令
例：start explorer d:\
呼叫圖形介面開啟D盤

11、assoc 和 ftype
檔案關聯
assoc 設定'副檔名'關聯，關聯到'檔案型別'
ftype 設定'檔案型別'關聯，關聯到'執行程式和引數'
當你雙擊一個.txt檔案時，windows並不是根據.txt直接判斷用 notepad.exe 開啟
而是先判斷.txt屬於 txtfile '檔案型別'
再呼叫 txtfile 關聯的命令列 txtfile=%SystemRoot%\system32\NOTEPAD.EXE %1
可以在"資料夾選項"→"檔案型別"裡修改這2種關聯
assoc          #顯示所有'副檔名'關聯
assoc .txt    #顯示.txt代表的'檔案型別'，結果顯示 .txt=txtfile
assoc .doc    #顯示.doc代表的'檔案型別'，結果顯示 .doc=Word.Document.8
assoc .exe    #顯示.exe代表的'檔案型別'，結果顯示 .exe=exefile
ftype          #顯示所有'檔案型別'關聯
ftype exefile #顯示exefile型別關聯的命令列，結果顯示 exefile="%1" %*
assoc .txt=Word.Document.8
設定.txt為word型別的文件，可以看到.txt檔案的圖示都變了
assoc .txt=txtfile
恢復.txt的正確關聯

ftype exefile="%1" %*
恢復 exefile 的正確關聯
如果該關聯已經被破壞，可以執行 command.com ，再輸入這條命令

12、pushd 和 popd
切換當前目錄
@echo off
c: & cd\ & md mp3    #在 C:\ 建立 mp3 資料夾
md d:\mp4             #在 D:\ 建立 mp4 資料夾
cd /d d:\mp4          #更改當前目錄為 d:\mp4
pushd c:\mp3          #儲存當前目錄，並切換當前目錄為 c:\mp3
popd                   #恢復當前目錄為剛才儲存的 d:\mp4
一般用處不大，在當前目錄名不確定時，會有點幫助。（dos程式設計中很有用）

13、CALL
CALL命令可以在批處理執行過程中呼叫另一個批處理，當另一個批處理執行完後，再繼續執行原來的批處理
CALL command
呼叫一條批處理命令，和直接執行命令效果一樣，特殊情況下很有用，比如變數的多級巢狀，見教程後面。在批處理程式設計中，可以根據一定條件生成命令字串，用call可以執行該字串，見例子。
CALL [drive:][path]filename [batch-parameters]
呼叫的其它批處理程式。filename 引數必須具有 .bat 或 .cmd 副檔名。
CALL :label arguments
呼叫本檔案內命令段，相當於子程式。被呼叫的命令段以標籤:label開頭
以命令goto :eof結尾。
另外，批指令碼文字引數參照(%0、%1、等等)已如下改變:
   批腳本里的 %* 指出所有的引數(如 %1 %2 %3 %4 %5 ...)
   批引數(%n)的替代已被增強。您可以使用以下語法:（看不明白的直接執行後面的例子）
      %~1       - 刪除引號(")，擴充 %1
      %~f1       - 將 %1 擴充到一個完全合格的路徑名
      %~d1       - 僅將 %1 擴充到一個驅動器號
      %~p1       - 僅將 %1 擴充到一個路徑
      %~n1       - 僅將 %1 擴充到一個檔名
      %~x1       - 僅將 %1 擴充到一個副檔名
      %~s1       - 擴充的路徑指含有短名
      %~a1       - 將 %1 擴充到檔案屬性
      %~t1       - 將 %1 擴充到檔案的日期/時間
      %~z1       - 將 %1 擴充到檔案的大小
      %~ $P A T H : 1 - 查找列在 P A T H 环境变量的目录，并将$

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
第二節常用特殊符號
    1、@  命令列回顯遮蔽符
2、%  批處理變數引導符
3、> 重定向符
4、>>  重定向符
5、<、>&、<& 重定向符
6、|  命令管道符
7、^  轉義字元
8、&  組合命令
9、&& 組合命令
10、||  組合命令
11、""  字串界定符
12、, 逗號
13、; 分號
14、() 括號
15、! 感嘆號
16、批處理中可能會見到的其它特殊標記符: （略）
      CR(0D) 命令列結束符
      Escape(1B) ANSI轉義字元引導符
      Space(20) 常用的引數界定符
      Tab(09) ; = 不常用的引數界定符
      + COPY命令檔案連線符
      * ? 檔案萬用字元
      / 引數開關引導符
      : 批處理標籤引導符

廢話少說，開講了
1、@  命令列回顯遮蔽符
這個字元在批處理中的意思是關閉當前行的回顯。我們從前幾課知道
ECHO OFF可以關閉掉整個批處理命令的回顯，但不能關掉ECHO OFF這個命令，現在我們在ECHO OFF這個命令前加個@，就可以達到所有命令均不回顯的要求

2、%  批處理變數引導符
這個百分號嚴格來說是算不上命令的，它只是批處理中的引數而已（多個%一起使用的情況除外，以後還將詳細介紹）。
引用變數用%var%，呼叫程式外部引數用%1至%9等等
%0  %1  %2  %3  %4  %5  %6  %7  %8  %9  %*為命令列傳遞給批處理的引數
%0 批處理檔案本身，包括完整的路徑和副檔名
%1 第一個引數
%9 第九個引數
%* 從第一個引數開始的所有引數
引數%0具有特殊的功能，可以呼叫批處理自身，以達到批處理本身迴圈的目的，也可以複製檔案自身等等。
例：最簡單的複製檔案自身的方法
copy %0 d:\wind.bat
小技巧：新增行內註釋
%註釋內容%（可以用作行內註釋，不能出現重定向符號和管道符號）
為什麼這樣呢？此時“註釋內容”其實被當作變數，其值是空的，故只起註釋作用，不過這種用法容易出現語法錯誤，一般不用。

3、> 重定向符
輸出重定向命令
DOS的標準輸入輸出通常是在標準裝置鍵盤和顯示器上進行的，利用重定向,可以方便地將輸入輸出改向磁碟檔案或其它裝置。其中:
1.大於號“>”將命令傳送到檔案或裝置，例如印表機>prn。使用大於號“>”時，有些命令輸出(例如錯誤訊息)不能重定向。
2.雙大於號“>>”將命令輸出新增到檔案結尾而不刪除檔案中已有的資訊。
3.小於號“<”從檔案而不是鍵盤上獲取命令所需的輸入。
4.>&符號將輸出從一個預設I/O流(stdout,stdin,stderr)重新定向到另一個預設I/O流。
例如，command >output_file 2>&1將處理command過程中的所有錯誤資訊從螢幕重定向到標準檔案輸出中。標準輸出的數值如下所示：
命令重定向的標準控制代碼

控制代碼名稱	值	說明
STDIN	0	標準輸入，傳送自鍵盤
STDUOT	1	標準輸出，傳送到命令Shell視窗
STDERR	2	標準錯誤輸出，傳送到命令Shell視窗
UNDEFINED	3~9	特定於應用程式的控制代碼

這個字元的意思是傳遞並且覆蓋，他所起的作用是將執行的結果傳遞到後面的範圍（後邊可以是檔案，也可以是預設的系統控制檯）
在NT系列命令列中，重定向的作用範圍由整個命令列轉變為單個命令語句，受到了命令分隔符&,&&,||和語句塊的制約限制。
比如：
使用命令：echo hello >1.txt將建立檔案1.txt，內容為”hello “（注意行尾有一空格）
使用命令：echo hello>1.txt將建立檔案1.txt，內容為”hello“（注意行尾沒有空格）：
具體重定向例項請看我的另外一篇文章：DOS的重定向命令及在安全方面的應用

4、>>  重定向符
輸出重定向命令
這個符號的作用和>有點類似，但他們的區別是>>是傳遞並在檔案的末尾追加，而>是覆蓋
用法同上
同樣拿1.txt做例子
使用命令：
echo hello > 1.txt
echo world >>1.txt
這時候1.txt 內容如下:
hello
world

5、<、>&、<& 重定向符
這三個命令也是管道命令，但它們一般不常用，你只需要知道一下就ok了，當然如果想仔細研究的話，可以自己查一下資料。(本人已查過，網上也查不到相關資料)
<，輸入重定向命令，從檔案中讀入命令輸入，而不是從鍵盤中讀入。
@echo off
echo 2005-05-01>temp.txt
date <temp.txt
del temp.txt
這樣就可以不等待輸入直接修改當前日期
>&，將一個控制代碼的輸出寫入到另一個控制代碼的輸入中。
<&，剛好和>&相反，從一個控制代碼讀取輸入並將其寫入到另一個控制代碼輸出中。
常用控制代碼：0、1、2，未定義控制代碼：3—9
1>nul 表示禁止輸出正確的資訊
2>nul 表示禁止輸出錯誤資訊。
其中的1與2都是代表某個資料流輸入輸出的地址（NT CMD 稱之為控制代碼，MSDOS稱之為裝置）。
控制代碼0：標準輸入stdin，鍵盤輸入
控制代碼1：標準輸出stdout，輸出到命令提示符視窗（console，程式碼為CON）
控制代碼2：標準錯誤stderr，輸出到命令提示符視窗（console，程式碼為CON）
其中的stdin可被<重定向，stdout可被>、>>重定向。
我們已經知道讀取文字中的內容可以用for命令，但如果只需要讀取第一行用for命令就有點麻煩。簡單的辦法如下:
@echo off
set /p str=<%0
echo %str%
pause
執行顯示批處理檔案自身的第一行：@echo off

6、|  命令管道符
格式：第一條命令 | 第二條命令 [| 第三條命令...]
將第一條命令的結果作為第二條命令的引數來使用，記得在unix中這種方式很常見。
例如：
dir c:\|find "txt"
以上命令是：查詢C：\所有，並發現TXT字串。
FIND的功能請用 FIND /? 自行檢視
在不使format的自動格式化引數時，我是這樣來自動格式化A盤的
echo y|format a: /s /q /v:system
用過format的都知道，再格盤時要輸入y來確認是否格盤，這個命令前加上echo y並用|字元來將echo y的結果傳給format命令
從而達到自動輸入y的目的
（這條命令有危害性，測試時請慎重）

7、^  轉義字元
^是對特殊符號<,>,&的前導字元，在命令中他將以上3個符號的特殊功能去掉，僅僅只把他們當成符號而不使用他們的特殊意義。
比如
echo test ^>1.txt
結果則是：test > 1.txt
他沒有追加在1.txt裡，呵呵。只是顯示了出來
另外，此轉義字元還可以用作續行符號。
舉個簡單的例子：
@echo off
echo 英雄^
是^
好^
男人
pause
不用多說，自己試一下就明白了。
為什麼轉義字元放在行尾可以起到續行符的作用呢？原因很簡單，因為每行末尾還有一個看不見的符號，即回車符，轉義字元位於行尾時就讓回車符失效了，從而起到了續行的作用。

8、& 組合命令
語法：第一條命令 & 第二條命令 [& 第三條命令...]
&、&&、||為組合命令，顧名思義，就是可以把多個命令組合起來當一個命令來執行。這在批處理腳本里是允許的，而且用的非常廣泛。因為批處理認行不認命令數目。
這個符號允許在一行中使用2個以上不同的命令，當第一個命令執行失敗了，也不影響後邊的命令執行。
這裡&兩邊的命令是順序執行的，從前往後執行。
比如：
dir z:\ & dir y:\ & dir c:\
以上命令會連續顯示z,y,c盤的內容，不理會該盤是否存在

9、&& 組合命令
語法：第一條命令 && 第二條命令 [&& 第三條命令...]
用這種方法可以同時執行多條命令，當碰到執行出錯的命令後將不執行後面的命令，如果一直沒有出錯則一直執行完所有命令
這個命令和上邊的類似，但區別是，第一個命令失敗時，後邊的命令也不會執行
dir z:\ && dir y:\ && dir c:\

10、||  組合命令
語法：第一條命令 || 第二條命令 [|| 第三條命令...]
用這種方法可以同時執行多條命令，當一條命令失敗後才執行第二條命令，當碰到執行正確的命令後將不執行後面的命令，如果沒有出現正確的命令則一直執行完所有命令；

提示：組合命令和重定向命令一起使用必須注意優先順序
管道命令的優先順序高於重定向命令，重定向命令的優先順序高於組合命令
問題：把C盤和D盤的檔案和資料夾列出到a.txt檔案中。看例：
dir c:\ && dir d:\ > a.txt
這樣執行後a.txt裡只有D盤的資訊！為什麼？因為組合命令的優先順序沒有重定向命令的優先順序高！所以這句在執行時將本行分成這兩部分：dir c:\和dir d:\ > a.txt，而並不是如你想的這兩部分：dir c:\ && dir d:\和> a.txt。要使用組合命令&&達到題目的要求，必須得這麼寫：
dir c:\ > a.txt && dir d:\ >> a.txt
這樣，依據優先順序高低，DOS將把這句話分成以下兩部分：dir c:\ > a.txt和dir d:\ >> a.txt。例十八中的幾句的差別比較特殊，值得好好研究體會一下。
當然這裡還可以利用&命令（自己想一下道理哦）：
dir c:\ > a.txt & dir d:\ >> a.txt
[這個也可以用 dir c:\;d:\ >>a.txt 來實現]

11、""  字串界定符
雙引號允許在字串中包含空格，進入一個特殊目錄可以用如下方法
cd "program files"
cd progra~1
cd pro*
以上三種方法都可以進入program files這個目錄

12、, 逗號
逗號相當於空格，在某些情況下“,”可以用來當做空格使
比如
dir,c:\

13、; 分號
分號，當命令相同時，可以將不同目標用；來隔離，但執行效果不變，如執行過程中發生錯誤，則只返回錯誤報告，但程式仍會執行。（有人說不會繼續執行，其實測試一下就知道了，只不過它的執行有個規則，請看下面的規則）
比如：
dir c:\;d:\;e:\;z:\
以上命令相當於
dir c:\
dir d:\
dir e:\
dir f:\
如果其中z盤不存在，執行顯示：系統找不到指定的路徑。然後終止命令的執行。
例：dir c:\;d:\;e:\1.txt
以上命令相當於
dir c:\
dir d:\
dir e:\1.txt
其中檔案e:\1.txt不存在，但e盤存在，有錯誤提示，但命令仍會執行。

規則：(我是在作業系統是XP SP3,英文版下測試的)
1.如果目標路徑不存在，則整個語句都不執行，例如dir c:\;c:\dfdfdf\a.txt，則根本不會執行，因為我沒有c:\dfdfdf\這個目錄；
2.如果路徑存在，僅檔案不存在，則會繼續執行，並且提示檔案不存在的錯誤，例如：dir c:\;c:\temp\a.txt，我的目錄中有c:\temp\資料夾，但這個目錄下面沒有1.txt這個檔案。
就說這些了!各位有什麼意見請回貼!有什麼疑問請到BAT交流區發貼!下一節改進!

14、() 括號
小括號在批處理程式設計中有特殊的作用，左右括號必須成對使用，括號中可以包括多行命令，這些命令將被看成一個整體，視為一條命令列。
括號在for語句和if語句中常見，用來巢狀使用迴圈或條件語句，其實括號()也可以單獨使用，請看例子。
例：
命令：echo 1 & echo 2 & echo 3
可以寫成：
(
echo 1
echo 2
echo 3
)
上面兩種寫法效果一樣，這兩種寫法都被視為是一條命令列。
注意：這種多條命令被視為一條命令列時，如果其中有變數，就涉及到變數延遲的問題。

15、! 感嘆號
沒啥說的，在變數延遲問題中，用來表示變數，即%var%應該表示為!var!，請看前面的setlocal命令介紹。

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
第二章 DOS迴圈：for命令詳解

講FOR之前呢,咋先告訴各位新手朋友,如果你有什麼命令不懂,直接在CMD下面輸入:
name /? 這樣的格式來看系統給出的幫助檔案,比如for /? 就會把FOR命令的幫助全部顯示出來!當然許多菜鳥都看不懂....所以才會有那麼多批處理文章!!!!俺也照顧菜鳥,把FOR命令用我自己的方式說明下!
正式開始:

一、基本格式
FOR %%variable IN (set) DO command [command-parameters]
  %%variable  指定一個單一字母表示可替換的引數。
  (set)    指定一個或一組檔案。可以使用萬用字元。
  command 指定對每個檔案執行的命令。
  command-parameters
         為特定命令指定引數或命令列開關。

引數:FOR有4個引數 /d /l /r /f 他們的作用我在下面用例子解釋
現在開始講每個引數的意思

二、引數 /d
FOR /D %%variable IN (set) DO command [command-parameters]
如果集中包含萬用字元，則指定與目錄名匹配，而不與檔案
名匹配。
如果 Set (也就是我上面寫的 "相關檔案或命令") 包含萬用字元（* 和 ?），將對與 Set 相匹配的每個目錄（而不是指定目錄中的檔案組）執行指定的 Command。
這個引數主要用於目錄搜尋,不會搜尋檔案,看這樣的例子
@echo off
for /d %%i in (c:\*) do echo %%i
pause
執行會把C盤根目錄下的全部目錄名字打印出來,而檔名字一個也不顯示!
在來一個,比如我們要把當前路徑下資料夾的名字只有1-3個字母的打出來
@echo off
for /d %%i in (???) do echo %%i
pause
這樣的話如果你當前目錄下有目錄名字只有1-3個字母的,就會顯示出來,沒有就不顯示了
這裡解釋下*號和?號的作用,*號表示任意N個字元,而?號只表示任意一個字元
知道作用了,給大家個思考題目!
@echo off
for /d %%i in (window?) do echo %%i
pause
儲存到C盤下執行,會顯示什麼呢?自己看吧! 顯示：windows
/D引數只能顯示當前目錄下的目錄名字,這個大家要注意!

三、引數 /R
FOR /R [[drive:]path] %%variable IN (set) DO command [command-parameters]
檢查以 [drive:]path 為根的目錄樹，指向每個目錄中的
FOR 語句。如果在 /R 後沒有指定目錄，則使用當前
目錄。如果集僅為一個單點(.)字元，則列舉該目錄樹。

遞迴
上面我們知道,/D只能顯示當前路徑下的目錄名字,那麼現在這個/R也是和目錄有關,他能幹嘛呢?放心他比/D強大多了!
他可以把當前或者你指定路徑下的檔名字全部讀取,注意是檔名字,有什麼用看例子!
請注意2點：
1、set中的檔名如果含有萬用字元(？或*)，則列舉/R引數指定的目錄及其下面的所用子目錄中與set相符合的所有檔案，無相符檔案的目錄則不列舉。
2、相反，如果set中為具體檔名，不含萬用字元，則列舉該目錄樹（即列舉該目錄及其下面的所有子目錄），而不管set中的指定檔案是否存在。這與前面所說的單點（.）列舉目錄樹是一個道理，單點代表當前目錄，也可視為一個檔案。
例：
@echo off
for /r c:\ %%i in (*.exe) do echo %%i
pause
咱們把這個BAT儲存到D盤隨便哪裡然後執行,我會就會看到,他把C盤根目錄,和每個目錄的子目錄下面全部的EXE檔案都列出來了!!!!
例：
@echo off
for /r %%i in (*.exe) do @echo %%i
pause
引數不一樣了吧!這個命令前面沒加那個C:\也就是搜尋路徑,這樣他就會以當前目錄為搜尋路徑,比如你這個BAT你把他放在d:\test目錄下執行,那麼他就會把D:\test目錄和他下面的子目錄的全部EXE檔案列出來!!!
例：
@echo off
for /r c:\ %%i in (boot.ini) do echo %%i
pause
執行本例發現枚舉了c盤所有目錄，為了只列舉boot.ini存在的目錄，可改成下面這樣：
@echo off
for /r c:\ %%i in (boot.ini) do if exist %%i echo %%i
pause
用這條命令搜尋檔案真不錯。。。。。。
這個引數大家應該理解了吧!還是滿好玩的命令!

四、引數 /L
FOR /L %%variable IN (start,step,end) DO command [command-parameters]
該集表示以增量形式從開始到結束的一個數字序列。
因此，(1,1,5) 將產生序列 1 2 3 4 5，(5,-1,1) 將產生
序列 (5 4 3 2 1)。
使用迭代變數設定起始值 (Start#)，然後逐步執行一組範圍的值，直到該值超過所設定的終止值 (End#)。/L 將通過對 Start# 與 End# 進行比較來執行迭代變數。如果 Start# 小於 End#，就會執行該命令。如果迭代變數超過 End#，則命令解釋程式退出此迴圈。還可以使用負的 Step# 以遞減數值的方式逐步執行此範圍內的值。例如，(1,1,5) 生成序列 1 2 3 4 5，而 (5,-1,1) 則生成序列 (5 4 3 2 1)。語法是：
看著這說明有點暈吧!咱們看例子就不暈了!
@echo off
for /l %%i in (1,1,5) do @echo %%i
pause
儲存執行看效果,他會列印從1 2 3 4 5  這樣5個數字
(1,1,5)這個引數也就是表示從1開始每次加1直到5終止!
等會暈,就列印個數字有P用...好的滿足大家,看這個例子
@echo off
for /l %%i in (1,1,5) do start cmd
pause
執行後是不是嚇了一跳,怎麼多了5個CMD視窗,呵呵!如果把那個 (1,1,5)改成 (1,1,65535)會有什麼結果,我先告訴大家,會開啟65535個CMD視窗....這麼多你不宕機算你強!
當然我們也可以把那個start cmd改成md %%i 這樣就會建立指定個目錄了!!!名字為1-65535
看完這個被我賦予破壞性質的引數後,我們來看最後一個引數

五、引數 /F
\迭代及檔案解析
使用檔案解析來處理命令輸出、字串及檔案內容。使用迭代變數定義要檢查的內容或字串，並使用各種options選項進一步修改解析方式。使用options令牌選項指定哪些令牌應該作為迭代變數傳遞。請注意：在沒有使用令牌選項時，/F 將只檢查第一個令牌。
檔案解析過程包括讀取輸出、字串或檔案內容，將其分成獨立的文字行以及再將每行解析成零個或更多個令牌。然後通過設定為令牌的迭代變數值，呼叫 for 迴圈。預設情況下，/F 傳遞每個檔案每一行的第一個空白分隔符號。跳過空行。

詳細的幫助格式為：
FOR /F ["options"] %%variable IN (file-set) DO command [command-parameters]
FOR /F ["options"] %%variable IN ("string") DO command [command-parameters]
FOR /F ["options"] %%variable IN ('command') DO command [command-parameters]
帶引號的字串"options"包括一個或多個
指定不同解析選項的關鍵字。這些關鍵字為:
      eol=c          - 指一個行註釋字元的結尾(就一個)(備註：預設以使用；號為行首字元的為註釋行)
        skip=n       - 指在檔案開始時忽略的行數，(備註：最小為1，n可以大於檔案的總行數，預設為1。)
      delims=xxx    - 指分隔符集。這個替換了空格和跳格鍵的預設分隔符集。
      tokens=x,y,m-n  - 指每行的哪一個符號被傳遞到每個迭代
                        的 for 本身。這會導致額外變數名稱的分配。m-n
                        格式為一個範圍。通過 nth 符號指定 mth。如果
                        符號字串中的最後一個字元星號，
                        那麼額外的變數將在最後一個符號解析之後
                        分配並接受行的保留文字。經測試，該引數最多
                        只能區分31個欄位。(備註：預設為1，則表示只顯示分割後的第一列的內容，最大是31，超過最大則無法表示)
        usebackq       - 使用後引號（鍵盤上數字1左面的那個鍵`）。
                     未使用引數usebackq時：file-set表示檔案，但不能含有空格
                        雙引號表示字串，即"string"
                        單引號表示執行命令，即'command'
                        使用引數usebackq時：file-set和"file-set"都表示檔案
                        當檔案路徑或名稱中有空格時，就可以用雙引號括起來
                        單引號表示字串，即'string'
                        後引號表示命令執行，即`command`

以上是用for /?命令獲得的幫助資訊，直接複製過來的，括號中的備註為我新增的說明。
暈慘了!我這就舉個例子幫助大家來理解這些引數!

For命令例1：****************************************
@echo off
rem 首先建立臨時檔案test.txt
echo ;註釋行,這是臨時檔案,用完刪除 >test.txt
echo 11段 12段 13段 14段 15段 16段 >>test.txt
echo 21段,22段,23段,24段,25段,26段 >>test.txt
echo 31段-32段-33段-34段-35段-36段 >>test.txt
FOR /F "eol=; tokens=1,3* delims=,- " %%i in (test.txt) do echo %%i %%j %%k
Pause
Del test.txt
執行顯示結果：
11段 13段 14段 15段 16段
21段 23段 24段,25段,26段
31段 33段 34段-35段-36段
請按任意鍵繼續. . .
為什麼會這樣?我來解釋：
eol=;       分號開頭的行為註釋行
tokens=1,3* 將每行第1段,第3段和剩餘欄位分別賦予變數%%i，%%j，%%k
delims=,-    （減號後有一空格）以逗號減號和空格為分隔符，空格必須放在最後

For命令例2：****************************************
@echo off
FOR /F "eol= delims=" %%i in (test.txt) do echo %%i
Pause
執行將顯示test.txt全部內容，包括註釋行，不解釋了哈。

For命令例3：****************************************
另外/F引數還可以以輸出命令的結果看這個例子
@echo off
FOR /F "delims=" %%i in ('net user') do @echo %%i
pause
這樣你本機全部帳號名字就出來了把擴號內的內容用兩個單引號引起來就表示那個當命令執行,FOR會返回命令的每行結果,加那個"delims=" 是為了讓我空格的行能整行顯示出來,不加就只顯示空格左邊一列!

基本上講完了FOR的基本用法了...如果你看過FOR的系統幫助,你會發現他下面還有一些特定義的變數,這些我先不講.大家因該都累了吧!你不累我累啊....
所謂文武之道，一張一弛，現休息一下。

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
第三章 FOR命令中的變數
FOR命令中有一些變數,他們的用法許多新手朋友還不太瞭解,今天給大家講解他們的用法!

先把FOR的變數全部列出來:
   ~I       - 刪除任何引號(")，擴充套件 %I
   %~fI       - 將 %I 擴充套件到一個完全合格的路徑名
   %~dI       - 僅將 %I 擴充套件到一個驅動器號
   %~pI       - 僅將 %I 擴充套件到一個路徑
   %~nI       - 僅將 %I 擴充套件到一個檔名
   %~xI       - 僅將 %I 擴充套件到一個副檔名
   %~sI       - 擴充套件的路徑只含有短名
   %~aI       - 將 %I 擴充套件到檔案的檔案屬性
   %~tI       - 將 %I 擴充套件到檔案的日期/時間
   %~zI       - 將 %I 擴充套件到檔案的大小
   %~$PATH:I - 查詢列在路徑環境變數的目錄，並將 %I 擴充套件
               到找到的第一個完全合格的名稱。如果環境變數名
               未被定義，或者沒有找到檔案，此組合鍵會擴充套件到
               空字串

我們可以看到每行都有一個大寫字母"I",這個I其實就是我們在FOR帶入的變數,我們FOR語句代入的變數名是什麼,這裡就寫什麼.
比如:FOR /F  %%z IN ('set') DO @echo %%z
這裡我們代入的變數名是z那麼我們就要把那個I改成z,例如%~fI改為%~fz
至於前面的%~p這樣的內容就是語法了!

好開始講解:

一、 ~I          - 刪除任何引號(")，擴充套件 %I
這個變數的作用就如他的說明,刪除引號!
我們來看這個例子:
首先建立臨時檔案temp.txt，內容如下
"1111
"2222"
3333"
"4444"44
"55"55"55
可建立個BAT檔案程式碼如下:
@echo off
echo ^"1111>temp.txt
echo "2222">>temp.txt
echo 3333^">>temp.txt
echo "4444"44>>temp.txt
echo ^"55"55"55>>temp.txt
rem 上面建立臨時檔案，注意不成對的引號要加轉義字元^，重定向符號前不要留空格
FOR /F "delims=" %%i IN (temp.txt) DO echo  %%~i
pause
del temp.txt
執行後,我們看CMD的回顯如下:
1111          #字串前的引號被刪除了
2222          #字串首尾的引號都被刪除了
3333"       #字串前無引號，後面的引號保留
4444"44       #字串前面的引號刪除了，而中間的引號保留
55"55"55    #字串前面的引號刪除了，而中間的引號保留
請按任意鍵繼續. . .
和之前temp.txt中的內容對比一下,我們會發現第1、2、5行的引號都消失了,這就是刪除引號~i的作用了!
刪除引號規則如下(BAT兄補充!)
1、若字串首尾同時存在引號，則刪除首尾的引號；
2、若字串尾不存在引號，則刪除字串首的引號；
3、如果字串中間存在引號，或者只在尾部存在引號，則不刪除。
龍捲風補充：無頭不刪，有頭連尾刪。

二、 %~fI       - 將 %I 擴充套件到一個完全合格的路徑名
看例子:
把程式碼儲存放在隨便哪個地方,我這裡就放桌面吧.
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~fi
pause
執行後顯示內容如下
C:\Documents and Settings\Administrator\桌面\test.bat
C:\Documents and Settings\Administrator\桌面\test.vbs
當我把程式碼中的 %%~fi直接改成%%i
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%i
pause
執行後就會顯示以下內容：
test.bat
test.vbs
通過對比,我們很容易就看出沒有路徑了,這就是"將 %I 擴充套件到一個完全合格的路徑名"的作用
也就是如果%i變數的內容是一個檔名的話,他就會把這個檔案所在的絕對路徑打印出來,而不只單單列印一個檔名,自己動手動實驗下就知道了!

三、 %~dI       - 僅將 %I 擴充套件到一個驅動器號
看例子:
程式碼如下,我還是放到桌面執行!
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~di
pause
執行後我CMD裡顯示如下
C:
C:
我桌面就兩個檔案test.bat,test.vbs,%%~di作用是,如果變數%%i的內容是一個檔案或者目錄名,他就會把他這檔案
或者目錄所在的碟符號打印出來!

四、 %~pI       - 僅將 %I 擴充套件到一個路徑
這個用法和上面一樣,他只打印路徑不列印檔名字
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~pi
pause
我就不打結果了,大家自己複製程式碼看結果吧,下面幾個都是這麼個用法,程式碼給出來,大家自己看結果吧!

五、 %~nI       - 僅將 %I 擴充套件到一個檔名
只打印檔名字
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~ni
pause

六、 %~xI       - 僅將 %I 擴充套件到一個副檔名
只打印檔案的副檔名
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~xi
pause

七、 %~sI       - 擴充套件的路徑只含有短名
列印絕對短檔名
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~si
pause

八、 %~aI       - 將 %I 擴充套件到檔案的檔案屬性
列印檔案的屬性
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~ai
pause

九、 %~tI       - 將 %I 擴充套件到檔案的日期/時間
列印檔案建立的日期
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~ti
pause

十、 %~zI       - 將 %I 擴充套件到檔案的大小
列印檔案的大小
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~zi
pause
上面例子中的"delims=="可以改為"delims="，即不要分隔符

十一、 %~$PATH:I - 查詢列在路徑環境變數的目錄

並將 %I 擴充套件到找到的第一個完全合格的名稱。如果環境變數名未被定義，或者沒有找到檔案，此組合鍵會擴充套件到空字串
這是最後一個,和上面那些都不一樣,我單獨說說!

然後在把這些程式碼儲存為批處理,放在桌面。
@echo off
FOR /F "delims=" %%i IN (“notepad.exe”) DO echo %%~$PATH:i
pause
龍捲風補充：上面程式碼顯示結果為C:\WINDOWS\system32\notepad.exe
他的意思就在PATH變數裡指定的路徑裡搜尋notepad.exe檔案，如果有notepad.

BAT 批處理指令碼教程 BAT 批處理指令碼教程 DOS的重定向命令及在安全方面的應用