2. 程式人生 > >轉一篇寫的不錯的NSIS打包指令碼示例

轉一篇寫的不錯的NSIS打包指令碼示例

阿新 • • 發佈：2019-01-08

----------------------------------------------------------------------------------------------

這幾天稍稍深入地使用了一下 NSIS，功能太強大了。回首看看不比學習一門高階語言容易，不過一般也能信手拈來。
製作了一個 CuteFoto 的 NSIS 安裝指令碼，支援多語言，支援自動判斷作業系統並優先選擇安裝 ASCII/UNICODE或AMD64版本...等等。

附件下載: 請點這裡

其中幾個地方說明一下:

---如果以 SectionGroup 而不是 Section 為第一個區段定義，發現 NSIS 無法正常處理預設/自定義安裝型別，應該是 NSIS 的一個 BUG。但是在d第一個 SectionGroup 之前加上一個無名的空段 (隱藏)，即可解決此問題。即 Section...SectionEnd。

---判斷是否是 NT 類作業系統: 
ReadRegStr $0 HKLM "SOFTWAREMicrosoftWindows NTCurrentVersion" "CurrentVersion"
${If} $0 != ""

---判斷是處理器架構: 
ReadRegStr $0 HKLM "SYSTEMCurrentControlSetControlSession ManagerEnvironment" "PROCESSOR_ARCHITECTURE"
${If} $0 != "AMD64"

---還有單選按鈕支援，看程式碼……

---NSIS 的中文文件和例子請看這裡: http://foobar.nease.net/nsis/ (衷心感謝藍色網際網友的工作，foobarr.cab 內有一個助手函式庫，看看也許會很有用)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 標頭檔案
!include "MUI.nsh"
!include "Sections.nsh"
!include "LogicLib.nsh"
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 巨集定義
!define STR_AppName "CuteFoto"
!define STR_Version "2.2.240"
!define STR_Publisher "Yonsm.NET"
!define STR_HomepageUrl "http://Yonsm.zj.com"

!define REG_AppPath "Software\Microsoft\Windows\CurrentVersion\App Paths\${STR_AppName}.exe"
!define REG_Uninstall "Software\Microsoft\Windows\CurrentVersion\Uninstall\${STR_AppName}"
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; MUI 設定
!define MUI_ABORTWARNING
!define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\orange-install.ico"
!define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\orange-uninstall.ico"
!define MUI_WELCOMEFINISHPAGE_BITMAP "${NSISDIR}\Contrib\Graphics\Wizard\orange.bmp"
!define MUI_UNWELCOMEFINISHPAGE_BITMAP "${NSISDIR}\Contrib\Graphics\Wizard\orange-uninstall.bmp"
!define MUI_HEADERIMAGE
!define MUI_HEADERIMAGE_BITMAP "${NSISDIR}\Contrib\Graphics\Header\orange.bmp"
!define MUI_HEADERIMAGE_UNBITMAP "${NSISDIR}\Contrib\Graphics\Header\orange-uninstall.bmp"

; 元件頁面設定
!define MUI_COMPONENTSPAGE_SMALLDESC

; 完成安裝頁面設定
!define MUI_FINISHPAGE_RUN "$INSTDIR\${STR_AppName}.exe"
!define MUI_FINISHPAGE_SHOWREADME "$INSTDIR\${STR_AppName}.chm"
!define MUI_FINISHPAGE_SHOWREADME_TEXT "$(LNG_ShowHelp)"
!define MUI_FINISHPAGE_LINK "${STR_AppName} $(LNG_Homepage): ${STR_HomepageUrl}"
!define MUI_FINISHPAGE_LINK_LOCATION "${STR_HomepageUrl}"

; 語言選擇設定
!define MUI_LANGDLL_REGISTRY_ROOT "HKLM"
!define MUI_LANGDLL_REGISTRY_KEY "${REG_Uninstall}"
!define MUI_LANGDLL_REGISTRY_VALUENAME "NSIS:Language"

; 安裝頁面
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_LICENSE "$(LNG_License)"
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH

; 解除安裝頁面
!insertmacro MUI_UNPAGE_WELCOME
!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES
!insertmacro MUI_UNPAGE_FINISH

; 語言支援
!insertmacro MUI_LANGUAGE "English"
!insertmacro MUI_LANGUAGE "SimpChinese"
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 語言相關字串
LicenseLangString LNG_License ${LANG_ENGLISH} "EULA.ENU.rtf"
LangString LNG_BrandingText ${LANG_ENGLISH} "Expert -> Professional -> Absorbedly"

LangString LNG_DefaultInstation ${LANG_ENGLISH} "Default installtion"
LangString LNG_FullInstation ${LANG_ENGLISH} "Full installtion"
LangString LNG_MinimalInstation ${LANG_ENGLISH} "Minimal installtion"

LangString LNG_Help ${LANG_ENGLISH} "Help"
LangString LNG_Homepage ${LANG_ENGLISH} "Homepage"
LangString LNG_Uninstall ${LANG_ENGLISH} "Uninstall"
LangString LNG_ShowHelp ${LANG_ENGLISH} "Show Help"

LangString LNG_ProgramFile ${LANG_ENGLISH} "Program Files"
LangString LNG_LanguageFile ${LANG_ENGLISH} "Language Files"
LangString LNG_CreateShortcut ${LANG_ENGLISH} "Create Shortcut"

LangString LNG_ProgramMenuShortcutGroup ${LANG_ENGLISH} "Program Menu Shortcut Group"
LangString LNG_DesktopShortcut ${LANG_ENGLISH} "Desktop Shortcut"
LangString LNG_ProgramMenuShortcut ${LANG_ENGLISH} "Program Menu Shortcut"
LangString LNG_StartMenuShortcut ${LANG_ENGLISH} "Start Menu Shortcut"
LangString LNG_QuickLaunchShortcut ${LANG_ENGLISH} "Quick Launch Bar Shortcut"

LangString LNG_ProgramFileDesc ${LANG_ENGLISH} "Install ${STR_AppName} program files."
LangString LNG_LanguageFileDesc ${LANG_ENGLISH} "Install ${STR_AppName} language files."
LangString LNG_CreateShortcutDesc ${LANG_ENGLISH} "Create shortcuts to launch the program easy."

LangString LNG_X86AsciiDesc ${LANG_ENGLISH} "ASCII version on WIN32 platform for X86 architecture (The only choice on WIN9X OS for X86 architecture)."
LangString LNG_X86UnicodeDesc ${LANG_ENGLISH} "Unicode version on WIN32 platform for X86 architecture (Preferred on WINNT OS for X86 architecture)."
LangString LNG_X64UnicodeDesc ${LANG_ENGLISH} "Unicode version on WIN64 platform for X64 architecture (Preferred on WIN64 OS for X64 architecture)."


LicenseLangString LNG_License ${LANG_SIMPCHINESE} "EULA.CHS.rtf"
LangString LNG_BrandingText ${LANG_SIMPCHINESE} "專家 -> 專業 -> 專心"

LangString LNG_DefaultInstation ${LANG_SIMPCHINESE} "預設安裝"
LangString LNG_FullInstation ${LANG_SIMPCHINESE} "完全安裝"
LangString LNG_MinimalInstation ${LANG_SIMPCHINESE} "最小安裝"

LangString LNG_Help ${LANG_SIMPCHINESE} "幫助"
LangString LNG_Homepage ${LANG_SIMPCHINESE} "主頁"
LangString LNG_Uninstall ${LANG_SIMPCHINESE} "解除安裝"
LangString LNG_ShowHelp ${LANG_SIMPCHINESE} "檢視幫助"

LangString LNG_ProgramFile ${LANG_SIMPCHINESE} "程式檔案"
LangString LNG_LanguageFile ${LANG_SIMPCHINESE} "語言檔案"
LangString LNG_CreateShortcut ${LANG_SIMPCHINESE} "建立快捷方式"

LangString LNG_ProgramMenuShortcutGroup ${LANG_SIMPCHINESE} "程式選單快捷方式組"
LangString LNG_DesktopShortcut ${LANG_SIMPCHINESE} "桌面快捷方式"
LangString LNG_ProgramMenuShortcut ${LANG_SIMPCHINESE} "程式選單快捷方式"
LangString LNG_StartMenuShortcut ${LANG_SIMPCHINESE} "開始選單快捷方式"
LangString LNG_QuickLaunchShortcut ${LANG_SIMPCHINESE} "快速啟動欄快捷方式"

LangString LNG_ProgramFileDesc ${LANG_SIMPCHINESE} "安裝 ${STR_AppName} 程式檔案。"
LangString LNG_LanguageFileDesc ${LANG_SIMPCHINESE} "安裝 ${STR_AppName} 語言檔案。"
LangString LNG_CreateShortcutDesc ${LANG_SIMPCHINESE} "建立用於快速訪問的快捷方式。"

LangString LNG_X86AsciiDesc ${LANG_SIMPCHINESE} "安裝 X86 架構 WIN32 平臺上的  ASCII 版本。這是在 X86 架構 WIN9X 類作業系統中的唯一選擇。"
LangString LNG_X86UnicodeDesc ${LANG_SIMPCHINESE} "安裝 X86 架構 WIN32 平臺上的 UNICODE 版本。這是在 X86 架構 WINNT 類作業系統中的優先選擇。"
LangString LNG_X64UnicodeDesc ${LANG_SIMPCHINESE} "安裝 X64 架構 WIN64 平臺上的 UNICODE 版本。這是在 X64 架構 WIN64 類作業系統中的優先選擇。"
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 雜項
Name "${STR_AppName} ${STR_Version}"
OutFile "${STR_AppName}.${STR_Version}.exe"
InstallDir "$PROGRAMFILES\${STR_AppName}"
InstallDirRegKey HKLM "${REG_AppPath}" ""
ShowInstDetails SHOW
ShowUnInstDetails SHOW
BrandingText "$(LNG_BrandingText)"
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;



;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 安裝型別
!ifndef NOINSTTYPES
    InstType "$(LNG_DefaultInstation)"
    InstType "$(LNG_FullInstation)"
    InstType "$(LNG_MinimalInstation)"
!endif
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 程式檔案
Section
SectionEnd
SectionGroup /e "$(LNG_ProgramFile)" SEC_ProgramFile
    Section "-HelpFile" SEC_HelpFile
        SetOutPath "$INSTDIR"
        SetOverwrite ON 
        
        File "..\Help\CuteFoto.chm"
    SectionEnd

    Section "X86 ASCII" SEC_X86Ascii
        SectionIn 1 2 3
        File "..\Release\CuteFoto.exe"
    SectionEnd

    Section "X86 UNICODE" SEC_X86Unicode
        SectionIn 5 RO
        File "..\Unicode\Release\CuteFoto.exe"
    SectionEnd

    Section "X64 UNICODE" SEC_X64Unicode
        SectionIn 5 RO
        File "..\AMD64\Release\CuteFoto.exe"
    SectionEnd
SectionGroupEnd
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 語言檔案
SectionGroup "$(LNG_LanguageFile)" SEC_LanguageFile
    Section "English" SEC_English
        SectionIn 2
        File "..\Release\English.lng"
    SectionEnd

    Section "CAPITAL ENGLISH" SEC_CapitalEnglish
        SectionIn 1 2
        File "..\Release\English (Capital).lng"
    SectionEnd

    Section "簡體中文" SEC_SimplifiedChinese
        SectionIn 1 2
        File "..\Release\Chinese (Simplified).lng"
    SectionEnd
SectionGroupEnd
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 快捷方式
SectionGroup "$(LNG_CreateShortcut)" SEC_Shortcut
    SectionGroup "$(LNG_ProgramMenuShortcutGroup)" SEC_ProgramMenuShortcutGroup
        Section "${STR_AppName}" SEC_AppNameShortcut
            SectionIn 1 2
            CreateDirectory "$SMPROGRAMS\${STR_AppName}"
            CreateShortCut "$SMPROGRAMS\${STR_AppName}\${STR_AppName}.lnk" "$INSTDIR\${STR_AppName}.exe"
        SectionEnd

        Section "${STR_AppName} $(LNG_Help)" SEC_HelpShortcut
            SectionIn 1 2
            CreateDirectory "$SMPROGRAMS\${STR_AppName}"
            CreateShortCut "$SMPROGRAMS\${STR_AppName}\${STR_AppName} $(LNG_Help).lnk" "$INSTDIR\${STR_AppName}.chm"
        SectionEnd

        Section "${STR_AppName} $(LNG_Homepage)" SEC_HomePageShortcut
            SectionIn 1 2
            CreateDirectory "$SMPROGRAMS\${STR_AppName}"
            WriteINIStr "$SMPROGRAMS\${STR_AppName}\${STR_AppName} $(LNG_Homepage).url" "InternetShortcut" "URL" "${STR_HomepageUrl}"
        SectionEnd

        Section "$(LNG_Uninstall) ${STR_AppName}" SEC_UninstallShortcut
            SectionIn 1 2
            CreateDirectory "$SMPROGRAMS\${STR_AppName}"
            CreateShortCut "$SMPROGRAMS\${STR_AppName}\$(LNG_Uninstall) ${STR_AppName}.lnk" "$INSTDIR\Uninstall ${STR_AppName}.exe"
        SectionEnd
    SectionGroupEnd

    Section "$(LNG_DesktopShortcut)" SEC_DesktopShortcut
        SectionIn 1 2
        CreateShortCut "$DESKTOP\${STR_AppName}.lnk" "$INSTDIR\${STR_AppName}.exe"
    SectionEnd

    Section "$(LNG_ProgramMenuShortcut)" SEC_ProgramMenuShortcut
        SectionIn 2
        CreateShortCut "$SMPROGRAMS\${STR_AppName}.lnk" "$INSTDIR\${STR_AppName}.exe"
    SectionEnd
    
    Section "$(LNG_StartMenuShortcut)" SEC_StartMenuShortcut
        SectionIn 2
        CreateShortCut "$STARTMENU\${STR_AppName}.lnk" "$INSTDIR\${STR_AppName}.exe"
    SectionEnd

    Section "$(LNG_QuickLaunchShortcut)" SEC_QuickLaunchShortcut
        SectionIn 2
        CreateShortCut "$QUICKLAUNCH\${STR_AppName}.lnk" "$INSTDIR\${STR_AppName}.exe"
    SectionEnd
SectionGroupEnd
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 完成安裝
Section "-PostInstall"
    WriteUninstaller "$INSTDIR\Uninstall ${STR_AppName}.exe"
    WriteRegStr HKLM "${REG_AppPath}" "" "$INSTDIR\CuteFoto.exe"
    WriteRegStr HKLM "${REG_Uninstall}" "DisplayName" "$(^Name)"
    WriteRegStr HKLM "${REG_Uninstall}" "UninstallString" "$INSTDIR\Uninstall ${STR_AppName}.exe"
    WriteRegStr HKLM "${REG_Uninstall}" "DisplayIcon" "$INSTDIR\CuteFoto.exe"
    WriteRegStr HKLM "${REG_Uninstall}" "DisplayVersion" "${STR_Version}"
    WriteRegStr HKLM "${REG_Uninstall}" "URLInfoAbout" "${STR_HomepageUrl}"
    WriteRegStr HKLM "${REG_Uninstall}" "Publisher" "${STR_Publisher}"
SectionEnd
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 解除安裝
Section "Uninstall"
    Delete /REBOOTOK "$SMPROGRAMS\${STR_AppName}\${STR_AppName}.lnk"
    Delete /REBOOTOK "$SMPROGRAMS\${STR_AppName}\${STR_AppName} $(LNG_Help).lnk"
    Delete /REBOOTOK "$SMPROGRAMS\${STR_AppName}\${STR_AppName} $(LNG_Homepage).url"
    Delete /REBOOTOK "$SMPROGRAMS\${STR_AppName}\$(LNG_Uninstall) ${STR_AppName}.lnk"

    Delete /REBOOTOK "$DESKTOP\${STR_AppName}.lnk"
    Delete /REBOOTOK "$SMPROGRAMS\${STR_AppName}.lnk"
    Delete /REBOOTOK "$STARTMENU\${STR_AppName}.lnk"
    Delete /REBOOTOK "$QUICKLAUNCH\${STR_AppName}.lnk"

    Delete /REBOOTOK "$INSTDIR\${STR_AppName}.exe"
    Delete /REBOOTOK "$INSTDIR\${STR_AppName}.chm"
    Delete /REBOOTOK "$INSTDIR\English.lng"
    Delete /REBOOTOK "$INSTDIR\English (Capital).lng"
    Delete /REBOOTOK "$INSTDIR\Chinese (Simplified).lng"

    Delete /REBOOTOK "$INSTDIR\${STR_AppName}.ini"
    Delete /REBOOTOK "$INSTDIR\Uninstall ${STR_AppName}.exe"

    RMDir /REBOOTOK "$SMPROGRAMS\${STR_AppName}"
    RMDir /REBOOTOK "$INSTDIR"

    DeleteRegKey HKLM "${REG_Uninstall}"
    DeleteRegKey HKLM "${REG_AppPath}"
    SetAutoClose True
SectionEnd
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 節描述
!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_ProgramFile} "$(LNG_ProgramFileDesc)"
    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_LanguageFile} "$(LNG_LanguageFileDesc)"
    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_Shortcut} "$(LNG_CreateShortcutDesc)"

    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_X86Ascii} "$(LNG_X86AsciiDesc)"
    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_X86Unicode} "$(LNG_X86UnicodeDesc)"
    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_X64Unicode} "$(LNG_X64UnicodeDesc)"

    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_English} "Install language file: English (For translation only)."
    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_CapitalEnglish} "INSTALL LANGUAGE FILE: CAPITAL ENGLISH."
    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_SimplifiedChinese} "安裝語言檔案: 簡體中文。"

    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_ProgramMenuShortcutGroup} "$(LNG_CreateShortcutDesc)"
    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_DesktopShortcut} "$(LNG_CreateShortcutDesc)"
    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_ProgramMenuShortcut} "$(LNG_CreateShortcutDesc)"
    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_StartMenuShortcut} "$(LNG_CreateShortcutDesc)"
    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_QuickLaunchShortcut} "$(LNG_CreateShortcutDesc)"

    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_AppNameShortcut} "$(LNG_CreateShortcutDesc)"
    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_HelpShortcut} "$(LNG_CreateShortcutDesc)"
    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_HomePageShortcut} "$(LNG_CreateShortcutDesc)"
    !insertmacro MUI_DESCRIPTION_TEXT ${SEC_UninstallShortcut} "$(LNG_CreateShortcutDesc)"
!insertmacro MUI_FUNCTION_DESCRIPTION_END
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 初始化回撥函式
Function .onInit
    StrCpy $1 ${SEC_X86Ascii}

    ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion" "CurrentVersion"
    ${If} $0 != ""
        SectionSetInstTypes ${SEC_X86Ascii} 0
        !insertmacro UnselectSection ${SEC_X86Ascii}
        !insertmacro ClearSectionFlag ${SEC_X86Unicode} ${SF_RO}

        ReadRegStr $0 HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" "PROCESSOR_ARCHITECTURE"
        ${If} $0 != "AMD64"
            SectionSetInstTypes ${SEC_X86Unicode} 7
            !insertmacro SelectSection ${SEC_X86Unicode}
            StrCpy $1 ${SEC_X86Unicode}
        ${Else}
            SectionSetInstTypes ${SEC_X64Unicode} 7
            !insertmacro ClearSectionFlag ${SEC_X64Unicode} ${SF_RO}
            !insertmacro SelectSection ${SEC_X64Unicode}
            StrCpy $1 ${SEC_X64Unicode}
        ${EndIf}        
    ${EndIf}
    
    !insertmacro MUI_LANGDLL_DISPLAY
FunctionEnd
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 選擇改變
Function .onSelChange
    !insertmacro StartRadioButtons $1
        !insertmacro RadioButton ${SEC_X86Ascii}
        !insertmacro RadioButton ${SEC_X86Unicode}
        !insertmacro RadioButton ${SEC_X64Unicode}
    !insertmacro EndRadioButtons
FunctionEnd
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 解除安裝初始化
Function un.onInit
    !insertmacro MUI_UNGETLANGUAGE
FunctionEnd
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


相關推薦

轉一篇寫的不錯的NSIS打包指令碼示例

---------------------------------------------------------------------------------------------- 這幾天稍稍深入地使用了一下 NSIS，功能太強大了。回首看看不比學習一門高階語言

轉一篇MYSQL文章《數據庫表設計，沒有最好只有最適合》

其他 eqv 新的 fmt 記錄 ces 末尾 base64 過程 http://mp.weixin.qq.com/s/a8klpzM5iam0_JYSw7-U4g 我們在設計數據庫的時候，是否會突破常規，找到最適合自己需求的設計方案，下面來舉個例子： 常用的鄰接表設計

PHP利用多程序處理任務(一篇寫得比較容易理解的多程序文章）

　PHP多程序一般應用在PHP_CLI命令列中執行php指令碼，不要在web訪問時使用。  　　多程序處理分解任務一般要比單程序更快。   php檢視是否安裝多程序模組： php -m

轉一篇關於如何在Unity裡使用Protobuf

https://www.cnblogs.com/designyourdream/p/4268092.html 原帖地址： http://purdyjotut.blogspot.com/2013/10/using-protobuf-in-unity3d.html 先轉過來，等時間合適了，再

一篇文章學懂Shell指令碼，最簡明的教程在這裡

Shell指令碼,就是利用Shell的命令解釋的功能，對一個純文字的檔案進行解析，然後執行這些功能，也可以說Shell指令碼就是一系列命令的集合。 Shell可以直接使用在win/Unix/Linux上面，並且可以呼叫大量系統內部的功能來解釋執行程式，如果熟練掌握Shell指令碼，可以

一篇文章學懂Shell指令碼

Shell指令碼,就是利用Shell的命令解釋的功能，對一個純文字的檔案進行解析，然後執行這些功能，也可以說Shell指令碼就是一系列命令的集合。 Shell可以直接使用在win/Unix/Linux上面，並且可以呼叫大量系統內部的功能來解釋執行程式，如果熟練掌握Shell

ElasticSearch原始碼解析（一）:轉一篇介紹中文分詞的文章

轉自：http://www.cnblogs.com/flish/archive/2011/08/08/2131031.html  基於CRF（Conditional Random Field）分詞演算法 論文連結：http://nlp.stanford.edu/pubs/

轉一篇有關Java的記憶體洩露的文章（受益哦）

引言      Java的一個重要優點就是通過垃圾收集器GC （Garbage Collection）自動管理記憶體的回收，程式設計師不需要通過呼叫函式來釋放記憶體。因此，很多程式設計師認為Java 不存在記憶體洩漏問題，或者認為即使有記憶體洩漏也不是程式的責任，而是GC 或JVM的問題。其實，這種想法是

一篇很不錯的單例模式詳解

1、什麼是設計模式？       首先我們來看第一個問題什麼是設計模式？在百度百科中它的定義是這樣的： 設計模式（Design pattern）是一套被反覆使用、多數人知曉的、經過分類編目的、程式碼設計經驗的總結。(百度百科)   &nb

nsis打包指令碼

最近在打包一個WEB程式，執行環境是PHP+Apache2+Mysql。打包過程比較順利，註冊服務、啟動都能成功。遇到一個問題，就是修改配置檔案的問題。既然是打包程式，當然要求打包的程式可以安裝在任意位置都能夠正常執行，修改apache伺服器的httpd.conf檔案費了我不

轉一篇有關JAVA的記憶體洩露的文章

引言      Java的一個重要優點就是通過垃圾收集器GC （Garbage Collection）自動管理記憶體的回收，程式設計師不需要通過呼叫函式來釋放記憶體。因此，很多程式設計師認為Java 不存在記憶體洩漏問題，或者認為即使有記憶體洩漏也不是程式的責任，而是GC 或JVM的問題。其實，這種想法是不正

轉一篇 有關JAVA的記憶體洩露的文章

1 引言     Java的一個重要優點就是通過垃圾收集器GC （Garbage Collection）自動管理記憶體的回收，程式設計師不需要通過呼叫函式來釋放記憶體。因此，很多程式設計師認為Java 不存在記憶體洩漏問題，或者認為即使有記憶體洩漏也不是程式的責任，而是GC 或JVM的問題。其實，這種想法是不

一篇寫給準備升級PHP7的小夥伴的文章

前言 本文是一篇講座聽後＋後續研究的總結。 話說當年追時髦，php7一出就給電腦立馬裝上了，php5和php7共存，也是立馬寫了個超級耗時間的迴圈指令碼測了一番，確實php7給力很多，然後也是注意了一些新增的特性與一些丟棄掉的用法。 由於php升級乃頭等大

轉一篇關於加密密碼安全性的文章

引子 最近有個虛擬練習專案，涉及到系統安全保障的設計，於是對安全保障這塊做了一些更深入的瞭解。發現了很多有趣的東西，開闊了眼界。中間查了一些資料，於是我打算重新整理，用更加循序漸進，大家都能懂的方式，說一說如何設計一個安全的系統。 著名的安全事件 首先來看看最近幾年

轉一篇比較詳細介紹FatFs檔案系統移植的文章 FatFs檔案系統的移植

  因為需要，又不想自己寫，所以就移植了一個檔案系統。     說下我的硬體和開發工具：接成 TRUE IDE 模式下的CF卡（也就是相當於一塊硬碟了），三星S3C2440的ARM9,開發工具是很老很老的D版的ADS1.2。    

轉一篇比較詳細介紹FatFs檔案系統移植的文章

摘自：http://blog.163.com/[email protected]/blog/static/3278568820090710053782/ 補充一點，FatFs的作者寫了兩個，一個是正宗的FatFs，比較適合大的RAM的裝置，另一個是FatFs/

轉載一篇很不錯的影評（返老還童）

 一個奇異的開始，註定了奇異的結束。一個魔幻的故事，譜寫著非凡的人生 　　　　一座死神頻顧的敬老院，宛如子宮般死寂，卻成為本傑明．巴頓的精神家園，詮釋著生與死的從容與詩意。 　　　　一股湧動不息的青春情慾，一段四海為家的船員生活，寫下了一個個自然淡定的荒唐故事，留下了一個個無法挽回的人生遺憾。 　　　　一個青

轉一篇關於android開發框架的全域性理解的好文

轉自：http://www.thinkphp.cn/document/382.html 導讀：對於Android開發者來說，成系列的技術文章對他們的技術成長幫助最大。如下是我們向您強烈推薦的主題為Android開發的第一個系列文章。 《Android核心分析》整理如下

寫的不錯的一篇雲資料庫的文章

本文作者：許中清，騰訊雲自研資料庫CynosDB的分散式儲存CynosStore負責人。從事資料庫核心開發、資料庫產品架構和規劃。曾就職於華為，2015年加入騰訊，參與過TBase（PGXZ）、CynosDB等資料庫產品研發。專注於關係資料庫、

轉載一篇關於springmvc下session的用法，覺得作者寫的不錯，給大家分享一下

繫結模型物件中某個屬性 Spring 2.0 定義了一個 org.springframework.ui.ModelMap 類，它作為通用的模型資料承載物件，傳遞資料供檢視所用。我們可以在請求處理方法中宣告一個 ModelMap 型別的入參，Spring 會將本次請求模型物