ReportMachine不能開啟列印設定的解決方法

1、問題現象

在使用ReportMachine作為報表列印時，發現不能呼叫本機印表機屬性設定對話方塊，如下圖：

 點選“屬性”按鈕後無反應，從而不能對印表機屬性進行設定。該問題同時也導致不能獲取印表機設定資訊。

2、問題原因

跟蹤程式碼發現點選“屬性”，會呼叫“PropertiesDlg”函式，RM_Printer.pas檔案中，程式碼如下：

function TRMPrinter.PropertiesDlg: Boolean;
var
    lDevMode: THandle;
    lPDevMode: PDeviceMode;
    lHandle: THandle;
    lResult: Boolean;
begin
 

    FLock.Acquire;
    try
        GetDevMode(lDevMode);  //呼叫返回lDevMode一直為0 
        Result := False;
        lResult := FALSE;
        try
            lPDevMode := GlobalLock(lDevMode);//不能分配記憶體，lPDevMode 為nil.
            if Screen.ActiveForm <> nil then
                lHandle := Screen.ActiveForm.Handle
            else
 

                lHandle := 0;

            if lPDevMode <> nil  then  //lPDevMode 為nil，不呼叫印表機屬性設定
                lResult := (Winspool.DocumentProperties(lHandle, PrinterHandle, PChar(PrinterInfo.Device),
                    lPDevMode^, lPDevMode^, DM_IN_BUFFER or DM_OUT_BUFFER or DM_IN_PROMPT) > 0
 
);

            if lResult then
            begin
                SetDevMode(lDevMode);
                Result := True;
            end;

            GlobalUnlock(lDevMode);
        finally
            GlobalFree(lDevMode);
        end;
    finally
        FLock.Release;
    end;
end;

進而跟蹤GetDevMode，找到RM_Printer.pas檔案中GetDocumentProperties函式，程式碼段如下：

function TRMCustomPrinter.GetDocumentProperties: THandle;
var
    lStubDevMode: TDeviceMode;
    lPrinterInfo: TRMPrinterInfo;
begin
    FLock.Acquire;
    try
        Result := 0;
        if FDevMode = 0 then
        begin
            lPrinterInfo := RMPrinters.PrinterInfo[FPrinterIndex];
            if lPrinterInfo = nil then
                Exit;

            FDevMode := GlobalAlloc(GHND,
                DocumentProperties(0, PrinterHandle, PChar(lPrinterInfo.Device), lStubDevMode, lStubDevMode, 0));
            //這裡FDevMode 執行後始終為0，函式反饋也就為0.同時，導致以下IF內程式碼不會執行，不能獲取印表機屬性資訊。

            if FDevMode <> 0 then
            begin
                FPDevMode := GlobalLock(FDevMode);
                if DocumentProperties(0, PrinterHandle, PChar(lPrinterInfo.Device), FPDevMode^, FPDevMode^, DM_OUT_BUFFER) >= 0 then
                begin
                    FDefaultBin := FPDevMode^.dmDefaultSource;
                end
                else
                    FreeDevMode;
            end;
        end;
        Result := FDevMode;
    finally
        FLock.Release;
    end;
end;

3、解決辦法

更改GetDocumentProperties函式中的程式碼

DocumentProperties(0, PrinterHandle, PChar(lPrinterInfo.Device), lStubDevMode, lStubDevMode, 0)

為

DocumentProperties(0, PrinterHandle, PChar(lPrinterInfo.Device), nil, nil, 0)

  完整程式碼如下：

function TRMCustomPrinter.GetDocumentProperties: THandle;
var
//  lStubDevMode: TDeviceMode;
    lPrinterInfo: TRMPrinterInfo;
begin
    FLock.Acquire;
    try
        Result := 0;
        if FDevMode = 0 then
        begin
            lPrinterInfo := RMPrinters.PrinterInfo[FPrinterIndex];
            if lPrinterInfo = nil then
                Exit;

            FDevMode := GlobalAlloc(GHND,
                DocumentProperties(0, PrinterHandle, PWideChar(lPrinterInfo.Device), nil, nil, 0));

            if FDevMode <> 0 then
            begin
                FPDevMode := GlobalLock(FDevMode);
                if DocumentProperties(0, PrinterHandle, PChar(lPrinterInfo.Device), FPDevMode^, FPDevMode^, DM_OUT_BUFFER) >= 0 then
                begin
                    FDefaultBin := FPDevMode^.dmDefaultSource;
                end
                else
                    FreeDevMode;
            end;
        end;
        Result := FDevMode;
    finally
        FLock.Release;
    end;
end;