AWR報告獲取指令碼

在實際的使用過程中發現，當撈取較長時間的AWR報告時，例如過去24小時的AWR報告（通常以1小時或者半小時為單位獲取），則需要執行24次獲取AWR報告的操作（獲取AWR報告的相關操作可以參見：https://blog.csdn.net/yingdovezuo/article/details/84772125）

於是針對此批量獲取AWR報告有編寫如下指令碼
首先以sysdba的方式進入資料庫

su - oracle
sqlplus / as sysdba

由於獲取的AWR報告數量較多，建議新建一個資料夾
先建立一個資料夾

mkdir  /home/oracle/awr_dir
 

建立完成後，制定新建立的路徑為存放AWR報告的路徑

CREATE OR REPLACE DIRECTORY awr_reports_dir AS '/home/oracle/awr_dir';（其中引號內的為對應的新建的資料夾的路徑）

首先按照常規獲取AWR報告的方式，獲取所需時間區間的Snap ID
之後，執行如下指令碼（在第三行與第四行分別輸入開始與結束時間點的Snap ID）

DECLARE
  -- Adjust before use.
  l_snap_start       NUMBER := 13373（此欄位輸入開始時間的Snap ID）;   
  l_snap_end         NUMBER := 13397（此欄位輸入結束時間的Snap ID）;
  l_dir              VARCHAR2(50) := 'AWR_REPORTS_DIR';
  
  l_last_snap        NUMBER := NULL;
  l_dbid             v$database.dbid%TYPE;
  l_instance_number  v$instance.instance_number%TYPE;
  l_file             UTL_FILE.file_type;
  l_file_name        VARCHAR(50);
 
BEGIN
  SELECT dbid
  INTO   l_dbid
  FROM   v$database;
 
  SELECT instance_number
  INTO   l_instance_number
  FROM   v$instance;
    
  FOR cur_snap IN (SELECT snap_id
                   FROM   dba_hist_snapshot
                   WHERE  instance_number = l_instance_number
                   AND    snap_id BETWEEN l_snap_start AND l_snap_end
                   ORDER BY snap_id)
  LOOP
    IF l_last_snap IS NOT NULL THEN
      l_file := UTL_FILE.fopen(l_dir, 'awr_' || l_last_snap || '_' || cur_snap.snap_id || '.htm', 'w', 32767);
      
      FOR cur_rep IN (SELECT output
                      FROM   TABLE(DBMS_WORKLOAD_REPOSITORY.awr_report_html(l_dbid, l_instance_number, l_last_snap, cur_snap.snap_id)))
      LOOP
        UTL_FILE.put_line(l_file, cur_rep.output);
      END LOOP;
      UTL_FILE.fclose(l_file);
    END IF;
    l_last_snap := cur_snap.snap_id;
  END LOOP;
  
EXCEPTION
  WHEN OTHERS THEN
    IF UTL_FILE.is_open(l_file) THEN
      UTL_FILE.fclose(l_file);
    END IF;
    RAISE; 
END;
 

上述Script也可直接通過PL/SQL 、SQL Developer等工具直接執行，相比較在putty中執行，可以更顯著的看到指令碼執行的狀態

執行完上述語句後需要稍等片刻，當系統提示

PL/SQL procedure successfully completed.

即代表已生成所需的AWR報告
至對應的路徑下’/home/oracle/awr_dir獲取相關報告即可

建議通過winscp介面可以直接獲取相關的AWR報告