PLSQL的應用例項

一、統計每年入職的員工人數

分析：

SQL語句：
select to_char(hiredate,'yyyy') from emp;
---> 集合 ---> 游標 ---> 迴圈  ---> 退出條件:notfound

變數：1. 初始值  2. 最終得到
每年入職的員工人數:
count80 number := 0;
count81 number := 0;
count82 number := 0;
count87 number := 0;

解：

set serveroutput on

declare
  cursor cemp is select to_char(hiredate,'yyyy') from emp;
  phiredate varchar2(4);

  --每年入職的員工人數:
  count80 number := 0;
  count81 number := 0;
  count82 number := 0;
  count87 number := 0;
begin
  open cemp;
  loop
    --取一個員工的入職年份
    fetch cemp into phiredate;
    --退出條件:notfound
    exit when cemp%notfound;

    --判斷年份
    if phiredate = '1980' then count80:=count80+1;
      elsif phiredate = '1981' then count81:=count81+1;
      elsif phiredate = '1982' then count82:=count82+1;
      else count87:=count87+1;
    end if;
  end loop;
  close cemp;

  dbms_output.put_line('Total:'||(count80+count81+count82+count87));
  dbms_output.put_line('1980:'||count80);
  dbms_output.put_line('1981:'||count81);
  dbms_output.put_line('1982:'||count82);
  dbms_output.put_line('1987:'||count87);
end;
 

二、使用scott使用者下的emp表：

為員工漲工資。從最低工資調起每人漲10%，但工資總額不能超過5萬元，請計算漲工資的人數和漲工資後的工資總額，並輸出漲工資人數及工資總額。

分析：

SQL語句：
select empno,sal from emp order by sal;
---> 游標 ---> 退出：1. 總額 > 5w   2. notfound

變數：1. 初始值  2. 最終得到
漲工資的人數: countEmp number := 0;
漲後的工資總額: salTotal number;
1. select sum(sal) into salTotal from emp;
2. 漲後=漲前 + sal * 0.1
 

解：

set serveroutput on
declare
  cursor cemp is select empno,sal from emp order by sal;
  pempno emp.empno%type;
  psal   emp.sal%type;
  --漲工資的人數: 
  countEmp number := 0;
  --漲後的工資總額: 
  salTotal number;
begin
  --得到初始的工資總額
  select sum(sal) into salTotal from emp;

  open cemp;
  loop
    --1. 總額 > 5w
    exit when salTotal > 50000;
    --取一個員工
    fetch cemp into pempno,psal;
    --2. notfound
    exit when cemp%notfound;

    --漲工資
    update emp set sal=sal*1.1 where empno=pempno;
    --人數+1
    countEmp := countEmp + 1;
    --2. 漲後=漲前 + sal * 0.1
    salTotal := salTotal + psal * 0.1;

  end loop;
  close cemp;

  commit;
  dbms_output.put_line('人數:'||countEmp||'   總額:'||salTotal);

end;
 

三、

用PL/SQL語言編寫一程式，實現按部門分段（6000以上、（6000,3000）、3000以下）統計各工資段的職工人數、以及各部門的工資總額（工資總額中不包括獎金）

建立一張表來儲存資料：

create table msg
(deptno number,
 count1 number,
 count2 number,
 count3 number,
 saltotal number);

分析：

SQL語句：
部門: select deptno from dept;
部門中員工的薪水：select sal from emp where deptno=???


變數：1. 初始值  2. 最終得到
每個段的人數:
count1 number; count2 number; count3 number;
部門的工資總額: salTotal number := 0;
1.select sum(sal) into salTotal from emp where deptno=???
2.累加

解：

set serveroutput on
declare
  --部門
  cursor cdept is select deptno from dept;
  pdeptno dept.deptno%type;

  --部門中員工的薪水
  cursor cemp(dno number) is select sal from emp where deptno=dno;
  psal emp.sal%type;
  --每個段的人數:
  count1 number; count2 number; count3 number;
  --部門的工資總額: 
  salTotal number := 0;
begin
  open cdept;
  loop
    --取一個部門
    fetch cdept into pdeptno;
    exit when cdept%notfound;

    --初始化
    count1:=0;count2:=0;count3:=0;
    --部門的工資總額
    select sum(sal) into salTotal from emp where deptno=pdeptno;

    --取部門中員工的薪水
    open cemp(pdeptno);
    loop
      --取一個員工
      fetch cemp into psal;
      exit when cemp%notfound;

      --判斷
      if psal < 3000 then count1:=count1+1;
        elsif psal>=3000 and psal<6000 then count2:=count2+1;
        else count3:=count3+1;
      end if;
    end loop;
    close cemp;

    --儲存結果
    insert into msg values(pdeptno,count1,count2,count3,nvl(saltotal,0));

  end loop;
  close cdept;

  commit;
  dbms_output.put_line('完成');
end;

四、

用PLSQL語言編寫一個程式。按系(系名）分段統計（成績小於60分，60-85分, 85分以上）“大學物理”課程各分數段的學生人數，及各系學生的平均成績。
提示：可建立一張新表，存放統計資訊。

參考執行結果：

分析：

--建立存放資料的結構表：
create table msg
(cname char(20),
 dname char(30),
 seg_1 number,
 seg_2 number,
 seg_3 number,
 avggrade number(4,2)
 );

--利用游標迴圈處理資料，並把處理結果寫到結果表中：

答案：

方式一：

declare 
  cursor c1 is select distinct dno,dname from dep order by dno;
  cursor c2(c_name char) is select student.dno,grade,course.cname from student,dep,sc,course 
                            where student.dno=dep.dno and student.sno=sc.sno and course.cno=sc.cno and cname=c_name  order by dno;
  tempcname char(20);
  stu_num1 number;
  stu_num2 number;
  stu_num3 number;
  stu_dno dep.dno%type;
  stu_grade sc.grade%type;
  avggrade number;
  people number;
begin
  open c2('大學物理');
  fetch c2 into stu_dno,stu_grade,tempcname;
  for r1 in c1
  loop
     people:=0;
     stu_num1:=0;
     stu_num2:=0;
     stu_num3:=0;
     avggrade:=0;
     while r1.dno=stu_dno
     loop
        people:=people+1;
        avggrade:=(avggrade*(people-1)+stu_grade)/people;
        if stu_grade<60 then stu_num1:=stu_num1+1;
        elsif stu_grade<85 and stu_grade>=60 then stu_num2:=stu_num2+1;
        else stu_num3:=stu_num3+1;
        end if;

        fetch c2 into stu_dno,stu_grade,tempcname;
        exit when c2%notfound;
     end loop;

     insert into msg values(tempcname,r1.dname,stu_num1,stu_num2,stu_num3,avggrade); 
  end loop;
commit;
end; 

方式二：

declare
   cursor cdep is select distinct dno,dname from dep order by dno;
   cursor cstudent(c_name char,d_no char) is select grade from sc 
                                             where sno in (select distinct sno from student where dno=d_no) 
                                             and cno in (select distinct cno from course where cname=c_name);
   pcName char(8);
   pdno dep.dno%type;
   pdname dep.dname%type;

   stu_num1 number;
   stu_num2 number;
   stu_num3 number;
   stu_grade sc.grade%type;
   sumGrade number;
   people   number;
begin
   pcName := '大學物理';
   open cdep;
   loop
     fetch cdep into pdno,pdname;
     exit when cdep%notfound;
     people:=0;
     stu_num1:=0;
     stu_num2:=0;
     stu_num3:=0;
     sumGrade:=0;
     open cstudent(pcName,pdno);
     loop 
         fetch cstudent into stu_grade;
         exit when cstudent%notfound;
         if stu_grade<60 then stu_num1:=stu_num1+1;
           elsif stu_grade<85 and stu_grade>=60 then stu_num2:=stu_num2+1;
           else stu_num3:=stu_num3+1;
         end if;     
         sumGrade := sumGrade+stu_grade;
         people := people + 1;
     end loop;
     close cstudent;

     if people>0 then
        insert into msg values(pcName,pdname,stu_num1,stu_num2,stu_num3,sumGrade/people);    
     end if;

 end loop;
 close cdep;
commit;
end;