今天看到一求助帖子再問這個事，所以無聊寫了個。

用的是awk指令碼 ， 也就是指令碼直譯器是用/usr/bin/awk ， 而不是/bin/sh

但都是指令碼 ， 如果你想的話，

可以用shell指令碼呼叫我這個awk指令碼就行了。

使用方法：將下面的指令碼儲存成檔案如get-cfile-notes.awk

然後chmod 755 get-cfile-notes.awk就可以運行了。

注意：

因為在這種腳本里面沒什麼好的方法使用棧和逐字元的處理，所以只能處理簡單的情況 。 比如一行中出現/*  xxxxdfafw */  /*  jwo*/ /* */ 等等。

但只要你不是故意要考倒我的這個程式，基本使用是沒問題的。

如下：

#!/usr/bin/awk -f

# 本程式用來統計c檔案中的註釋的行數
# by fdl19881 
# 2012.8.10

BEGIN {
	num_notes = 0;
	stat = 0; # 0:無註釋， 1://註釋(notes1) , 2:/* */註釋(notes2)
}

{
	if(stat ==  0) {
		notes1 = match($0 , /\/\//); # 查詢//位置
		notes21 = match($0 , /\/\*/); # 查詢/*位置

		if(notes1 > 0 && notes21 == 0) { # //註釋
			stat = 1;
		}
		if(notes1 == 0 && notes21 == 0) #無註釋
			stat = 0;

		if(notes1 >0 && notes21 >0) {
			if(notes1 < notes21)
				stat = 1;
			else
				stat = 2;
		}

		if(notes1 == 0 && notes21 > 0)
			stat = 2;

		if(stat == 1) { # 此時為//註釋
			stat = 0;
			num_notes += 1;
			next;
		} 
		if(stat == 2){ 	# /*註釋
			notes22 = match($0 , /\*\//);
			if(notes22 == 0) { #沒找到*/
				num_notes += 1;
				next;
			}
			if(notes21 < notes22) { # /**/註釋一行
				num_notes += 1;
				stat = 0;
				next;
			} else {
				print "error , find */ before /*\n"
				exit;
			}
		}
	}

	if(stat == 2) {
		num_notes += 1;
		if($0~/\*\//) {
		  	stat = 0;
		}
	}
}

END {
	print num_notes;
}
 

#!/bin/sh

./get-cfile-notes.awk $1

就行了

試驗:

#include <stdio.h>

/* this is my first program */
// haha 

int main()
{
	/* this is my first program
	   thank you !
	*/

	printf("hello world!\n"); //printf statement
	return 0; /* return *? */
}

然後./get-cfile-notes.awk main.c

輸出：

7