雖然國家目前嚴令禁止ICO，但是我覺得基於區塊鏈平臺的虛擬幣本身是很有價值的，大家只要不去碰基於發幣的ICO就好，因此這裡簡單談談怎麼在以太坊發行自己的代幣(Test網路)。

翻牆

目前來說，相關的網站很多都是被牆的，因此沒有梯子建議就放棄吧，推薦自己購買香港或者海外的雲伺服器，用shadowsocks搭建代理，注意如果用阿里雲的話，不要用視訊等大流量服務，可能會被封。

下載安裝

下載並安裝最新版本以太坊錢包

選擇網路

下載好以太坊錢包後選擇testnet,別選成mainnet了,建立代幣合約和轉賬代幣是要收費的。選好testnet後，錢包會去同步區塊資訊，目前都是快速同步區塊的header，而且是點對點的方式，所以很快。

建立賬戶

在錢包介面選擇Wallet，然後選擇ADD ACCOUNT

領取測試環境的以太幣ether

新建完賬戶，餘額是0.00ether

因此我們需要領取一些rinkeby測試環境的ether,進入連結,可以看到有三種方法獲取,我們就用第一種發推特的方式,點選下面圈出來的tweet的連結:

接著會彈出以下推文,把0x0000…換成你的賬戶地址0x…，然後釋出推文即可：

接著進入twitter，找到發表的推文，拷貝連結：

最後回到領取ether的連結，把推文連結貼上進去

過大概3-10分鐘，就能在你的錢包看到ether幣了！

建立智慧合約

拷貝以下合約程式碼(這段程式碼是從官方的token例子

pragma solidity ^0.4.16;

interface tokenRecipient { function receiveApproval(address _from, uint256 _value, address _token, bytes _extraData) external; }

contract TokenERC20 {
    // Public variables of the token
    string public name;
    string public symbol;
    uint8 public
 
 decimals = 18;
    // 18 decimals is the strongly suggested default, avoid changing it
    uint256 public totalSupply;

    // This creates an array with all balances
    mapping (address => uint256) public balanceOf;
    mapping (address => mapping (address => uint256)) public allowance;

    // This generates a public event on the blockchain that will notify clients
    event Transfer(address indexed from, address indexed to, uint256 value);

    // This notifies clients about the amount burnt
    event Burn(address indexed from, uint256 value);

    /**
     * Constructor function
     *
     * Initializes contract with initial supply tokens to the creator of the contract
     */
    function TokenERC20(
        uint256 initialSupply,
        string tokenName,
        string tokenSymbol
    ) public {
        totalSupply = initialSupply * 10 ** uint256(decimals);  // Update total supply with the decimal amount
        balanceOf[msg.sender] = totalSupply;                // Give the creator all initial tokens
        name = tokenName;                                   // Set the name for display purposes
        symbol = tokenSymbol;                               // Set the symbol for display purposes
    }

    /**
     * Internal transfer, only can be called by this contract
     */
    function _transfer(address _from, address _to, uint _value) internal {
        // Prevent transfer to 0x0 address. Use burn() instead
        require(_to != 0x0);
        // Check if the sender has enough
        require(balanceOf[_from] >= _value);
        // Check for overflows
        require(balanceOf[_to] + _value > balanceOf[_to]);
        // Save this for an assertion in the future
        uint previousBalances = balanceOf[_from] + balanceOf[_to];
        // Subtract from the sender
        balanceOf[_from] -= _value;
        // Add the same to the recipient
        balanceOf[_to] += _value;
        emit Transfer(_from, _to, _value);
        // Asserts are used to use static analysis to find bugs in your code. They should never fail
        assert(balanceOf[_from] + balanceOf[_to] == previousBalances);
    }

    /**
     * Transfer tokens
     *
     * Send `_value` tokens to `_to` from your account
     *
     * @param _to The address of the recipient
     * @param _value the amount to send
     */
    function transfer(address _to, uint256 _value) public {
        _transfer(msg.sender, _to, _value);
    }

    /**
     * Transfer tokens from other address
     *
     * Send `_value` tokens to `_to` on behalf of `_from`
     *
     * @param _from The address of the sender
     * @param _to The address of the recipient
     * @param _value the amount to send
     */
    function transferFrom(address _from, address _to, uint256 _value) public returns (bool success) {
        require(_value <= allowance[_from][msg.sender]);     // Check allowance
        allowance[_from][msg.sender] -= _value;
        _transfer(_from, _to, _value);
        return true;
    }

    /**
     * Set allowance for other address
     *
     * Allows `_spender` to spend no more than `_value` tokens on your behalf
     *
     * @param _spender The address authorized to spend
     * @param _value the max amount they can spend
     */
    function approve(address _spender, uint256 _value) public
        returns (bool success) {
        allowance[msg.sender][_spender] = _value;
        return true;
    }

    /**
     * Set allowance for other address and notify
     *
     * Allows `_spender` to spend no more than `_value` tokens on your behalf, and then ping the contract about it
     *
     * @param _spender The address authorized to spend
     * @param _value the max amount they can spend
     * @param _extraData some extra information to send to the approved contract
     */
    function approveAndCall(address _spender, uint256 _value, bytes _extraData)
        public
        returns (bool success) {
        tokenRecipient spender = tokenRecipient(_spender);
        if (approve(_spender, _value)) {
            spender.receiveApproval(msg.sender, _value, this, _extraData);
            return true;
        }
    }

    /**
     * Destroy tokens
     *
     * Remove `_value` tokens from the system irreversibly
     *
     * @param _value the amount of money to burn
     */
    function burn(uint256 _value) public returns (bool success) {
        require(balanceOf[msg.sender] >= _value);   // Check if the sender has enough
        balanceOf[msg.sender] -= _value;            // Subtract from the sender
        totalSupply -= _value;                      // Updates totalSupply
        emit Burn(msg.sender, _value);
        return true;
    }

    /**
     * Destroy tokens from other account
     *
     * Remove `_value` tokens from the system irreversibly on behalf of `_from`.
     *
     * @param _from the address of the sender
     * @param _value the amount of money to burn
     */
    function burnFrom(address _from, uint256 _value) public returns (bool success) {
        require(balanceOf[_from] >= _value);                // Check if the targeted balance is enough
        require(_value <= allowance[_from][msg.sender]);    // Check allowance
        balanceOf[_from] -= _value;                         // Subtract from the targeted balance
        allowance[_from][msg.sender] -= _value;             // Subtract from the sender's allowance
        totalSupply -= _value;                              // Update totalSupply
        emit Burn(_from, _value);
        return true;
    }
}

token name ,和 token symbol自己可以隨便命名，然後把費用Fee拉到最大（Faster,為了更快的讓礦工記錄你的合約),最後點擊發布就ok了。

發起轉賬

目標賬戶地址可以填寫[0x8DF451466Ee0e75F73eafB36a8C0833F3022a687](/send/0x8DF451466Ee0e75F73eafB36a8C0833F3022a687 "0x8DF451466Ee0e75F73eafB36a8C0833F3022a687")


檢視轉賬資訊

點選其中一筆轉賬

點選上圖的Transaction下的藍色地址，可以前往rinkeby.io檢視詳細資訊

小結

發代幣的基本方法已經介紹完了，在後續章節，會繼續介紹發行代幣的高階技巧，歡迎大家訂閱。
這裡要額外提一下，發代幣的關鍵就是智慧合約，而智慧合約一旦上傳是不可變的，因此請務必小心謹慎：
- 確保智慧合約沒有Bug，一旦存在Bug，你就別想去修復了
- 程式碼要儘量簡潔，程式碼越長，執行費用越高（每次轉賬都要執行一次)

同時，大家也可以在這裡檢視代幣的Coin