我們知道Erlang的排程器是公平的，當程序的時間片用完了後，會強制切出，但是這個粒度是比較粗的。比如說程序進行了大量的Io操作，這個操作換成時間片是不準確的，會導致某些CPU計算密集型的比較吃虧，IO密集型的合算。

為了避免這個情況，IO密集型的經常可以互動要求短暫放棄執行，最簡單的方法就是用訊息等待機制。當程序在等訊息的時候，就會被切出，我們就達到目的。

我們可以參考mnesia的實現：

%%mnesia_dumper.erl:L1181
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%                                                       
%% Load regulator                                                                                                            
%%                                                                                                                           
%% This is a poor mans substitute for a fair scheduler algorithm                                                             
%% in the Erlang emulator. The mnesia_dumper process performs many                                                           
%% costly BIF invokations and must pay for this. But since the                                                               
%% Emulator does not handle this properly we must compensate for                                                             
%% this with some form of load regulation of ourselves in order to                                                           
%% not steal all computation power in the Erlang Emulator ans make                                                           
%% other processes starve. Hopefully this is a temporary solution.                                                           

start_regulator() ->
    case mnesia_monitor:get_env(dump_log_load_regulation) of
        false ->
            nopid;
        true ->
            N = ?REGULATOR_NAME,
            case mnesia_monitor:start_proc(N, ?MODULE, regulator_init, [self()]) of
                {ok, Pid} ->
                    Pid;
                {error, Reason} ->
                    fatal("Failed to start ~n: ~p~n", [N, Reason])
            end
    end.

regulator_init(Parent) ->
    %% No need for trapping exits.                                                                                           
    %% Using low priority causes the regulation                                                                              
    process_flag(priority, low),
    register(?REGULATOR_NAME, self()),
    proc_lib:init_ack(Parent, {ok, self()}),
    regulator_loop().

regulator_loop() ->
    receive
        {regulate, From} ->
            From ! {regulated, self()},
            regulator_loop();
        {stop, From} ->
            From ! {stopped, self()},
            exit(normal)
    end.

regulate(nopid) ->
    ok;
regulate(RegulatorPid) ->
    RegulatorPid ! {regulate, self()},
    receive
        {regulated, RegulatorPid} -> ok
    end.

祝玩得開心!

Post Footer automatically generated by wp-posturl plugin for wordpress.

No related posts.