開啟一個終端視窗，執行以下命令：

cd /home/oracle/wkdir sqlplus hr/hr

建立程式包 STATIC_CONSTANTS 以宣告可用在條件編譯中的程式包常量。從 SQL*Plus 會話中，執行以下指令碼：

@static_constants

static_constants.sql 指令碼包含以下內容：

CREATE OR REPLACE PACKAGE static_constants is
debug CONSTANT BOOLEAN := FALSE; 
trace CONSTANT BOOLEAN := FALSE;
END ; 
/

建立兩個過程：CHECK_DEBUG（用於檢查程式包常量除錯的值是否是 TRUE）和 CHECK_TRACE（用於檢查程式包跟蹤的值是否是 TRUE）。從 SQL*Plus 會話中，執行以下指令碼：

@debug_trc

debug_trc.sql 指令碼包含以下內容：

CREATE OR REPLACE PROCEDURE check_Debug IS
BEGIN
$IF static_constants.debug $THEN DBMS_OUTPUT.put_line('Debugging ON'); 
$ELSE DBMS_OUTPUT.put_line('Debugging OFF'); $END
END;
/
CREATE or REPLACE PROCEDURE Check_trace IS
BEGIN
$IF static_constants.trace $THEN DBMS_OUTPUT.put_line('Tracing ON'); 
$ELSE DBMS_OUTPUT.put_line('Tracing OFF'); $END
END;
/

Set serveroutput on  using the new SIZE UNLIMITED syntax available in Oracle Database 10g Release 2. Now execute both the procedures.您將看到它顯示跟蹤和除錯均被關閉。

注意：可以將每一行單獨地複製到 sqlplus 中，但不要一起復制這 3 個語句。

set serveroutput on size unlimited exec check_debug exec check_trace

現在，將更改程式包常量的值。從 SQL*Plus 會話中，執行以下指令碼：

@reset_const

reset_const.sql 指令碼包含以下內容：

CREATE OR REPLACE PACKAGE static_constants is
debug CONSTANT BOOLEAN := TRUE; 
trace CONSTANT BOOLEAN := TRUE;
END ; 
/

現在，再次執行這兩個過程。您將看到除錯和跟蹤自動啟用了。在重新編譯程式包時，所有相關的物件都變為無效，並在下一次執行時重新編譯。因此，程式包常量的新值可即刻適用於所有相關物件。

exec check_debug exec check_trace

這可以擴充套件至任意數量的相關程式。在需要通過單一機制控制大量程式時，使用這個方法最為有效。用例的其他示例包括針對同一應用程式按州更改賦稅，或根據許可選項更改軟體特性等等。

2.

建立 SEND_MESSAGE_TO_DBA 和 CHECK_UNIQUE 過程。CHECK_UNIQUE 過程包含兩個不同的程式碼段，一個用於開發中的測試，另一個部署在最終生產環境中。開發程式碼使用條件編譯指令，而生產程式碼使用傳統的 IF-THEN-ELSE 邏輯檢查重複的記錄。從 SQL*Plus 會話中，執行以下指令碼：

@dba_email @chk_unq show errors

dba_email.sql 指令碼包含以下內容：

CREATE OR REPLACE PROCEDURE send_message_to_DBA(emp_id number)
IS
mailhost VARCHAR2(64) := 'mailhost.fictional-domain.com';
sender VARCHAR2(64) := '[email protected]';
recipient VARCHAR2(64) := '[email protected]';
mail_conn utl_smtp.connection;
BEGIN
mail_conn := utl_smtp.open_connection(mailhost, 25);
utl_smtp.helo(mail_conn, mailhost);
utl_smtp.mail(mail_conn, sender);
utl_smtp.rcpt(mail_conn, recipient);
-- open_data(), write_data(), and close_data() into a single call to data().
utl_smtp.open_data(mail_conn);
utl_smtp.write_data(mail_conn, 'A primary key violation has occured for record '||
emp_id || 'in the EMPLOYEES table.This is an automatically generated e-mail message.Please do not respond to this, this is an alert.'|| chr(13));
utl_smtp.write_data(mail_conn, 'This is line 2.'|| chr(13));
utl_smtp.close_data(mail_conn);
utl_smtp.quit(mail_conn);
EXCEPTION
WHEN OTHERS THEN 
NULL;
END;
/

chk_unq.sql 指令碼包含以下內容：

Create or replace Procedure check_unique(emp_id NUMBER) is
v_num number;
force_pk_violation exception;
Begin
Select count(*) into v_num from employees where employee_id = emp_id;
-- production code
If v_num > 1 
then SEND_MESSAGE_TO_DBA(emp_id);
raise force_pk_violation; 
END IF ;
-- Development code 
$if $$FORCE 
$then SEND_MESSAGE_TO_DBA(emp_id);
raise force_pk_violation;
$end
END; 
/

現在，更改會話將 $$force 的值設為 FALSE。從 SQL*Plus 執行以下命令。

ALTER SESSION SET PLSQL_CCFLAGS='force:FALSE';

現在，再次執行 chk_unq.sql。

因為變數 $$force 現在的值是 FALSE，所以沒有出現警告；

建立 GET_RECORD 過程。該過程接受 employee id 並返回員工記錄。如果 CHECK_UNIQUE 過程檢查出存在重複記錄，則會顯示一個友好訊息。從 SQL*Plus 會話執行以下指令碼：

@get_record

get_record.sql 指令碼包含以下內容：

Create or replace procedure get_record(emp_id IN NUMBER)
as
emp_record employees%rowtype;
Begin
check_unique(emp_id);
Select * into emp_record from employees where employee_id =emp_id;
Dbms_output.put_line ( 'Name:'|| emp_record.first_name||' '||emp_record.last_name||' '||'Hiredate: ' ||emp_record.hire_date||'
'||'Job:'||' '||emp_record.job_id);
Exception
When others then 
DBMS_OUTPUT.PUT_LINE('We are unable to process your request at this time.
Please try again later.We apologize for any inconvenience');
End;
/

現在，執行 GET_RECORD 過程，傳入 100 作為引數。

exec GET_RECORD(100)

因為沒有重複記錄，所以該過程成功執行。

現在，測試是否在出現重複記錄時顯示訊息。更改會話將 $$force 的值設為 TRUE，並再次執行 GET_RECORD。從 SQL*Plus 會話執行以下命令：

ALTER SESSION SET PLSQL_CCFLAGS='force:TRUE'; exec GET_RECORD(100)

由於未重新編譯該過程，因此它不會受到影響。

使用 ALTER...COMPILE 語句重新編譯 CHECK_UNIQUE 過程，併為 PLSQL_CCFLAGS 引數提供新值。使用 REUSE SETTINGS選項。然後，以值 100 再次執行 GET_RECORD。從 SQL*Plus 會話執行以下命令。

ALTER PROCEDURE CHECK_UNIQUE compile plsql_ccflags = 'force:TRUE' REUSE SETTINGS; exec GET_RECORD(100)

現在，PLSQL_CCFLAGS 值生效，因而程式發出訊息。該方法可以用於影響會話內的特定程式，比如後生產除錯。然而，每個需要新設定的程式都必須使用 CREATE OR REPLACE 或 ALTER...COMPILE 語句進行重新編譯。

1.

Execute the following command to see the actual source code used to compile a valid PL/SQL program: 

EXEC DBMS_PREPROCESSOR.PRINT_POST_PROCESSED_SOURCE('PROCEDURE', 'HR', 'CHECK_UNIQUE');

請注意，已刪除了所有條件編譯指令。

1.

啟用 ALTER SESSION 以設定標記，從而在兩個版本之間進行選擇。首先，選擇使用 NUMBER 資料型別。從 SQL*Plus 會話中，執行以下命令：

ALTER SESSION SET PLSQL_CCFLAGS = ' numversion:TRUE';

2.

您希望知道哪個程式碼執行速度更快。建立一個 CALC_CIRCLE 過程計算給定半徑的圓的周長和麵積。從 SQL*Plus 會話中，執行以下指令碼：

@num_bdbl

num_bdbl.sql 指令碼包含以下內容：

CREATE or REPLACE PROCEDURE Calc_circle( RADIUS $IF $$NUMVERSION $THEN NUMBER 
$ELSE BINARY_DOUBLE $END)
as 
SUBTYPE my_real IS
$IF $$numversion $THEN 
NUMBER; 
$ELSE 
BINARY_DOUBLE;
$END
num_circ my_real;
num_area my_real;
BDBL_circ my_real;
BDBL_AREA my_real;
BEGIN
num_CIRC:= (3.14016408289008292431940027343666863227 * 2 * RADIUS); 
NUM_AREA := (3.14016408289008292431940027343666863227*radius*radius);
DBMS_OUTPUT.PUT_LINE('The circumference is:'||num_circ);
DBMS_OUTPUT.PUT_LINE('The area is:'||num_area);
END ;
/

3.

執行 CALC_CIRCLE 過程，使用數字 1234567890 作為半徑

set timing on exec calc_circle(1234567890)

4.

使用 ALTER COMPILE 命令將 $$numversion 的值更改為 FALSE 來編譯 CALC_CIRCLE，並使用相同的引數再次執行 CALC_CIRCLE。

ALTER PROCEDURE calc_circle COMPILE plsql_ccflags = 'numversion :false' REUSE SETTINGS;exec calc_circle(1234567890) set timing off

您可以看出二者效能間的差異。本例闡明瞭可以使用條件編譯在相同程式內有選擇地測試兩個版本的程式碼。

現在可以測試 Oracle 資料庫版本了。從終端視窗中執行以下指令碼：

@check_version

check_version.sql 指令碼包含以下內容：

CREATE OR REPLACE PROCEDURE check_version AS
BEGIN
-- some code which performs transaction processing ...
$if DBMS_DB_VERSION.VER_LE_10_2 $then 
-- traditional commit
COMMIT;
DBMS_OUTPUT.PUT_LINE ('The transaction has been successfully committed.');
$else 
-- faster COMMIT supported in 10.2
COMMIT WRITE IMMEDIATE NOWAIT;
DBMS_OUTPUT.PUT_LINE ('The transaction has been successfully committed.');
$end
END;
/

現在，在 SQL*Plus 視窗中執行以下命令來執行 check_version 過程。

exec check_version

check_version 的輸出說明：無論版本如何，該過程都能成功完成而且對終端使用者而言是透明的。因此，沒有理由在不同的資料庫版本中使用不同的程式單元