2. 程式人生 > >SQL Server DDL觸發器運用

SQL Server DDL觸發器運用

阿新 • • 發佈：2018-12-31

一.本文所涉及的內容（Contents）

二.背景（Contexts）

　　說到觸發器，大家都會想到這樣的使用場景：當一個表的資料修改了，運用DML觸發插入或者更新到其它表中；那DDL觸發器（SQL Server 2005引入的新功能）會運用到什麼場景中呢？本文將為你講述4種運用DDL觸發器的場景：

　　1) 禁止使用者修改和刪除表；

　　2) 禁止使用者刪除資料庫；

　　3) 記錄和監控某資料庫所有的DDL操作；

　　4) 把DDL操作資訊以郵件的形式主動傳送通知和預警；

三.基礎知識（Rudimentary Knowledge）

　　DDL觸發器是由修改資料庫物件的 DDL 語句（如以 CREATE、ALTER 或 DROP）激發。

　　DDL觸發器支援BEFORE和AFTER事件觸發器，並在資料庫或模式級執行。通常，DDL觸發器用於監控資料庫中的重要事件。有時用它們來監控錯誤程式碼。錯誤程式碼可能會執行破壞資料庫或使資料庫不穩定的活動。更常見的情況是：在開發、測試和stage系統中用它們來了解和監控資料庫活動的動態。

　　當監控GRANT和REVOKE許可權語句時，它們也是有效的安全工具。

四.DDL運用場景（DDL Scene）

(一) 首先我們來看一個簡單的例子：建立資料庫DDL_DB和一個名為DatabaseLog的表，現在建立一個DDL觸發器：禁止使用者修改和刪除表，並進行提醒。執行下面的SQL指令碼進行測試。

--Script1：
--建立測試資料庫
USE MASTER
GO
CREATE DATABASE DDL_DB

--建立DDL觸發器記錄表
USE DDL_DB
GO
CREATE TABLE [dbo].[DatabaseLog](
    [DatabaseLogID] [int] IDENTITY(1,1) NOT NULL,
    [PostTime] [datetime] NOT NULL,
    [ServerName] [sysname] NOT NULL,
    [LoginName] [sysname] NOT NULL,
    
 
[DatabaseUser] [sysname] NOT NULL,
    [DatabaseName] [sysname] NOT NULL,
    [Schema] [sysname] NULL,
    [Object] [sysname] NULL,
    [TSQL] [nvarchar](max) NOT NULL,
    [Event] [sysname] NOT NULL,
    [XmlEvent] [xml] NOT NULL,
 CONSTRAINT [PK_DatabaseLog_DatabaseLogID] PRIMARY KEY NONCLUSTERED 
(
    [DatabaseLogID] ASC
) ON [PRIMARY]
) ON [PRIMARY]

--Script2：
--建立DDL觸發器：禁止修改或者刪除資料表
CREATE TRIGGER DDL_TableTrigger
ON DATABASE
FOR DROP_TABLE, ALTER_TABLE
AS
   PRINT '對不起，您不能對資料表進行操作，請聯絡DBA'
   ROLLBACK ;

--測試刪除表
USE DDL_DB
GO
DROP TABLE [DatabaseLog]

wps_clip_image-14403_thumb

（Figure1：建立資料庫級別的DDL）

wps_clip_image-32149_thumb

（Figure2：返回的提示資訊）

wps_clip_image-7628_thumb

（Figure3：SSMS返回的提示資訊）

建立資料庫級別的DDL之後會出現在資料庫觸發器列表中，如Figure1；當執行刪除表的Drop等DDL命令的時候，就會出現Figure2的提示資訊；如果是在SSMS中刪除表則會出現Figure3的提示資訊。

(二) 在上面的基礎上再進行擴充套件，建立一個DDL觸發器：禁止使用者刪除資料庫，並進行提醒。

--Script3：
--禁止SQL Server伺服器裡刪除資料庫
CREATE TRIGGER DDL_DataBaseTrigger
ON ALL SERVER
FOR DROP_DATABASE
AS
    PRINT '對不起，您不能刪除資料庫，請聯絡DBA' 
    ROLLBACK;

--測試刪除資料庫
USE MASTER
GO
DROP DATABASE [DDL_DB]

wps_clip_image-11348_thumb

（Figure4：建立伺服器級別的DDL）

wps_clip_image-13353_thumb

（Figure5：返回的提示資訊）

wps_clip_image-16272_thumb

（Figure6：SSMS返回的提示資訊）

建立伺服器級別的DDL之後會出現在伺服器物件-觸發器的列表中，如Figure4；當執行刪除資料庫的Drop等DDL命令的時候，就會出現Figure5的提示資訊；如果是在SSMS中刪除資料庫則會出現Figure6的提示資訊。

(三) 很多時候在程式開發階段是不會禁用對資料庫的修改的，這些時候我們更希望是記錄資料庫的修改資訊，方便對資訊進行跟蹤檢查。使用 EVENTDATA 函式，可以捕獲有關激發 DDL 觸發器的事件的資訊，此函式返回 xml 值。

前面已經建立了資料表DatabaseLog，建立下面的DDL_DatabaseLog觸發器，每當資料庫發生DDL事件，DDL觸發器就會把相關的DDL資訊插入到DatabaseLog表，資訊包括操作的時間，操作人，操作的SQL等。

執行Script5測試指令碼，返回Figure7的資訊，查詢DatabaseLog表，返回的記錄有2條，一條是建立表資訊，一條是刪除表資訊，如Figure8、Figure9所示。

--Script4：
--建立當前資料庫的DDL觸發器
USE DDL_DB
GO
-- =============================================
-- Author:        <聽風吹雨>
-- Create date:    <2013.05.03>
-- Description:    <記錄資料庫DDL操作>
-- Blog:        <http://www.cnblogs.com/gaizai/>
-- =============================================
CREATE TRIGGER [DDL_DatabaseLog]
ON DATABASE 
FOR DDL_DATABASE_LEVEL_EVENTS AS 
BEGIN
    SET NOCOUNT ON;
    DECLARE @data XML;
    DECLARE @schema sysname;
    DECLARE @object sysname;
    DECLARE @eventType sysname;
    SET @data = EVENTDATA();
    SET @eventType = @data.value('(/EVENT_INSTANCE/EventType)[1]', 'sysname');
    SET @schema = @data.value('(/EVENT_INSTANCE/SchemaName)[1]', 'sysname');
    SET @object = @data.value('(/EVENT_INSTANCE/ObjectName)[1]', 'sysname') 
    
    IF @object IS NOT NULL
        PRINT '  ' + @eventType + ' - ' + @schema + '.' + @object;
    ELSE
        PRINT '  ' + @eventType + ' - ' + @schema;
    IF @eventType IS NULL
        PRINT CONVERT(nvarchar(max), @data);
    INSERT [DDL_DB].[dbo].[DatabaseLog](
        [PostTime], 
        [ServerName], 
        [LoginName], 
        [DatabaseUser], 
        [DatabaseName],
        [Schema], 
        [Object], 
        [TSQL], 
        [Event], 
        [XmlEvent])
    VALUES(
        GETDATE(), 
        @data.value('(/EVENT_INSTANCE/ServerName)[1]', 'sysname'), 
        @data.value('(/EVENT_INSTANCE/LoginName)[1]', 'sysname'), 
        CONVERT(sysname, CURRENT_USER),
        @data.value('(/EVENT_INSTANCE/DatabaseName)[1]', 'sysname'),  
        CONVERT(sysname, @schema), 
        CONVERT(sysname, @object), 
        @data.value('(/EVENT_INSTANCE/TSQLCommand)[1]', 'nvarchar(max)'),
        @eventType,  
        @data
        );
END;

--Script5：測試DDL記錄
--禁用DDL 觸發器
DISABLE TRIGGER DDL_TableTrigger ON DATABASE;
GO
CREATE TABLE TestTable (a int)
GO
DROP TABLE TestTable;
GO

SELECT * FROM [DatabaseLog];
GO

wps_clip_image-15637_thumb

（Figure7：返回的提示資訊）

wps_clip_image-3080_thumb

（Figure8：DatabaseLog表前半部分資訊）

wps_clip_image-5273_thumb

（Figure9：DatabaseLog表後半部分資訊）

(四) 我們可以使用DDL觸發器主動監控DDL語句的執行，當有對資料庫執行DDL就會觸發，我們把這些資訊儲存到表中，並且把操作使用者的HostName和修改的T-SQL以郵件的形式傳送到指定的郵件。關於設定資料庫郵件可以參考：SQL Server 資料庫郵件。傳送郵件的效果如Figure10。郵件部分參考：MS SQL監控資料庫的DDL操作

--Script5：
--建立當前資料庫的DDL觸發器
USE DDL_DB
GO
-- =============================================
-- Author:        <聽風吹雨>
-- Create date:    <2013.05.03>
-- Description:    <記錄資料庫DDL操作，傳送郵件預警>
-- Blog:        <http://www.cnblogs.com/gaizai/>
-- =============================================
CREATE TRIGGER [DDL_DatabaseLog]
ON DATABASE 
FOR DDL_DATABASE_LEVEL_EVENTS AS 
BEGIN
    SET NOCOUNT ON;
    DECLARE @data XML;
    DECLARE @schema sysname;
    DECLARE @object sysname;
    DECLARE @eventType sysname;
    DECLARE @databaseName sysname;
    DECLARE @tableHTML  NVARCHAR(MAX);
    SET @data = EVENTDATA();
    SET @eventType = @data.value('(/EVENT_INSTANCE/EventType)[1]', 'sysname');
    SET @schema = @data.value('(/EVENT_INSTANCE/SchemaName)[1]', 'sysname');
    SET @object = @data.value('(/EVENT_INSTANCE/ObjectName)[1]', 'sysname');
    SET @databaseName = @data.value('(/EVENT_INSTANCE/DatabaseName)[1]', 'sysname');
    
    IF @object IS NOT NULL
        PRINT '  ' + @eventType + ' - ' + @schema + '.' + @object;
    ELSE
        PRINT '  ' + @eventType + ' - ' + @schema;
    IF @eventType IS NULL
        PRINT CONVERT(nvarchar(max), @data);
    INSERT [DDL_DB].[dbo].[DatabaseLog](
        [PostTime], 
        [ServerName], 
        [LoginName], 
        [DatabaseUser], 
        [DatabaseName],
        [Schema], 
        [Object], 
        [TSQL], 
        [Event], 
        [XmlEvent])
    VALUES(
        GETDATE(), 
        @data.value('(/EVENT_INSTANCE/ServerName)[1]', 'sysname'), 
        @data.value('(/EVENT_INSTANCE/LoginName)[1]', 'sysname'), 
        CONVERT(sysname, CURRENT_USER),
        @databaseName,  
        CONVERT(sysname, @schema), 
        CONVERT(sysname, @object), 
        @data.value('(/EVENT_INSTANCE/TSQLCommand)[1]', 'nvarchar(max)'),
        @eventType,  
        @data
        );

    SET @tableHTML =
        N'<H1>DDL Event</H1>' +
        N'<table border="0">' +
    N'<tr><th>PostTime</th><th>ServerName</th><th>LoginName</th><th>DatabaseUser</th><th>DatabaseName</th><th>Object</th>' +
        N'<th>TSQL</th></tr>' +
        CAST((SELECT
        td = [PostTime],'',
        td = [ServerName],'',
        td = [LoginName],'',
        td = [DatabaseUser],'',
        td = [DatabaseName],'',
        td = [Object],'',
        td = TSQL,''
        FROM [DDL_DB].[dbo].[DatabaseLog]
        WHERE DatabaseLogID =(SELECT MAX(DatabaseLogID) FROM [DDL_DB].[dbo].[DatabaseLog])
        FOR XML PATH('tr'), TYPE) AS NVARCHAR(MAX)) +
        N'</table>';
        
    DECLARE @subjectStr  NVARCHAR(MAX);
    SET @subjectStr = 'DDL Event - DataBaseName: ' + @databaseName;
        EXEC msdb.dbo.sp_send_dbmail
        @profile_name = 'DataBase_DDL_Event',
        @recipients='[email protected]',
        @subject = @subjectStr,
        @body = @tableHTML,
        @body_format = 'HTML';
END;

wps_clip_image-30426_thumb

（Figure10：郵件收到的預警）

五.補充說明（Addon）

(一) 關於DML、DDL、DCL、TCL的解釋：

DML

DML is abbreviation of Data Manipulation Language. It is used to retrieve, store, modify, delete, insert and update data in database.

Examples: SELECT, UPDATE, INSERT statements

DDL

DDL is abbreviation of Data Definition Language. It is used to create and modify the structure of database objects in database.

Examples: CREATE, ALTER, DROP statements

DCL

DCL is abbreviation of Data Control Language. It is used to create roles, permissions, and referential integrity as well it is used to control access to database by securing it.

Examples: GRANT, REVOKE statements

TCL

TCL is abbreviation of Transactional Control Language. It is used to manage different transactions occurring within a database.

Examples: COMMIT, ROLLBACK statements

(二) 關於DML與DDL運用場景的一些區別：

DML 觸發器可以看作是一種特殊的儲存過程，可以保證系統保持其完整性，在系統中進行級聯更新或強行業務規則。通過INSERTED 和 DELETED ，我們可以檢索哪些列被更新了。DML觸發器的本質就是當這兩個發生資料修改時自動執行的儲存過程。

DDL 觸發器的構建主要是為了安全，或者根據部門的需求對系統所進行的變更進行通報。通過使用 EVENTDATA( ) 函式，可以在觸發器中使用XML資訊。

(三) 如果是線上的系統，可以考慮做下面的限制：在工作時間，不允許修改任何儲存過程，否則回滾，示例程式碼如下：IF DATEPART(hour, GETDATE()) >=9 AND DATEPART(hour, GETDATE()) <= 17

(四) 一些維護DDL的SQL指令碼：

--啟用DDL 觸發器
ENABLE TRIGGER DDL_TableTrigger ON DATABASE;
--禁用DDL 觸發器
DISABLE TRIGGER ddlDatabaseTriggerLog ON DATABASE;
--刪除DDL 觸發器
DROP TRIGGER ddlDatabaseTriggerLog ON DATABASE;

--禁用當前資料庫中所有資料庫級別的DDL 觸發器
DISABLE TRIGGER ALL ON DATABASE
--禁用伺服器例項中所有伺服器級別的DDL 觸發器
DISABLE TRIGGER ALL ON ALL SERVER

(五) 所有的DDL事件可以檢視DDL 事件，也可以通過下面的SQL進行檢視：

--獲取有關DDL 觸發器可觸發的事件或事件組的資訊
SELECT * FROM sys.trigger_event_types
--檢視觸發器的依賴關係
SELECT * FROM sys.sql_expression_dependencies
SELECT * FROM sys.dm_sql_referenced_entities
SELECT * FROM sys.dm_sql_referencing_entities
--獲取有關資料庫範圍內的觸發器的資訊
SELECT * FROM sys.triggers
--獲取有關激發觸發器的資料庫事件的資訊
SELECT * FROM sys.trigger_events
SELECT * FROM sys.trigger_events AS a 
LEFT join sys.triggers AS b
ON a.object_id=b.object_id
WHERE name = 'ddlDatabaseTriggerLog'
--獲取有關伺服器範圍內的觸發器的資訊
SELECT * FROM sys.server_triggers
SELECT * FROM sys.server_trigger_events
--檢視資料庫範圍內的觸發器的定義
SELECT * FROM sys.sql_modules

(六) 在執行Script3的時候如果你正在使用SSMS開啟這個資料庫（SPID）的話，那有可能不是出現Figure5的錯誤資訊，而是出現Figure11的錯誤，這是因為你沒有關閉SPID這些視窗，我還沒有在程式連線的情況測試是否會返回這些資訊：

wps_clip_image-1961_thumb

（Figure11：Figure5可能出現的）

(七) 如果你想修改DDL觸發器的內容，那麼你不能直接Alter DDL，而應該是先執行Drop DDL，之後在Create DDL。

(八) 之前已經建立了DDL_TableTrigger和DDL_DatabaseLog觸發器，這兩個觸發器都是在DDL_DB資料庫中建立的，當我們需要修改DDL觸發器，應該觸發物件從小到大進行修改，即DDL_TableTrigger（表）到DDL_DatabaseLog（資料庫）進行修改。

如Figure12所示，如果只修改DDL_TableTrigger（Drop、Create），再執行下面的指令碼將會出現Figure13的錯誤（還沒找到官方理論描述）。解決辦法就是對DDL_DatabaseLog進行建立建立（Drop、Create）。

--測試刪除表
USE MASTER
GO
DROP DATABASE [DDL_DB]

wps_clip_image-27698_thumb

（Figure12：DDL觸發器列表）

wps_clip_image-170_thumb

（Figure13：錯誤資訊）

七.疑問（Questions）

(一) 刪除DDL觸發器是否也可以觸發一個事件呢？不然如何防止使用者先刪除DDL觸發器之後再做DDL操作呢？難道是使用者許可權？

解答：第一種方法，可以對DDL觸發器進行許可權控制；第二種方式就是在伺服器級別加一個DROP的觸發器，可以監控各個資料庫的DDL觸發器；下圖Figure14是DDL_DatabaseLog被刪除時的預警；

wps_clip_image-10302_thumb

（Figure14：刪除DDL觸發器）

(二) 能對所有資料庫進行DDL監控？一條DDL預警能實現？

解答：可以在DDL_DatabaseLog把 ON DATABASE 設定為ON All SERVER，這樣就可以監控整個伺服器例項，下圖Figure15是Logon_DB的DDL預警；

wps_clip_image-16633_thumb

（Figure15：刪除DDL觸發器）

八.參考文獻（References）

相關推薦

SQL Server DDL觸發器運用

一.本文所涉及的內容（Contents） 二.背景（Contexts） 　　說到觸發器，大家都會想到這樣的使用場景：當一個表的資料修改了，運用DML觸發插入或者更新到其它表中；那DDL觸發器（SQL Server 2005引入的新功能）會運用到什麼場景中呢？本文將為你講述4種運用DDL觸發器的場景：

SQL Server DDL觸發器

用戶名 eat exists lar value back ref tro get DDL 觸發器作用： DDL 觸發器主要用於防止對數據庫架構、視圖、表、存儲過程等進行的某些修改。 DDL 觸發器事件： DDL 觸發器在創建用來監視並響應該數據庫或服務器實例中的活動的

SQL Server DDL Triggers to Track All Database Changes(用SQLServer DDL 觸發器跟蹤所有資料庫變化)

Problem In a perfect world, only the DBA would have sa privileges, F5 would only ever be hit on purpose, every change would go throug

SQL SERVER-10-觸發器|遊標|動態sql

1.觸發器 --可以理解為一個特殊的儲存過程,在某一個動作執行的時候,自動執行,而不需要人手動執行 --觸發器的分類 --1.DML觸發器 --insert,delete,update(不支援select) --after觸發器,instead of 觸發器(相當於其他資

SQL Server資料庫——觸發器的建立

create trigger trigger_sage on student after insert,update as if exists (select * from inserted where sage not between 15 and 45) begin print '插入學生年齡不在15~4

獲取SQL SERVER delete 觸發器 觸發前的值

1、觸發器觸發時：    a、系統自動在記憶體中建立deleted表或者inserted表   b、只讀，不允許修改；觸發器執行完成後，自動刪除 2、inserted表 a、臨時儲存了插入或更新後的記錄行 b、可以從inserted表中檢查插入的資料是否滿足業務需求 c、

SQL Server：觸發器詳解

1. 概述2. 觸發器的分類3. Inserted和Deleted表4. 觸發器的執行過程5. 建立觸發器6. 修改觸發器：7. 刪除觸發器：8. 檢視資料庫中已有觸發器：9. “Instead of”相關示例:10. “After”觸發器11. 參考資源1. 概述觸發器是一

2.SQL Server DML觸發器之COMMIT和ROLLBACK TRANSACTION

14.1.2 COMMIT和ROLLBACK TRANSACTION 當執行能夠激發觸發器操作的語句時，觸發器中的操作也將包含在該語句的事務處理過程中。即使在SQL Server的自動事務處理模式下，也是如此。在自動事務處理模式下，當語句遇到錯誤時，會有隱含的BEGIN

SQL server觸發器、存儲過程操作遠程數據庫插入數據,解決服務器已存在的問題

定義 ims val rom 記錄 插入記錄 其它 pre 項目 近期弄了一個小項目，也不是非常復雜，須要將一個數據庫的一些數據備份到另外一個庫。不是本地，可能是網絡上其它的數據庫。想了一下，用了存儲過程和觸發器。也不是非常復雜，首先我須要操作遠程數據庫，於是寫了一個存

靈活運用 SQL SERVER FOR XML PATH

eight str 類型 spa ima 更多 for 逗號 image FOR XML PATH 有的人可能知道有的人可能不知道，其實它就是將查詢結果集以XML形式展現，有了它我們可以簡化我們的查詢語句實現一些以前可能需要借助函數活存儲過程來完成的工作。那麽以一個實例為

Sql Server——運用代碼創建數據庫及約束

bsp -1 nbsp 唯一約束 執行方法 blog create src wid 　　在沒有學習運用代碼創建數據庫、表和約束之前，我們只能用鼠標點擊操作，這樣看起來就不那麽直觀（高大上）了。 　　在寫代碼前要知道在哪裏寫和怎麽運行： 　　 　　點擊新建查詢，然後中間

【2018-01-19】Sql Server-觸發器

1-1 觸發器 eight sco 不能 val ted 直接 ins 1 --create table users--創建用戶表 2 --( 3 -- ids int primary key identity(1,1), 4 -- name nvar

遍歷SQL SERVER中所有存儲過程和觸發器

server text 查找 所有 and from obj where serve 如果需要查找某個存儲過程或觸發器中是否含有某段文本(比如：你想知道有哪些存儲過程操作了某個表) 可以這麽寫 select name from sysobjects o, syscomm

SQL Server如何用觸發器捕獲DML操作的會話信息

align bottom date name har 2-2 一次 ogr 一個 原文:SQL Server如何用觸發器捕獲DML操作的會話信息需求背景 上周遇到了這樣一個需求，維護人員發現一個表的數據經常被修改，由於歷史原因；文檔缺少；以及維護人員的經常變

SQL Server資料庫級別觸發器

禁止修改表結構和加表  CREATE TRIGGER [Object_Change_Trigger_DDL] ON DATABASE FOR ALTER_TABLE,DROP_TABLE,CREATE_TABLE,CREATE_INDEX,ALTER_INDEX

淺入淺出SQL Server 觸發器

什麼是觸發器 簡單的來說，在SQL Server裡面也就是對某一個表的一定的操作，觸發某種條件，從而執行的一段程式。觸發器是一個特殊的儲存過程。 觸發器的建立 常見的觸發器有三種，分別對應於Insert 、Update、Delete事件。 怎麼建立觸發器呢？在牛腩新聞釋出系統

2018年11月16日SQL Server實驗內容（觸發器實驗）

--注意：先把studentmanager資料庫中的所有表用select into命令複製一份， --然後用複製後新表完成下面的實驗，同時，對每個觸發器都要進行驗證。 select *into department2 from department select *into course2 fro

SQL Server觸發器建立、刪除、修改、檢視

教程貼士：本教程為大家介紹SQL Server觸發器建立、刪除、修改、檢視方法。   　　一：觸發器是一種特殊的儲存過程，它不能被顯式地呼叫，而是在往表中插入記錄﹑更新記錄或者刪除記錄時被自動地啟用。所以觸發器可以用來實現對錶實施複雜的完整性約束。 　　二：SQL Server

Sql Server 觸發器Update、Insert、Delete

什麼是觸發器 在SQL Server裡面也就是對某一個表的一定的操作，觸發某種條件，從而執行的一段程式。觸發器是一個特殊的儲存過程。 常見的觸發器一共有三種 Insert, Update,Delete

【SQL server觸發器】觸發器基礎知識

前言： 觸發器與儲存過程有一點點差別的，那麼我們什麼時候要用觸發器，接下來將給大家揭曉！ 1、什麼是觸發器 觸發器是一個在修改指定表中的資料執行的儲存過程。通常通過建立觸發器來強制實現 不同表 中的邏輯相關資料的引用完整性或一致性。由於使用者不能繞過