halcon的模板匹配種類有很多種，方法各有優缺點，一般有基於灰度的匹配，基於形狀的匹配等等，這裡具體理論和方法不做詳解，只簡單總結一個例項。影象匹配一般需要對旋轉放縮排行處理，另外為了提高搜尋效率，常用用影象金字塔來處理模板影象，影象金子塔就是把影象按一定演算法，縮小為不同比例的模板，減少畫素。一般的模板匹配流程如下：

所以首先建立模板，模板的建立就是採集一張自己需要的原始影象，如下我採集的原始影象：

我需要的是銀聯那個標誌，生成模板的原始碼如下：

read_image (Image, 'E:/HalconTest/實驗2d匹配/exp/110.jpg')
*讀取模板影象
rgb1_to_gray (Image, GrayImage)
*灰度操作
gen_rectangle1 (ROI_0, 189.5, 531.5, 325.5, 717.5)
*選擇要匹配的影象，去除不必要的
reduce_domain (GrayImage, ROI_0, ImageReduced2)
*減少影象，分割出切除的那部分
bin_threshold (ImageReduced2, Region1)
*自動灰度閾值處理
connection (Region1, ConnectedRegions1)
*求聯通域
select_shape (ConnectedRegions1, SelectedRegions1, 'area', 'and', 8, 14016)
*選擇影象
reduce_domain (ImageReduced2, SelectedRegions1, ImageReduced3)
*分割出影象
inspect_shape_model (ImageReduced3, ModelImages1, ModelRegions1, 4, 30)
*建立一個形狀的表示模型
create_scaled_shape_model (ImageReduced3, 'auto', rad(-45), rad(90), 'auto', 0.9, 1, 0, 'no_pregeneration', 'ignore_global_polarity', 'auto', 'auto', ModelID)
*使用用影象建立帶有縮放的匹配模板，上面的灰度分割什麼的其實可以不要
*NumLevels 最高金子塔層數
*AngleStart 開始角度加rad(90)是將弧度制轉為角度值
*AngleExtent 角度範圍
*AngleStep 旋轉角度步長
*ScaleMin 模板行方向縮放最小尺度
*ScaleMax 模板行方向縮放最大尺寸
*MinScore 最低匹配分值 百分比
*ScaleStep 步長
*Optimization 優化選項 是否減少模板點數
*Metric 匹配度量級性旋轉 
*MinContrast 最小對比度
*ModelID 生成模板ID
write_shape_model (ModelID, 'C:/Users/shanwenjun/Desktop/img_model3.shm')
*生成模板檔案
 

生成的模板檔案要用來進行匹配，下面是我用攝像頭進行實時匹配的影象：

匹配的的原始碼如下，左上角是影象處理過程疊加的：

dev_close_window ()
dev_open_window (0, 0, 640, 480, 'black', WindowHandle)
*先關閉活動圖形視窗，再開啟這個視窗，識別符號為WindowHandle；
*相對於介面左上角第0行、第0列，大小是我相機的拍照比例，顏色為黑色。
open_framegrabber ('MindVision11', 1, 1, 0, 0, 0, 0, 'progressive', 8, 'Gray', -1, 'false', 'auto', 'Camera MV-U130RC#C17D8221-3', 0, -1, AcqHandle)
*DirectShow是筆記本攝像頭或者其他DirectShow的攝像頭，MindVision11是我相機的攝像頭；
* 注意攝像頭的名稱,可以用工具欄中的“助手”——開啟新的Image Acquisition獲取攝像頭及插入程式碼

grab_image_start (AcqHandle, -1)
while (true)
 grab_image_async (Image, AcqHandle, -1) 
* Calibration 01: Code generated by Calibration 01
CamParOriginal:= [0.01629,-2024.24,8.30436e-006,8.3e-006,710.402,361.975,1280,960]
CameraPose := [-0.0236413,0.0135896,0.152813,16.2821,3.05758,76.5791,0]
*上面是我相機的標定量，根據自己相機標定填寫，此段程式碼不可直接用

CamParVirtualFixed:=CamParOriginal  
CamParVirtualFixed[1]:=0  
*上面是標定時候的引數設定

gen_radial_distortion_map(MapFixed,CamParOriginal,CamParVirtualFixed,'bilinear')  
*生產徑向畸變對映圖，  
*mapfixed是輸出，  
*CamParOriginal是標定後的引數，  
*CamParVirtualFixed也是輸出的引數，  
*'bilinear'對映型別 

map_image(Image,MapFixed,ImageRectifiedFixed)  
*利用對映，消除影象畸變運算元 

read_shape_model ('E:/HalconTest/實驗2d匹配/img_model/img_model3.shm', ModelID)
*讀取影象
find_scaled_shape_model (ImageRectifiedFixed, ModelID, rad(-180), rad(180), 0.5, 1.2, 0.3, 1, 0.5, 'none', 4, 0.9, Row, Column, Angle, Scale, Score)
*尋找單個帶尺度形狀模板最佳匹配
*ImageRectifiedFixed 要搜尋的影象
*ModelID 模板ID
*AngleStart 開始角度加rad(90)是將弧度制轉為角度值
*AngleExtent 角度範圍
*ScaleMin 模板行方向縮放最小尺度
*ScaleMax 模板行方向縮放最大尺寸
*MinScore 最低匹配分值 百分比
*NumMatches 匹配例項的個數
*MaxOverlap 最大重疊 在有重疊時也可檢測匹配
*SubPixel 是否亞畫素精度
*NumLevels 金子塔層數
*Greediness 搜尋貪婪度； 0安全慢；1塊不穩定；其他就是介於中間值
*剩下的幾個引數是匹配影象的位置狀態等引數
get_shape_model_contours (ModelContours, ModelID, 1)
*返回匹配結果的輪廓

for I := 0 to |Score| - 1 by 1
    *for迴圈查詢匹配
     vector_angle_to_rigid (0, 0, 0, Row[I], Column[I], Angle[I], HomMat2DRotate)
    *單匹配計算剛性變換矩陣 為了顯示匹配影象
     hom_mat2d_scale (HomMat2DRotate, Scale[I], Scale[I], Row[I], Column[I], HomMat2DScale)
     *新增一個擴充套件到一個均勻的二維變換矩陣 為了顯示匹配影象
     affine_trans_contour_xld (ModelContours, ModelTrans, HomMat2DScale)       
     *應用任意二維仿射變換XLD輪廓 為了顯示匹配影象
     disp_message (WindowHandle,'匹配一個', 'image', Row[I], Column[I]+100, 'blue', 'true') 
     *新增文字
     dev_display (ModelTrans)
     *顯示模型 為了顯示匹配影象
endfor
 
disp_continue_message (WindowHandle, 'black', 'true')
stop ()
* ****
* step: destroy model
* ****
endwhile
clear_shape_model (ModelID)