/***** 
遍歷資料夾進行資料庫還原
*******/



---需要開啟xp_cmdshell 如已經開啟 可以略過
/***** Step 1 開啟 xp_cmdshell 
Use Master
GO
EXEC master.dbo.sp_configure 'show advanced options', 1
RECONFIGURE WITH OVERRIDE
GO
EXEC master.dbo.sp_configure 'xp_cmdshell', 1
RECONFIGURE WITH OVERRIDE
GO
*******/


IF OBJECT_ID('tempdb..#files') IS NULL
BEGIN
    --DROP TABLE  #files
    CREATE TABLE #files
    (
    	dbname     VARCHAR(200) NULL,
    	dbsql      VARCHAR(7000) NULL
    )
END

DELETE #files 

IF OBJECT_ID('tempdb..#filelistinfo') IS NOT NULL
    DROP TABLE #filelistinfo

CREATE TABLE #filelistinfo
(
	LogicalName              NVARCHAR(128) NULL,
	PhysicalName             NVARCHAR(260) NULL,
	TYPE                     CHAR(1) NULL,
	FileGroupName            NVARCHAR(128) NULL,
	FileSize                 BIGINT NULL,
	MAXSIZE                  BIGINT NULL,
	FileId                   BIGINT,
	CreateLSN                NUMERIC(25, 0),
	DropLSN                  NUMERIC(25, 0) NULL,
	UniqueID                 UNIQUEIDENTIFIER,
	ReadOnlyLSN              NUMERIC(25, 0) NULL,
	ReadWriteLSN             NUMERIC(25, 0) NULL,
	BackupSizeInBytes        BIGINT,
	SourceBlockSize          INT,
	FileGroupID              INT,
	LogGroupGUID             UNIQUEIDENTIFIER NULL,
	DifferentialBaseLSN      NUMERIC(25, 0) NULL,
	DifferentialBaseGUID     UNIQUEIDENTIFIER,
	IsReadOnly               BIT,
	IsPresent                BIT,
	TDEThumbprint            BIT
)





DECLARE @path VARCHAR(500)
DECLARE @pathData VARCHAR(500)
DECLARE @sql VARCHAR(8000)
DECLARE @bakName VARCHAR(500)
DECLARE @LogicalNameDat VARCHAR(500)
DECLARE @LogicalNameLog VARCHAR(500)
DECLARE @tempCommand VARCHAR(800) 

SET @path = 'E:\DataBak'    ---指定要處理的資料夾
SET @sql = 'dir ' + @path + ' /b'
SET @pathData = 'D:\SqlDataBase' ----資料庫還原到的目錄
SET @bakName = ''  -----統一的備份名稱（不要加.bak），比如固定日期或者可變名，根據自己的路徑規則定
  
--獲取檔名稱，存放在#files
INSERT #files
  (
    dbname
  )
EXEC MASTER..xp_cmdshell @sql

  


--從#files表遍歷處理據庫數資訊，根據備份檔案獲取資料邏輯名稱
						 
DECLARE @dbname VARCHAR(50)
DECLARE curs CURSOR 
FOR
    --定義遊標curs
    SELECT dbname
    FROM   #files               
						OPEN curs                       

						FETCH NEXT FROM curs INTO @dbname  

WHILE @@fetch_status = 0 
BEGIN
    SET @bakName = @dbname  --根據自己的路徑規則來定
    
    --根據自己路徑規則拼接資料庫備份檔案路徑，並執行RESTORE FILELISTONLY
    SET @tempCommand = 'restore filelistonly from disk=''' + @path + '\' +
        @dbname + '\' + @bakName + '.bak'''
    
    PRINT @tempCommand
    
    --將得到資料庫的資料存入臨時表#filelistinfo
    INSERT INTO #filelistinfo
    EXEC (@tempCommand)
    
    SELECT @LogicalNameDat = LogicalName
    FROM   #filelistinfo
    WHERE [TYPE]= 'D'  --資料庫檔案
    
    SELECT @LogicalNameLog = LogicalName
    FROM   #filelistinfo
    WHERE [TYPE]= 'L' --日誌檔案
    
    
    --拼接恢復資料庫語句，並更新對應記錄到#files
    UPDATE #files
    SET    dbsql = 'RESTORE DATABASE ' + dbname 
           + ' FROM DISK = ''' + @path + '\' + dbname + '\' + @bakName +
           '.bak''' 
           + ' WITH MOVE ''' + @LogicalNameDat + ''' TO ''' + @pathData + '\' +
           dbname
           + '.mdf'','
           + ' MOVE ''' + @LogicalNameLog + ''' TO ''' + @pathData + '\' +
           dbname +
           '_log.ldf'''
    WHERE  dbname = @dbname
    
    --清除#filelistinfo臨時表，繼續處理下一條記錄
    DELETE FROM   #filelistinfo
    
    FETCH NEXT FROM curs INTO @dbname  
END

					CLOSE curs                   
					DEALLOCATE curs
			 


 	
			
			
SELECT *
FROM   #files


--遍歷#files表 執行恢復
DECLARE cur CURSOR STATIC LOCAL 
FOR
    SELECT dbsql
    FROM   #files

OPEN cur

WHILE 1 = 1
BEGIN
    FETCH cur INTO @sql
    IF @@fetch_status <> 0
        BREAK
    
    EXEC (@sql)
END

DEALLOCATE cur

DROP TABLE  #files
 

操作原理：

遍歷備份檔案，將所有要還原的資料庫名稱存入#files

通過執行“RESTORE FILELISTONLY”，將結果存入##filelistinfo，從記錄中得到備份資料庫的庫檔案及日誌檔案的邏輯檔名，拼接“RESTORE DATABASE”，並對應更新存入#files表

遍歷#files表，執行恢復語句

本例 備份檔案儲存路徑參考：