深入理解呼叫門

    呼叫門用於 向高特權級的程式碼段轉移（CPL >= DPLobject）     呼叫門描述符的特權級 低於當前特權級（CPL <= DPLgate）     

關於呼叫門的注意事項之一

    呼叫門支援特權級 同級轉移     呼叫門 同級轉移被處理為普通函式呼叫或直接跳轉     call通過呼叫門能提升特權級， jmp通過呼叫門只能同級轉移     通過呼叫門降特權級返回（ retf）時         對目的碼段以及棧段進行 特權級檢查         對相關段暫存器 強制清零（指向高特權級資料的段暫存器）

小結

    呼叫門的使用（數值上）： DPLobject <= CPL <= DPLgate     呼叫門支援同級轉移（ jmp指令只能同級轉移）     retf對棧的檢查： CS.RPL == SS.RPL == SS.DPL     特權級降低轉移時，相關段暫存器的值將被清零

程式碼

// loader.asm
%include "inc.asm"                            ; 載入標頭檔案，一些常量、設定函式
 
org 0x9000                                    ; 記憶體載入地址
 
jmp ENTRY_SEGMENT                            ; 跳轉到ENTRY_SEGMENT入口處
 
[section .gdt]                                
 
; 全域性描述符表，部分段基址未知基址需使用時再調節（InitDescItem）
; GDT definition        8Byte 64bit
;                        "函式名"    段基址        段界限                    段屬性
GDT_ENTRY        :        Descriptor    0,            0,                        0                ; 全域性段描述符表第0項不使用
CODE32_DESC        :        Descriptor    0,            Code32SegLen - 1,        DA_C    + DA_32    + DA_DPL2
VIDEO_DESC        :        Descriptor    0xB8000,    0x07FFF,                DA_DRWA + DA_32    + DA_DPL2; 視訊段描述符表設定正確無須初始化
DATA32_DESC_0    :        Descriptor    0,            Data32SegLen0 - 1,        DA_DR    + DA_32    + DA_DPL0
DATA32_DESC_2    :        Descriptor    0,            Data32SegLen2 - 1,        DA_DR    + DA_32    + DA_DPL2
STACK32_DESC_0    :        Descriptor    0,            TopOfStack320,            DA_DRW  + DA_32    + DA_DPL0
STACK32_DESC_2    :        Descriptor    0,            TopOfStack322,            DA_DRW  + DA_32    + DA_DPL2
TSS_DESC        :        Descriptor    0,            TSSLen     -         1,        DA_386TSS        + DA_DPL0
FUNCTION_DESC    :        Descriptor    0,            FunctionSegLen -1,        DA_C    + DA_32 + DA_DPL0
; Call Gate
;                                        選擇子                偏移        引數個數            屬性
FUNC_PRINTSTRING_DESC    :    Gate    FunctionSelector,    PrintString,    0,    DA_386CGate + DA_DPL3
; GDT end
 
GdtLen    equ    $ - GDT_ENTRY
 
GdtPtr:                                        ; 全域性描述符表指標
        dw    GdtLen - 1    ; 偏移，記錄描述符數量
        dd    0            ; 全域性描述符起始地址，先設定為0
 
 
; GDT Selector        2Byte 16bit    TI：全域性、區域性    RPL：請求許可權級別
Code32Selector        equ    (0x0001 << 3) + SA_TIG + SA_RPL2    ; 0x0001==第二個選擇子
VideoSelector        equ (0x0002 << 3) + SA_TIG + SA_RPL2    ; 視訊記憶體特權級低只會影響顯示，對系統安全無影響
Data32Selector0        equ (0x0003 << 3) + SA_TIG + SA_RPL0
Data32Selector2        equ (0x0004 << 3) + SA_TIG + SA_RPL2
Stack32Selector0    equ (0x0005 << 3) + SA_TIG + SA_RPL0
Stack32Selector2    equ (0x0006 << 3) + SA_TIG + SA_RPL2
TSSSelector            equ (0x0007 << 3) + SA_TIG + SA_RPL0
FunctionSelector    equ (0x0008 << 3) + SA_TIG + SA_RPL0
; Gate Selector
FuncPrintStringSelector    equ    (0x0009 << 3) + SA_TIG + SA_RPL3
; end of [section .gdt]
 
TopOfStack16 equ 0x7c00
 
[section .s16]    ; 真實模式程式碼段（16bit）
[bits 16]        ; 使用16位編譯
ENTRY_SEGMENT:                                ; 16位保護模式入口段
    mov ax, cs                    ; 初始化相關暫存器
    mov ds, ax
    mov es, ax
    mov ss, ax
    mov sp, TopOfStack16
 
            ; initialize GDT for 32 bits code segment
    mov esi, CODE32_SEGMENT        ; 初始化32位程式碼段、資料段、棧段描述符
    mov edi, CODE32_DESC
 
    call InitDescItem
    ;  視訊段描述符表設定正確無須初始化
    mov esi, DATA32_SEGMENT_0
    mov edi, DATA32_DESC_0
 
    call InitDescItem
    
    mov esi, DATA32_SEGMENT_2
    mov edi, DATA32_DESC_2
    
    call InitDescItem
        
    mov esi, STACK32_SEGMENT_0
    mov edi, STACK32_DESC_0
 
    call InitDescItem
 
    mov esi, STACK32_SEGMENT_2
    mov edi, STACK32_DESC_2
 
    call InitDescItem
    
    mov esi, FUNCTION_SEGMENT
    mov edi, FUNCTION_DESC
 
    call InitDescItem
    
    mov esi, TSS_SEGMENT        ; 初始化TSS任務段
    mov edi, TSS_DESC
 
    call InitDescItem
 
    
            ; initialize GDT pointer struct
    mov eax, 0                    ; 程式碼段地址左移4位
    mov ax, ds
    shl eax, 4
    add eax, GDT_ENTRY            ; 程式碼段偏移地址==> 左移過後的程式碼段+全域性描述符表入口地址偏移量
    mov dword [GdtPtr + 2], eax    ; 寫入全域性描述符表指標
 
            ; 1. load GDT
    lgdt [GdtPtr]                ; 載入全域性描述符表
 
            ; 2. close interrupt
    cli                            ; 關閉中斷
 
            ; 3. open A20
    in al, 0x92                    ; 通過0x92埠開啟A20地址線開關
    or al, 00000010b
    out 0x92, al
 
            ; 4. enter protect mode
    mov eax, cr0                ; 設定cr0暫存器，進入保護模式
    or eax, 0x01
    mov cr0, eax
    
            ; 5. load TSS
    mov ax, TSSSelector
    ltr ax
 
            ; 6. jump to 32 bits code
    push Stack32Selector2        ;jmp dword Code32Selector : 0 ; 使用jmp跳轉到32位程式碼段選擇子的0偏移處
    push TopOfStack322
    push Code32Selector
    push 0
    retf                        ; 彈出2個棧，分別給IP、CS暫存器
    
    
 
; esi    --> code segment label
; edi    --> descriptor label
InitDescItem:                                ; 初始化描述符專案
    push eax
    
    mov eax, 0                        ; 程式碼段地址左移4位
    mov ax, cs
    shl eax, 4                        ; 實地址=段暫存器地址左移4位+偏移地址
    add eax, esi
    mov word [edi + 2], ax            ; 將段基址寫入描述符2個位元組（16位暫存器），低32位的16-31bit（偏移2位元組）
    shr eax, 16                        ; 移除eax實地址中已經寫入段基址的2位元組資料
    mov byte [edi + 4], al            ; 將段基址寫入描述符1個位元組(8位暫存器)，高32位的0-7bit（偏移4+0=4位元組）
    mov byte [edi + 7], ah            ; 將段基址寫入描述符1個位元組(8位暫存器)，高32位的24-31bit（偏移4+3=7位元組）
 
    pop eax
    
    ret
 
[section .dat0]
[bits 32]
DATA32_SEGMENT_0:
    DPL0            db    "DPL = 0", 0
    DPL0_OFFSET        equ    DPL0 - $$
    
Data32SegLen0 equ $ - DATA32_SEGMENT_0
 
[section .dat2]
[bits 32]
DATA32_SEGMENT_2:
    DPL2            db    "DPL = 2", 0
    DPL2_OFFSET        equ    DPL2 - $$
    
Data32SegLen2 equ $ - DATA32_SEGMENT_2
 
[section .tss]                    ; TSS任務段104位元組，另可附加額外資訊
[bits 32]
TSS_SEGMENT:
        dd    0                    ; 保留前一個TSS段選擇子，由CPU填寫，高位填0
        dd    TopOfStack320        ; 0特權級棧指標
        dd    Stack32Selector0    ; 0特權級棧段選擇子，只能用低2個位元組，高位填0
        dd    0                    ; 1特權級
        dd    0                    ;
        dd    0                    ; 2特權級
        dd    0                    ;
        times 4 * 18 dd 0        ; 用於切換暫存器的值，由CPU填寫，共18個dd型別
        dw    0                    ; 最低位為除錯陷阱標誌T，其餘為0
        dw    $ - TSS_SEGMENT + 2    ; I/O Map Base Address
        db    0xFF                ; 結束標記，屬於額外資訊
        
TSSLen    equ    $ - TSS_SEGMENT
 
[section .s32]    ; 32位程式碼段
[bits 32]        ; 使用32位編譯
CODE32_SEGMENT:                                ; 32位程式碼段資料
    mov ax, VideoSelector            ; 把視訊段選擇子放到gs全域性段暫存器
    mov gs, ax
 
    mov ax, Data32Selector2            ; 設定資料段地址
    mov ds, ax
    
    mov ebp, DPL2_OFFSET            ; 全域性函式列印字串，使用選擇子：偏移量呼叫
    mov bx, 0x0c
    mov dh, 12
    mov dl, 33
    
    call FuncPrintStringSelector : 0
    
    jmp $
 
Code32SegLen    equ        $ - CODE32_SEGMENT
 
 
[section .func]
[bits 32]
FUNCTION_SEGMENT:
 
; ds:ebp        --> string address
; bx            --> attribute
; dx            --> dh : row, dl : col
PrintStringFunc:
    push ebp
    push eax
    push edi
    push cx
    push dx
    
Print:
    mov cl, [ds:ebp]        ; 取一個字元
    cmp cl, 0                ; 結束符判斷
    je end
    mov eax, 80                ; 每行字元列數
    mul dh                    ; 乘以行數
    ;add al, dl             ; 總偏移字元數，al太小超過255會溢位（3*80+16==3行16列）
    push dx                 ; 備份dx（dh），供迴圈呼叫避免丟失行號
    mov dh, 0               ; dx高位置0，確保dx=dl
    add ax, dx              ; 總偏移字元數（65536個字元）
    pop dx
    shl eax, 1                ; 每個字元佔2位元組
    mov edi, eax
    mov ah, bl                ; 字元屬性
    mov al, cl                ; 字元
    mov [gs:edi], ax        ; 寫入視訊記憶體
    inc ebp                    ; 字元源地址遞增
    inc dl                    ; 視訊記憶體字元地址遞增
    jmp Print
    
end:
    pop dx
    pop cx
    pop edi
    pop eax
    pop ebp
    
    mov ax, Data32Selector0
    mov ds, ax
    mov gs, ax
 
    retf
    
PrintString        equ PrintStringFunc - $$
 
FunctionSegLen    equ $ - FUNCTION_SEGMENT
    
[section .gs0]
[bits 32]
STACK32_SEGMENT_0:                            ; 32位棧段定義
    times 1024 * 4 db 0
 
Stack32SegLen0 equ $ - STACK32_SEGMENT_0
TopOfStack320 equ Stack32SegLen0 - 1
 
[section .gs2]
[bits 32]
STACK32_SEGMENT_2:                            ; 32位棧段定義
    times 1024 * 4 db 0
 
Stack32SegLen2 equ $ - STACK32_SEGMENT_2
TopOfStack322 equ Stack32SegLen2 - 1