#1，摘要 【本文目標】 通過本文學習，可以實現區塊鏈私募，基金會員工期權(代幣)激勵時鎖倉一定時間，逐步釋放的方法。

【前置條件】 1）已經完成了一個ERC20的代幣，本文以作者接觸的CLB為樣例。 2） 懂得在REMIX除錯SOLIDITY語言，不熟悉的參考文章《第十課 Solidity語言編輯器REMIX指導大全》。

#2，需求實現描述 一般區塊鏈專案在私募或者員工溝通時，都會明確代幣發放的政策，一般來說都會要求專案上線後鎖倉多久，分幾年釋放。如果通過合同的方式來人工操作，一個是實現比較麻煩或者存在不可控性，另一方面也存在無法取信私募機構或者員工的情況。 那麼專業的團隊會選擇通過智慧合約來實現，這是更可信、公開、且不可串改的最佳方式。 這個實現概括講包括3步：

#3，鎖倉智慧合約分析 鎖倉智慧合約核心程式碼：

/**
 * @title TokenVesting
 * @dev A token holder contract that can release its token balance gradually like a
 * typical vesting scheme, with a cliff and vesting period. Optionally revocable by the
 * owner.
 */
contract TokenVesting is Ownable {
  using SafeMath for uint256;
  using SafeERC20 for Colorbay;

  event Released(uint256 amount);
  event Revoked();

  // beneficiary of tokens after they are released
  address public beneficiary;

  uint256 public cliff;
  uint256 public start;
  uint256 public duration;

  bool public revocable;

  mapping (address => uint256) public released;
  mapping (address => bool) public revoked;

  /**
   * @dev Creates a vesting contract that vests its balance of any ERC20 token to the
   * _beneficiary, gradually in a linear fashion until _start + _duration. By then all
   * of the balance will have vested.
   * @param _beneficiary address of the beneficiary to whom vested tokens are transferred
   * @param _cliff duration in seconds of the cliff in which tokens will begin to vest
   * @param _start the time (as Unix time) at which point vesting starts
   * @param _duration duration in seconds of the period in which the tokens will vest
   * @param _revocable whether the vesting is revocable or not
   */
  constructor(
    address _beneficiary,
    uint256 _start,
    uint256 _cliff,
    uint256 _duration,
    bool _revocable
  )
    public
  {
    require(_beneficiary != address(0));
    require(_cliff <= _duration);

    beneficiary = _beneficiary;
    revocable = _revocable;
    duration = _duration;
    cliff = _start.add(_cliff);
    start = _start;
  }

  /**
   * @notice Transfers vested tokens to beneficiary.
   * @param _token Colorbay token which is being vested
   */
  function release(Colorbay _token) public {
    uint256 unreleased = releasableAmount(_token);

    require(unreleased > 0);

    released[_token] = released[_token].add(unreleased);

    _token.safeTransfer(beneficiary, unreleased);

    emit Released(unreleased);
  }

  /**
   * @notice Allows the owner to revoke the vesting. Tokens already vested
   * remain in the contract, the rest are returned to the owner.
   * @param _token ERC20 token which is being vested
   */
  function revoke(Colorbay _token) public onlyOwner {
    require(revocable);
    require(!revoked[_token]);

    uint256 balance = _token.balanceOf(address(this));

    uint256 unreleased = releasableAmount(_token);
    uint256 refund = balance.sub(unreleased);

    revoked[_token] = true;

    _token.safeTransfer(owner, refund);

    emit Revoked();
  }

  /**
   * @dev Calculates the amount that has already vested but hasn't been released yet.
   * @param _token Colorbay token which is being vested
   */
  function releasableAmount(Colorbay _token) public view returns (uint256) {
    return vestedAmount(_token).sub(released[_token]);
  }

  /**
   * @dev Calculates the amount that has already vested.
   * @param _token ERC20 token which is being vested
   */
  function vestedAmount(Colorbay _token) public view returns (uint256) {
    uint256 currentBalance = _token.balanceOf(this);
    uint256 totalBalance = currentBalance.add(released[_token]);
    
    if (block.timestamp < cliff) {
      return 0;
    } else if (block.timestamp >= start.add(duration) || revoked[_token]) {
      return totalBalance;
    } else {
      return totalBalance.mul(block.timestamp.sub(start)).div(duration);
    }
  }
}
 

函式說明： 1，鎖倉合約初始化函式constructor(…)，包含5個引數：

• address _beneficiary：接受通證投放的收益賬戶；
• uint256 _start： 起始時間（Unix time），提示從什麼時刻開始計時；
• uint256 _cliff： 單位為秒（s），斷崖時間，例如“鎖倉4年，1年之後一次性解凍25%”中的1年
• uint256 _duration： 單位為秒（s），持續鎖倉時間，例如“鎖倉4年，1年之後一次性解凍25%”中的4年；
• bool _revocable： 是否可回收 （例如公司給了員工張三 10K 代幣鎖倉4年，張三在工作一年的時候離職了，剩餘的部分公司是否可回收） 舉例來說明：
  如果 _cliff=半年 ，_duration=1年 具體解凍情況如下： Month 1: I get 0 tokens Month 2: I get 0 tokens Month 3: I get 0 tokens Month 4: I get 0 tokens Month 5: I get 0 tokens Month 6: I get 0 tokens — End of cliff Month 7: I get 700 tokens (7/12th) Month 8: I get 100 tokens (8/12th) Month 9: I get 100 tokens (9/12th) Month 10: I get 100 tokens (10/12th) Month 11: I get 100 tokens (11/12th) Month 12: I get 100 tokens (12/12th)

2，期權代幣釋放函式release(…)，包含1個引數：

• Colorbay _token：_token為CLB代幣的例項引數，時間到後通過該函式釋放給對應的收益賬戶；

3，期權代幣回收函式revoke(…)，包含1個引數：

• Colorbay _token：_token為CLB代幣的例項引數，把未釋放的代幣打回給之前的分配賬戶池；

完整的程式碼和CLB通證的呼叫函式，輝哥存放到知識星球，歡迎加入下載。

#3, 測試用例驗證 1] 管理員賬號釋出一個ERC20的ColorBay代幣合約

• 管理員地址： 0xca35b7d915458ef540ade6068dfe2f44e8fa733c
• 代幣合約資訊如下： (1) decimals = 18; (2) totalSupply() = 10億； (3) symbol = CLB (4) paused = false (5) owner = 0xca35b7d915458ef540ade6068dfe2f44e8fa733c (6) contract address = 0x692a70d2e424a56d2c6c27aa97d1a86395877b3a

2] 管理員賬號轉發500萬給員工激勵專用賬號用於期權激勵專用

• 管理員地址： 0xca35b7d915458ef540ade6068dfe2f44e8fa733c
• 員工激勵專用賬號地址： 0x14723a09acff6d2a60dcdf7aa4aff308fddc160c
• 轉賬操作：(記得去除500萬後面的",") transfer(“0x14723a09acff6d2a60dcdf7aa4aff308fddc160c”, “5000000,000000000000000000”) 【結果驗證】 balanceOf(“0x14723a09acff6d2a60dcdf7aa4aff308fddc160c”) 檢查確認餘額為500萬CLB。

3] 當前賬號切換到員工激勵專用賬號下建立期權激勵計劃

• 場景假設： 激勵計劃起始時間為[2018.08.06 20:25]，2分鐘內不得釋放，持續5分鐘(300s),支援回收未釋放的期權
• 員工激勵專用賬號地址： 0x14723a09acff6d2a60dcdf7aa4aff308fddc160c
• 被員工李四的私人收益賬號地址： 0x4b0897b0513fdc7c541b6d9d7e929c4e5364d2db
• 呼叫函式： constructor(“0x4b0897b0513fdc7c541b6d9d7e929c4e5364d2db”, “1533558300”, “120”, “300”, true) 【說明】如何獲得準確的起始時間，可用站長工具輸入具體時間來轉換。
• 期權激勵智慧合約例項建立成功資訊如下： (1) contract address = 0x0fdf4894a3b7c5a101686829063be52ad45bcfb7

4] 在CLB合約下，把CLB通證打給期權激勵智慧合約地址

• 切換到員工激勵專用賬號 0x14723a09acff6d2a60dcdf7aa4aff308fddc160c
• 執行轉賬操作，（記得去除100萬後面的","） transfer(“0x0fdf4894a3b7c5a101686829063be52ad45bcfb7”, “1000000,000000000000000000”)
• 結果 balanceOf(“0x0fdf4894a3b7c5a101686829063be52ad45bcfb7”) 檢查確認餘額為100萬，表示CLB代幣已經轉給期權激勵智慧合約了。

5] [2018.08.06 17:31] 5分鐘(300s)後測試分配期權

• 執行期權是否操作 release(“0x692a70d2e424a56d2c6c27aa97d1a86395877b3a”)
• 切換到CLB合約下，查詢李四私人賬號 balanceOf(“0x4b0897b0513fdc7c541b6d9d7e929c4e5364d2db”) 檢查確認餘額為100萬，轉賬成功。

6] 離職員工激勵計劃實施

• 場景假設 當前賬號切換到員工激勵專用賬號下建立期權激勵計劃，假定給員工王五做的激勵，起始時間為[2018.08.06 21:00]，2分鐘內不得釋放，持續5分鐘(300s),支援回收期權。王五在4分鐘的時候離職，公司收回未激勵代幣，打回到員工激勵專用賬號下。

• 員工激勵專用賬號： 0x14723a09acff6d2a60dcdf7aa4aff308fddc160c

• 被員工王五私人收益賬號： 0x583031d1113ad414f02576bd6afabfb302140225

• 執行操作： constructor(“0x583031d1113ad414f02576bd6afabfb302140225”, “1533560400”, “120”, “300”, true)

• 期權激勵智慧合約資訊如下： contract address = 0x15e08fa9fe3e3aa3607ac57a29f92b5d8cb154a2

7] 在CLB合約下，通證打給期權激勵智慧合約地址

• 切換到員工激勵專用賬號，在CLB合約下操作 0x14723a09acff6d2a60dcdf7aa4aff308fddc160c
• 王五期權激勵智慧合約例項地址： 0x15e08fa9fe3e3aa3607ac57a29f92b5d8cb154a2
• 具體操作（記得去除100萬後面的","） transfer(“0x15e08fa9fe3e3aa3607ac57a29f92b5d8cb154a2”, “1000000,000000000000000000”)
• 查詢王五期權激勵智慧合約的賬戶餘額： balanceOf(“0x15e08fa9fe3e3aa3607ac57a29f92b5d8cb154a2”) 檢查確認餘額為100萬
• 查詢員工期權激勵智慧合約的賬戶餘額： balanceOf(“0x14723a09acff6d2a60dcdf7aa4aff308fddc160c”) 檢查確認餘額為300萬

8] [2018.08.06 21:03] 3分鐘(180s)後測試分配期權

• 2分鐘內操作release均會失敗回滾。21:03操作釋放函式： release(“0x692a70d2e424a56d2c6c27aa97d1a86395877b3a”)
• 切換到CLB合約下，查詢王五私人賬號 balanceOf(“0x583031d1113ad414f02576bd6afabfb302140225”) 檢查有76萬代幣釋放到王五收益賬戶。

9] [2018.08.06 21:05] 4分鐘(240s)後，李四離職，收回分配期權 revoke(“0x692a70d2e424a56d2c6c27aa97d1a86395877b3a”)

• 切換到CLB合約下，查詢李四私人賬號 balanceOf(“0x583031d1113ad414f02576bd6afabfb302140225”) 檢查有76萬代幣在王五收益賬戶，沒有增加。

• 查詢員工專用賬戶餘額 balanceOf(“0x14723a09acff6d2a60dcdf7aa4aff308fddc160c”) 發現王五剩餘未釋放的額度全部返回到員工專用賬號了。

#4， 商用實現需求 輝哥給了一個命題需求，看看誰能把這個需求實現。除了功能，要提供網頁查詢頁面，使用者輸入以太坊地址，可以查到對應賬戶的期權代幣總額，已釋放額度，未釋放額度。

某專案方釋出10億的代幣總額，其中： 1] 機構方私募為 1.5 億枚， 上交易所後私募鎖倉三個月，之後逐月釋放 20%； 2] 基金會核心運作團隊持有 2 億枚， 鎖定一年， 兩年內逐步釋放； 3] 社群建設 1 億枚， 海外社群核心團隊， 鎖定一年，兩年內逐步釋放；

轉化為具體的時間點動作為： 1] 私募總額1.5億枚，2018.09.01上交易所，私募鎖倉三個月到2018.12.01到期，之後逐月釋放情況 [2019.01.01 - 20%, 3000萬枚; 2019.02.01 - 20%, 3000萬枚; 2019.03.01 - 20%, 3000萬枚; 2019.04.01 20%, 3000萬枚; 2019.05.01 20%, 3000萬枚; ] 2] 基金會核心運作團隊 2億枚,2018.09.01上交易所，鎖定一年到2019.09.01， 兩年內按月逐步釋放； [2019.10.01 - 2億1/24, 約833萬枚; …; 2020.10.01 - 2億1/24, 約833萬枚;] 3] 海外社群核心團隊 1 億枚，2018.09.01上交易所，鎖定一年到2019.09.01，兩年內逐步釋放； [2019.10.01 - 1億1/24, 約416萬枚; …; 2020.10.01 - 1億1/24, 約416萬枚;]

我們已完成該商用合約的編碼，取得了鏈安科技的合約審計驗收。有需要合作的可勾搭下下。