深入解析 Autoreleasepool

阿新 • • 發佈：2018-12-24

由於 Objective-C 中的記憶體管理是一個比較大的話題，所以會分為兩篇文章來對記憶體管理中的一些機制進行剖析，一部分分析自動釋放池以及 autorelease 方法，另一部分分析 retain、release 方法的實現以及自動引用計數。

這篇文章會在原始碼層面介紹 Objective-C 中自動釋放池，以及方法的 autorelease 的具體實現。

從 main 函式開始

main 函式可以說是在整個 iOS 開發中非常不起眼的一個函式，它很好地隱藏在 Supporting Files 資料夾中，卻是整個 iOS 應用的入口。

objc-autorelease-main

main.m 檔案中的內容是這樣的：

int main(int argc, char * argv[]) {
    @autoreleasepool {
        return UIApplicationMain(argc, argv, nil, NSStringFromClass([AppDelegate class]));
    }
}

在這個 @autoreleasepool block 中只包含了一行程式碼，這行程式碼將所有的事件、訊息全部交給了 UIApplication 來處理，但是這不是本文關注的重點。

需要注意的是：整個 iOS 的應用都是包含在一個自動釋放池 block 中的

。

@autoreleasepool

@autoreleasepool 到底是什麼？我們在命令列中使用 clang -rewrite-objc main.m 讓編譯器重新改寫這個檔案：

$ clang -rewrite-objc main.m

在生成了一大堆警告之後，當前目錄下多了一個 main.cpp 檔案

objc-autorelease-main-cpp

這裡刪除了 main 函式中其他無用的程式碼。

在這個檔案中，有一個非常奇怪的 __AtAutoreleasePool 的結構體，前面的註釋寫到 /* @autoreleasepopl */

。也就是說 @autoreleasepool {} 被轉換為一個 __AtAutoreleasePool 結構體：

{
    __AtAutoreleasePool __autoreleasepool;
}

想要弄清楚這行程式碼的意義，我們要在 main.cpp 中查詢名為 __AtAutoreleasePool 的結構體：

objc-autorelease-main-cpp-struct

struct __AtAutoreleasePool {
  __AtAutoreleasePool() {atautoreleasepoolobj = objc_autoreleasePoolPush();}
  ~__AtAutoreleasePool() {objc_autoreleasePoolPop(atautoreleasepoolobj);}
  void * atautoreleasepoolobj;
};

這個結構體會在初始化時呼叫 objc_autoreleasePoolPush() 方法，會在析構時呼叫 objc_autoreleasePoolPop 方法。

這表明，我們的 main 函式在實際工作時其實是這樣的：

int main(int argc, const char * argv[]) {
    {
        void * atautoreleasepoolobj = objc_autoreleasePoolPush();
        
        // do whatever you want
        
        objc_autoreleasePoolPop(atautoreleasepoolobj);
    }
    return 0;
}

@autoreleasepool 只是幫助我們少寫了這兩行程式碼而已，讓程式碼看起來更美觀，然後要根據上述兩個方法來分析自動釋放池的實現。

AutoreleasePool 是什麼

這一節開始分析方法 objc_autoreleasePoolPush 和 objc_autoreleasePoolPop 的實現：

void *objc_autoreleasePoolPush(void) {
    return AutoreleasePoolPage::push();
}

void objc_autoreleasePoolPop(void *ctxt) {
    AutoreleasePoolPage::pop(ctxt);
}

上面的方法看上去是對 AutoreleasePoolPage 對應靜態方法 push 和 pop 的封裝。

這一小節會按照下面的順序逐步解析程式碼中的內容：

AutoreleasePoolPage 的結構
objc_autoreleasePoolPush 方法
objc_autoreleasePoolPop 方法

AutoreleasePoolPage 的結構

AutoreleasePoolPage 是一個 C++ 中的類：

objc-autorelease-AutoreleasePoolPage

它在 NSObject.mm 中的定義是這樣的：

class AutoreleasePoolPage {
    magic_t const magic;
    id *next;
    pthread_t const thread;
    AutoreleasePoolPage * const parent;
    AutoreleasePoolPage *child;
    uint32_t const depth;
    uint32_t hiwat;
};

magic 用於對當前 AutoreleasePoolPage 完整性的校驗
thread 儲存了當前頁所在的執行緒

每一個自動釋放池都是由一系列的 AutoreleasePoolPage 組成的，並且每一個 AutoreleasePoolPage 的大小都是 4096 位元組（16 進位制 0x1000）

#define I386_PGBYTES 4096
#define PAGE_SIZE I386_PGBYTES

雙向連結串列

自動釋放池中的 AutoreleasePoolPage 是以雙向連結串列的形式連線起來的：

objc-autorelease-AutoreleasePoolPage-linked-list

parent 和 child 就是用來構造雙向連結串列的指標。

自動釋放池中的棧

如果我們的一個 AutoreleasePoolPage 被初始化在記憶體的 0x100816000 ~ 0x100817000 中，它在記憶體中的結構如下：

objc-autorelease-page-in-memory

其中有 56 bit 用於儲存 AutoreleasePoolPage 的成員變數，剩下的 0x100816038 ~ 0x100817000 都是用來儲存加入到自動釋放池中的物件。

begin() 和 end() 這兩個類的例項方法幫助我們快速獲取 0x100816038 ~ 0x100817000 這一範圍的邊界地址。

next 指向了下一個為空的記憶體地址，如果 next 指向的地址加入一個 object，它就會如下圖所示移動到下一個為空的記憶體地址中：

objc-autorelease-after-insert-to-page

關於 hiwat 和 depth 在文章中並不會進行介紹，因為它們並不影響整個自動釋放池的實現，也不在關鍵方法的呼叫棧中。

POOL_SENTINEL（哨兵物件）

到了這裡，你可能想要知道 POOL_SENTINEL 到底是什麼，還有它為什麼在棧中。

首先回答第一個問題： POOL_SENTINEL 只是 nil 的別名。

#define POOL_SENTINEL nil

在每個自動釋放池初始化呼叫 objc_autoreleasePoolPush 的時候，都會把一個 POOL_SENTINEL push 到自動釋放池的棧頂，並且返回這個 POOL_SENTINEL 哨兵物件。

int main(int argc, const char * argv[]) {
    {
        void * atautoreleasepoolobj = objc_autoreleasePoolPush();
        
        // do whatever you want
        
        objc_autoreleasePoolPop(atautoreleasepoolobj);
    }
    return 0;
}

上面的 atautoreleasepoolobj 就是一個 POOL_SENTINEL。

而當方法 objc_autoreleasePoolPop 呼叫時，就會向自動釋放池中的物件傳送 release 訊息，直到第一個 POOL_SENTINEL：

objc-autorelease-pop-stack

<a id='objc_autoreleasePoolPush'></a>objc_autoreleasePoolPush 方法

瞭解了 POOL_SENTINEL，我們來重新回顧一下 objc_autoreleasePoolPush 方法：

void *objc_autoreleasePoolPush(void) {
    return AutoreleasePoolPage::push();
}

它呼叫 AutoreleasePoolPage 的類方法 push，也非常簡單：

static inline void *push() {
   return autoreleaseFast(POOL_SENTINEL);
}

<a id='autoreleaseFast'></a>在這裡會進入一個比較關鍵的方法 autoreleaseFast，並傳入哨兵物件 POOL_SENTINEL：

static inline id *autoreleaseFast(id obj)
{
   AutoreleasePoolPage *page = hotPage();
   if (page && !page->full()) {
       return page->add(obj);
   } else if (page) {
       return autoreleaseFullPage(obj, page);
   } else {
       return autoreleaseNoPage(obj);
   }
}

上述方法分三種情況選擇不同的程式碼執行：

有 hotPage 並且當前 page 不滿
- 呼叫 page->add(obj) 方法將物件新增至 AutoreleasePoolPage 的棧中
有 hotPage 並且當前 page 已滿
- 呼叫 autoreleaseFullPage 初始化一個新的頁
- 呼叫 page->add(obj) 方法將物件新增至 AutoreleasePoolPage 的棧中
無 hotPage
- 呼叫 autoreleaseNoPage 建立一個 hotPage
- 呼叫 page->add(obj) 方法將物件新增至 AutoreleasePoolPage 的棧中

最後的都會呼叫 page->add(obj) 將物件新增到自動釋放池中。

hotPage 可以理解為當前正在使用的 AutoreleasePoolPage。

page->add 新增物件

id *add(id obj) 將物件新增到自動釋放池頁中：

id *add(id obj) {
    id *ret = next;
    *next = obj;
    next++;
    return ret;
}

筆者對這個方法進行了處理，更方便理解。

這個方法其實就是一個壓棧的操作，將物件加入 AutoreleasePoolPage 然後移動棧頂的指標。

autoreleaseFullPage（當前 hotPage 已滿）

autoreleaseFullPage 會在當前的 hotPage 已滿的時候呼叫：

static id *autoreleaseFullPage(id obj, AutoreleasePoolPage *page) {
    do {
        if (page->child) page = page->child;
        else page = new AutoreleasePoolPage(page);
    } while (page->full());

    setHotPage(page);
    return page->add(obj);
}

它會從傳入的 page 開始遍歷整個雙向連結串列，直到：

查詢到一個未滿的 AutoreleasePoolPage
使用構造器傳入 parent 建立一個新的 AutoreleasePoolPage

在查詢到一個可以使用的 AutoreleasePoolPage 之後，會將該頁面標記成 hotPage，然後調動上面分析過的 page->add 方法新增物件。

autoreleaseNoPage（沒有 hotPage)

如果當前記憶體中不存在 hotPage，就會呼叫 autoreleaseNoPage 方法初始化一個 AutoreleasePoolPage：

static id *autoreleaseNoPage(id obj) {
    AutoreleasePoolPage *page = new AutoreleasePoolPage(nil);
    setHotPage(page);

    if (obj != POOL_SENTINEL) {
        page->add(POOL_SENTINEL);
    }

    return page->add(obj);
}

既然當前記憶體中不存在 AutoreleasePoolPage，就要從頭開始構建這個自動釋放池的雙向連結串列，也就是說，新的 AutoreleasePoolPage 是沒有 parent 指標的。

初始化之後，將當前頁標記為 hotPage，然後會先向這個 page 中新增一個 POOL_SENTINEL 物件，來確保在 pop 呼叫的時候，不會出現異常。

最後，將 obj 新增到自動釋放池中。

<a id='objc_autoreleasePoolPop'></a>objc_autoreleasePoolPop 方法

同樣，回顧一下上面提到的 objc_autoreleasePoolPop 方法：

void objc_autoreleasePoolPop(void *ctxt) {
    AutoreleasePoolPage::pop(ctxt);
}

看起來傳入任何一個指標都是可以的，但是在整個工程並沒有發現傳入其他物件的例子。不過在這個方法中傳入其它的指標也是可行的，會將自動釋放池釋放到相應的位置。

我們一般都會在這個方法中傳入一個哨兵物件 POOL_SENTINEL，如下圖一樣釋放物件：

objc-autorelease-pop-stack

對 objc_autoreleasePoolPop 行為的測試

在繼續分析這個方法之前做一個小測試，在 objc_autoreleasePoolPop 傳入非哨兵物件，測試一下這個方法的行為。

下面是 main.m 檔案中的原始碼：

#import <Foundation/Foundation.h>

int main(int argc, const char * argv[]) {
    @autoreleasepool {

        NSString *s = @"Draveness";
        [s stringByAppendingString:@"-Suffix"];

    }
    return 0;
}

在程式碼的這一行打一個斷點，因為這裡會呼叫 autorelease 方法，將字串加入自動釋放池：

objc-autorelease-breakpoint-main

當代碼執行到這裡時，通過 lldb 打印出當前 hotPage 中的棧內容：

objc-autorelease-print-pool-content

通過 static 方法獲取當前 hotPage
列印 AutoreleasePoolPage 中的內容
列印當前 next 指標指向的內容，以及之前的內容，-2時已經到了 begin() 位置
使用 print()和 printAll()列印自動釋放池中內容

然後將字串 @"Draveness-Suffix" 的指標傳入 pop 方法，測試 pop 方法能否傳入非哨兵引數。

objc-autorelease-pop-string

再次列印當前 AutoreleasePoolPage 的內容時，字串已經不存在了，這說明向 pop 方法傳入非哨兵引數是可行的，只是我們一般不會傳入非哨兵物件。

讓我們重新回到對 objc_autoreleasePoolPop 方法的分析，也就是 AutoreleasePoolPage::pop 方法的呼叫：

static inline void pop(void *token) {
    AutoreleasePoolPage *page = pageForPointer(token);
    id *stop = (id *)token;

    page->releaseUntil(stop);

    if (page->child) {
        if (page->lessThanHalfFull()) {
            page->child->kill();
        } else if (page->child->child) {
            page->child->child->kill();
        }
    }
}

在這個方法中刪除了大量無關的程式碼，以及對格式進行了調整。

該靜態方法總共做了三件事情：

使用 pageForPointer 獲取當前 token 所在的 AutoreleasePoolPage
呼叫 releaseUntil 方法釋放棧中的物件，直到 stop
呼叫 child 的 kill 方法

我到現在也不是很清楚為什麼要根據當前頁的不同狀態 kill 掉不同 child 的頁面。

if (page->lessThanHalfFull()) {
    page->child->kill();
} else if (page->child->child) {
    page->child->child->kill();
}

pageForPointer 獲取 AutoreleasePoolPage

pageForPointer 方法主要是通過記憶體地址的操作，獲取當前指標所在頁的首地址：

static AutoreleasePoolPage *pageForPointer(const void *p) {
    return pageForPointer((uintptr_t)p);
}

static AutoreleasePoolPage *pageForPointer(uintptr_t p) {
    AutoreleasePoolPage *result;
    uintptr_t offset = p % SIZE;

    assert(offset >= sizeof(AutoreleasePoolPage));

    result = (AutoreleasePoolPage *)(p - offset);
    result->fastcheck();

    return result;
}

將指標與頁面的大小，也就是 4096 取模，得到當前指標的偏移量，因為所有的 AutoreleasePoolPage 在記憶體中都是對齊的：

p = 0x100816048
p % SIZE = 0x48
result = 0x100816000

而最後呼叫的方法 fastCheck() 用來檢查當前的 result 是不是一個 AutoreleasePoolPage。

通過檢查 magic_t 結構體中的某個成員是否為 0xA1A1A1A1。

releaseUntil 釋放物件

releaseUntil 方法的實現如下：

void releaseUntil(id *stop) {
    while (this->next != stop) {
        AutoreleasePoolPage *page = hotPage();

        while (page->empty()) {
            page = page->parent;
            setHotPage(page);
        }

        page->unprotect();
        id obj = *--page->next;
        memset((void*)page->next, SCRIBBLE, sizeof(*page->next));
        page->protect();

        if (obj != POOL_SENTINEL) {
            objc_release(obj);
        }
    }

    setHotPage(this);
}

它的實現還是很容易的，用一個 while 迴圈持續釋放 AutoreleasePoolPage 中的內容，直到 next 指向了 stop 。

使用 memset 將記憶體的內容設定成 SCRIBBLE，然後使用 objc_release 釋放物件。

kill() 方法

到這裡，沒有分析的方法就只剩下 kill 了，而它會將當前頁面以及子頁面全部刪除：

void kill() {
    AutoreleasePoolPage *page = this;
    while (page->child) page = page->child;

    AutoreleasePoolPage *deathptr;
    do {
        deathptr = page;
        page = page->parent;
        if (page) {
            page->unprotect();
            page->child = nil;
            page->protect();
        }
        delete deathptr;
    } while (deathptr != this);
}

autorelease 方法

我們已經對自動釋放池生命週期有一個比較好的瞭解，最後需要了解的話題就是 autorelease 方法的實現，先來看一下方法的呼叫棧：

- [NSObject autorelease]
└── id objc_object::rootAutorelease()
    └── id objc_object::rootAutorelease2()
        └── static id AutoreleasePoolPage::autorelease(id obj)
            └── static id AutoreleasePoolPage::autoreleaseFast(id obj)
                ├── id *add(id obj)
                ├── static id *autoreleaseFullPage(id obj, AutoreleasePoolPage *page)
                │   ├── AutoreleasePoolPage(AutoreleasePoolPage *newParent)
                │   └── id *add(id obj)
                └── static id *autoreleaseNoPage(id obj)
                    ├── AutoreleasePoolPage(AutoreleasePoolPage *newParent)
                    └── id *add(id obj)

在 autorelease 方法的呼叫棧中，最終都會呼叫上面提到的 autoreleaseFast 方法，將當前物件加到 AutoreleasePoolPage 中。

這一小節中這些方法的實現都非常容易，只是進行了一些引數上的檢查，最終還要呼叫 autoreleaseFast 方法：

inline id objc_object::rootAutorelease() {
    if (isTaggedPointer()) return (id)this;
    if (prepareOptimizedReturn(ReturnAtPlus1)) return (id)this;

    return rootAutorelease2();
}

__attribute__((noinline,used)) id objc_object::rootAutorelease2() {
    return AutoreleasePoolPage::autorelease((id)this);
}

static inline id autorelease(id obj) {
   id *dest __unused = autoreleaseFast(obj);
   return obj;
}

由於在上面已經分析過 autoreleaseFast 方法的實現，這裡就不會多說了。

小結

整個自動釋放池 AutoreleasePool 的實現以及 autorelease 方法都已經分析完了，我們再來回顧一下文章中的一些內容：

自動釋放池是由 AutoreleasePoolPage 以雙向連結串列的方式實現的
當物件呼叫 autorelease 方法時，會將物件加入 AutoreleasePoolPage 的棧中
呼叫 AutoreleasePoolPage::pop 方法會向棧中的物件傳送 release 訊息

深入解析 Autoreleasepool

從 main 函式開始

@autoreleasepool

AutoreleasePool 是什麼

AutoreleasePoolPage 的結構

<a id='objc_autoreleasePoolPush'></a>objc_autoreleasePoolPush 方法

<a id='objc_autoreleasePoolPop'></a>objc_autoreleasePoolPop 方法

autorelease 方法

小結

深入解析 Autoreleasepool

MySQL主從復制原理深入解析與練習

深入解析瀏覽器的幕後工作原理(三) 呈現樹和 DOM 樹的關系

深入解析瀏覽器的幕後工作原理(二) 呈現引擎

jQuery技術內幕：深入解析jQuery架構設計與實現原理

java int轉String全部方式的效率對照與深入解析

轉-Java基礎深入解析——類與對象

.NET深入解析LINQ框架（二：LINQ優雅的前奏）

.NET深入解析LINQ框架（四：IQueryable、IQueryProvider接口詳解)

.NET深入解析LINQ框架（六：LINQ執行表達式）

.NET深入解析LINQ框架（三：LINQ優雅的前奏）

UWP -- Background Task 深入解析

深入解析Java垃圾回收機制

Linux學習-- su -和 su的區別深入解析

ajax異步傳輸之深入解析

騰訊工程師帶你深入解析 MySQL binlog

java基礎(一) 深入解析基本類型

深入解析Java反射（1） - 基礎

深入解析條件變量(condition variables)

java基礎(八) 深入解析常量池與裝拆箱機制

深入解析 Autoreleasepool

從 main 函式開始

@autoreleasepool

AutoreleasePool 是什麼

AutoreleasePoolPage 的結構

<a id='objc_autoreleasePoolPush'></a>objc_autoreleasePoolPush 方法

<a id='objc_autoreleasePoolPop'></a>objc_autoreleasePoolPop 方法

autorelease 方法

小結

相關推薦