1：對於Arduino，print()和println()函式都是用ASCII字元的方式傳送資料。
無論是int、float還是string，都自動轉換成ASCII碼傳送。
其中println()函式在傳送的資料後面加了回車和換行符（”\r”和”\n”）。換行符正好可以作為結束符來讓手機端識別。
2：藍芽串列埠是非同步傳輸方式，每次Serial.read()只讀一個位元組，在一個loop()迴圈中可能收不全一條資料資訊，必須要有一個全域性變數來收集接收到的字元。如果要通訊可靠，使用結束符來確定收到了一條完整的資訊，是非常必要的。手機端也是一樣。
3：用的Serial.parseInt()函式，作用是在收到的字元流中，找到數字字元，並累積在一起，直到收到一個非數字字元時，將前面收到的數字字元轉換成一個整數。如果要傳送多個數值，中間用逗號等分隔符隔開即可。比如三個數值，”12，325，993“，後面加一個自定義的結束符，作為字串發給Arduino。
（例程中用字元”X”作為結束符。）這樣接收資料完整而可靠。接收float可以用Serial.parseFloat()函式，用法一樣。
4：/* 本例程演示從手機藍芽串列埠接收指令，點亮或熄滅11腳的LED，或者調整亮度。
* 接收指令格式：“101X”點亮，“102X”熄滅，”000X”調整亮度。（000為0-100的整數，表示亮度值，X是結束符。）
* 串列埠是非同步接收的，用parseInt()查詢第一個有效整數，檢測到結束符後開始處理。
* 接收資料顯示在1602LCD屏上。
* 點亮或熄滅LED後，將收到資料回傳給手機。用pringln()函式，資料後面加了”\r”和”\n”兩個字元，可以用作結束符。
* 串列埠傳送的是ASCII字元，資料格式可以自動轉換。
*/

/* 本例程演示從手機藍芽串列埠接收指令，點亮或熄滅11腳的LED，或者調整亮度。
 * 接收指令格式：“101X”點亮，“102X"熄滅，”000X"調整亮度。（000為0-100的整數，表示亮度值，X是結束符。）
 * 串列埠是非同步接收的，用parseInt()查詢第一個有效整數，檢測到結束符後開始處理。
 * 接收資料顯示在1602LCD屏上。
 * 點亮或熄滅LED後，將收到資料回傳給手機。用pringln()函式，資料後面加了"\r"和"\n"兩個字元，可以用作結束符。
 * 串列埠傳送的是ASCII字元，資料格式可以自動轉換。
 */

#include <Wire.h>                  // 包含LCD庫。
 

#include <LiquidCrystal_I2C.h>
LiquidCrystal_I2C lcd(0x27,16,2);  // 初始化LCD物件，地址為0x27，每行16個字元，共兩行。
int p;                             // 定義整數型全域性變數，儲存接收的資料。

void setup() {
  lcd.init();                      // 初始化LCD。 
  lcd.backlight();                 // 開啟LCD背光。
  Serial.begin(9600);              // 開啟串列埠（藍芽）
 

  pinMode(11,OUTPUT);              // 定義11腳為輸出。（數字或PWM）
}

void loop() {
  while (Serial.available() > 0) {   // 串列埠收到字元數大於零。
    p = Serial.parseInt();           // 在串列埠資料流中查詢一個有效整數。
    if (Serial.read() == 'X') {      // 收到結束符後開始處理資料。
      lcd.clear();                   // LCD清屏。
      lcd.print(p);                  // LCD顯示收到的資料（整數）。
      switch (p) {                   // 判斷資料內容。
      case 101:
        digitalWrite(11,HIGH);       // 點亮LED。
        Serial.println(p);           // 回傳資料。
        break;
      case 102:
        digitalWrite(11,LOW);        // 熄滅LED。
        Serial.println(p);           // 回傳資料。
        break;
      default:
        p = map(p,0,100,0,255);      // 轉換資料範圍到PWM輸出值。
        analogWrite(11,p);           // 調整LED亮度。（PWM）
      }
    }
  }
}