遊標就是移動的游標，可以用來逐條或批量的處理資料。當遊標移動到某行時，即可對該行資料進行操作，如提取資料等。

遊標有一下四個屬性，即這四個屬性僅可被用於遊標上：%isopen判斷遊標是否被開啟，值為true或false；%found和%notfound判斷遊標所在行是否有效，一般沒有資料了既是無效，值也是true或false；%rowcount返回的是當前位置為止遊標讀取的記錄行數。

比如我有一個users表，儲存使用者名稱和密碼等資訊，現在我想用遊標對資料進行遍歷處理，我就可以這樣寫：

declare 
v_username users.username%type;
v_password users.password%type;
cursor c is select t.username,t.password from users t;
begin
  open c;
  loop
  fetch c into v_username,v_password;
  exit when c%notfound;
  dbms_output.put_line('使用者'||v_username||'的密碼是'||v_password);
  end loop;
  dbms_output.put_line('一共有'||c%rowcount||'條記錄');
  close c;
end;
 

第二三行定義變數，用於獲得遊標當前位置的資料，為了防止資料型別不一致，可以用“表名.列名%type”的形式獲取到合適的資料型別，即如果表users中列username的資料型別是varchar的話，那麼v_username的資料型別也是varchar。後面還會給出另一種獲得資料型別的方式。

第四行就是定義遊標了，注意不能把值直接賦給遊標，也不能在表示式中使用遊標。is後面是遊標的定義，是一個查詢語句，表明了遊標在這個操作時，會發生作用，逐條指向這個操作產生的資料。

從第五行開始就是程式主體。首先我們需要開啟遊標，不開啟遊標將會得到錯誤提示。接著迴圈處理，將每次遊標提取到的資料放入變數中（第八行）。

第九行是一個退出的判斷，即當遊標查詢不到資料時，退出迴圈。

第十行是輸出語句，輸出迴圈的結果。

第十二行利用遊標屬性%rowcount統計了記錄總數。

結束時要關閉遊標。

程式執行結果如圖：

如果你覺得逐條處理過於繁瑣，遊標也提供了批量處理資料的方式，利用bulk collect：

declare
type username_type is table of users.username%type;
type password_type is table of users.password%type;
v_username username_type;
v_password password_type;
cursor c is select t.username,t.password from users t;
begin
  open c;
  fetch c
  bulk collect into v_username,v_password;
  ......
  close c;
end;
 

這裡給出了另一種獲取資料型別的方式，先定義type型別username_type來接收資料型別，接著將其賦給變數v_username。

在使用bulk collect時，直接在fetch c後面加入bulk collect，則這時變數v_username和v_password中儲存的是所有資料的集合，因此不能向上面那樣使用dbms_output.put_line將其輸出。

如果你經常使用遊標，會發現頻繁地寫open、fetch、close會顯得很麻煩，因此我們可以用一個遊標for迴圈來簡化操作及程式碼。上面的遊標操作可以寫為：

declare
cursor c is select t.username,t.password from users t;
begin
  for c_rec in c loop
    dbms_output.put_line('使用者'||c_rec.username||'的密碼是'||c_rec.password);
    dbms_output.put_line('一共有'||c%rowcount||'條記錄');
  end loop;  
end;

這時我們不必再定義變數來儲存遊標處理的資料了，且也不必再開啟或關閉遊標了，因為for迴圈一開始，遊標便被開啟，結束迴圈，遊標則自動關閉。值得注意的是，這裡有一個隱式宣告的記錄c_rec，它的每一個域都儲存來自遊標c中取出的值。因此我們就可以利用它來找到遊標獲取的使用者名稱和密碼。另外這個c_rec不是遊標，因此不能用它來統計記錄數，即不可以寫c_rec%rowcount，這是錯誤的。

操作結果如圖：

更加簡潔地，你可以用子查詢來代替遊標：

declare
begin
  for c_rec in (select t.username,t.password from users t) loop
    dbms_output.put_line('使用者'||c_rec.username||'的密碼是'||c_rec.password);
  end loop;  
end;

但是這樣用%rowcount統計記錄數就變得十分麻煩。因此我們可以換個思路，我們定義一個變數，讓其在for迴圈中，每執行一次便+1，這樣我們就能統計出記錄數了。這就是在for迴圈中使用引數。同樣，我們也可以在遊標中使用引數，傳遞一些我們暫時不能確定的值：

declare
v_name users.username%type;
v_record number:=0;
begin
  select '123qwe' into v_name from dual;
  for c_rec in (select t.username,t.password from users t where t.username=v_name) loop
    v_record:=v_record+1;
    dbms_output.put_line('使用者'||c_rec.username||'的密碼是'||c_rec.password);
    dbms_output.put_line('一共有'||to_char(v_record)||'條記錄');
  end loop;  
end;

上面的程式是為了找出使用者名稱為“123qwe”的使用者，我們將這個值賦給v_name，然後傳遞給遊標（即那個子查詢）。for迴圈中的引數我們也可以在前面定義好，後面拿來直接使用（這個v_record是需要初始化的，即需要賦初始值，如果你寫成v_record number;，那麼在下面的操作中這個v_record始終是空的，你可以自己試試）。

執行結果如圖：

很好地完成了統計記錄的操作。

我們可以用遊標寫出很複雜的操作，比如處理某些員工的工資等，在loop中寫合適的程式體即可。

下一章我會介紹遊標變數。遊標是靜態的，遊標變數是動態的，它們之間的區別就像常量和變數一樣。下回再說。