C51啟動檔案詳解
阿新 • • 發佈：2019-02-07
$NOMOD51 ; Ax51巨集彙編器控制命令，禁止預定義的8051。使編譯器不使能預定義的8051符號，避免產生重複定義的錯誤。
;------------------------------------------------------------------------------
; This file is part of the C51 Compiler package
; Copyright (c) 1988-2001 Keil Elektronik GmbH and Keil Software, Inc.
;------------------------------------------------------------------------------
; STARTUP.A51: This code is executed after processor reset.
;
; To translate this file use A51 with the following invocation:
;
; A51 STARTUP.A51
;
; To link the modified STARTUP.OBJ file to your application use the following
; BL51 invocation:
;
; BL51 <your object file list>, STARTUP.OBJ <controls>
; --- BL51是Keil使用的連結器(Linker),這是命令列的使用格式，一般不用,使用IDE環境,用project管理,有相應的按鈕可以實現該功能.
;
;--------------------------------------------------------------------------------------------------------------------
;
; User-defined Power-On Initialization of Memory --- 初始化RAM單元
;
; With the following EQU statements the initialization of memory --- 用下面的EQU宣告初始化ram單元
; at processor reset can be defined:
;
; ; the absolute start-address of IDATA memory is always 0
IDATALEN EQU 80H ; the length of IDATA memory in bytes.
; --- 根據你選用的晶片可以適當的修改這些值 。IDATALEN 只是一個標號，EQU只是做巨集一樣的替換，類似於C語言中的
; --- #define uint (unsigned int) ，以上的程式碼使得程式以後在碰到IDATALEN時替換成80H
;
XDATASTART EQU 0H ; the absolute start-address of XDATA memory --以下兩項根據目標系統的外設配置和連線自己修改
XDATALEN EQU 0H ; the length of XDATA memory in bytes.
;
PDATASTART EQU 0H ; the absolute start-address of PDATA memory
PDATALEN EQU 0H ; the length of PDATA memory in bytes.
;
; Notes: The IDATA space overlaps physically the DATA and BIT areas of the
; 8051 CPU. At minimum the memory space occupied from the C51
; run-time routines must be set to zero.
;------------------------------------------------------------------------------------------------------------------------
;
; Reentrant Stack Initilization ;-- 再入堆疊初始化
; --- 注意：再入堆疊的方向區別於晶片自帶的堆疊的生長方式，自頂向下生長的！而SP是是自底向上的。
; --- 且再入堆疊是由編譯器自己管理的，一般不必去關心，只是在有再入函式的時候，根據函式的儲存器模式使用相應的RAM空間做為再入堆疊。
;
; The following EQU statements define the stack pointer for reentrant
; functions and initialized it:
; --- Keil C預設情況不是用堆疊來傳遞引數的，所以造成函式不可重入，Keil要求使用者顯示宣告函式是否具有可重入屬性，以便為C函式呼叫初始化棧。
;
; Stack Space for reentrant functions in the SMALL model.
IBPSTACK EQU 0 ; set to 1 if small reentrant is used.
IBPSTACKTOP EQU 0FFH+1 ; set top of stack to highest location+1.
;
; Stack Space for reentrant functions in the LARGE model.
XBPSTACK EQU 0 ; set to 1 if large reentrant is used.
XBPSTACKTOP EQU 0FFFFH+1 ; set top of stack to highest location+1.
;
; Stack Space for reentrant functions in the COMPACT model.
PBPSTACK EQU 0 ; set to 1 if compact reentrant is used.
PBPSTACKTOP EQU 0FFFFH+1 ; set top of stack to highest location+1.
;
; --- 不同記憶體模式下的堆疊。Keil 編譯器中有三種模式設定：
; --- Small：所有的變數都放在內部RAM區
; --- Compact：所有變數在預設情況下都會放在外部RAM的低256位元組中(可由R0定址)
; --- Large：所有變數都放在外部RAM中(DPTR定址)
; --- 這是由51處理器繁多的定址模式導致的，不同的定址模式有不同的效率
;
;------------------------------------------------------------------------------------------------------------------------------
;
; Page Definition for Using the Compact Model with 64 KByte xdata RAM
; --- 使用COMPACT儲存器模式時64K位元組XDATA儲存器空間的分頁定義
;
; The following EQU statements define the xdata page used for pdata
; variables. The EQU PPAGE must conform with the PPAGE control used
; in the linker invocation.
;--- 以下用EQU指令定義PDATA型別變數在XDATA儲存器空間的頁地址
;--- 使用EQU指令定義PFAGE時必須與L51連線定位器PDATA指令的控制引數一致
;
PPAGEENABLE EQU 0 ; set to 1 if pdata object are used.
PPAGE EQU 0 ; define PPAGE number.
PPAGE_SFR DATA 0A0H ; SFR that supplies uppermost address byte
; --- (most 8051 variants use P2 as uppermost address byte) 很多的外部頁面定址以P2口為高位地址的數值，有使用外部頁面RAM的情況
; --- 對PPAGEENABLE 設定為1 ，根據硬體連線修改PPAGE的值。
;
;------------------------------------------------------------------------------
; Standard SFR Symbols required in XBANKING.A51 ;--- 標準的SFR符號
ACC DATA 0E0H ;--- 關鍵字DATA A51偽指令定義微控制器內部資料儲存器位元組地址的符號
B DATA 0F0H
SP DATA 81H
DPL DATA 82H
DPH DATA 83H
NAME ?C_STARTUP ;--- 定義當前程式模組的目標模組名
?C_C51STARTUP SEGMENT CODE ;-- 定義一個可再定位的段符號名和段所在的儲存空間，彙編器產生的這個段符號名在BL51/L51連線定位時用
?STACK SEGMENT IDATA ;-- 定義一個IDATA段，段名?STACK ,符合C51編譯器的命名規則 （SEGMENT 用於定義一個段）
RSEG ?STACK ;-- 聲明當前段是IDATA段，段中保留空間。RSEG偽指令用於選擇一個事先用SEGMENT偽指令宣告的普通段
DS 1 ; DS是預留空間定義指令
EXTRN CODE (?C_START) ;宣告本模組引用的外部全域性符號，用於和C相連線在.src檔案中可以看到這個符號
PUBLIC ?C_STARTUP ;宣告可被其他模組使用的全域性符號，由.src檔案中可以看出這個符號的作用。
CSEG AT 0 ;結束當前的IDATA段，產生一個位於CODE中新段，起始地址是0000H。程式碼段的起始點
?C_STARTUP: LJMP STARTUP1 ;C編譯器編譯源程式後，晶片復位之後的復位程式碼第一個就是執行這條語句。
RSEG ?C_C51STARTUP ;選擇段名為?C_C51STARTUP的CODE段為當前段，儲存程式程式碼。
STARTUP1:
;--- 微控制器上電IDATA記憶體清零。如果不需要上電清零IDATA，
;--- 可以登出IF到IFEDN之間的話句或者修改IDTALEN的長度
IF IDATALEN <> 0 ;如果IDATALEN不等於0 條件彙編指令，有IDATA區的話，清IDATA區。
MOV R0,#IDATALEN - 1 ;區域為0——IDATALEN-1
CLR A
IDATALOOP:
MOV @R0,A
DJNZ R0,IDATALOOP
ENDIF
;（一）如果上面idatalen＝80H，那麼是對0～7FH清零；如果你的程式是改寫成：IDATALEN EQU 0100H ;就是對0～FFH清零。
;（二）如何按你意願載入這段程式
;一般考慮到這個往往是你的設計中要區分上電覆位和程式復位。有時候當程式復位時你不希望一些記憶體單元被清零了，
;那麼你不對startup.a51作點修改，就不行了。
;預設是自動載入這段startup.a51的。
;所以你要這樣做：把lib目錄下的原始startup.a51檔案拷到你的專案所在目錄下，再把你專案目錄下的這個startup.a51加入到你的專案中
;比如改成：IDATALEN EQU 00H ; the length of IDATA memory in bytes.
;然後編譯連結。這樣你的程式中就不會包含對idata清零的內碼了。
;為什麼？上面提到的IF語句的作用呀！當定義IDATALEN＝0時，清零程式碼被跳過！
;--- 微控制器上電XDATA記憶體清零。如果不需要上電清零XDATA，
;--- 可以登出IF到IFEDN之間的話句或者修改XDATALEN的長度
IF XDATALEN <> 0 ;如果有外部資料區，則把外部資料區中從XDATASTART到XDATASTART+ XDATALEN的區域清零
MOV DPTR,#XDATASTART
MOV R7,#LOW (XDATALEN)
IF (LOW (XDATALEN)) <> 0
MOV R6,#(HIGH (XDATALEN)) +1 ;如果低地址是零，一個高地址就代表256位元組
ELSE
MOV R6,#HIGH (XDATALEN)
ENDIF
CLR A
XDATALOOP:
MOVX @DPTR,A
INC DPTR
DJNZ R7,XDATALOOP
DJNZ R6,XDATALOOP
ENDIF
IF PPAGEENABLE <> 0 ;清外部頁RAM區域
MOV P2,#PPAGE ;給P2口賦相應的值，根據使用者自己的目標系統。
ENDIF
;--- 微控制器上電XDATA記憶體清零。如果不需要上電清零XDATA，
;--- 可以登出IF到IFEDN之間的話句或者修改XDATALEN的長度
IF PDATALEN <> 0 ;清外部頁RAM區域
MOV R0,#PDATASTART
MOV R7,#LOW (PDATALEN)
CLR A
PDATALOOP:
MOVX @R0,A
INC R0
DJNZ R7,PDATALOOP
ENDIF
;--- 設定使用SMALL儲存器模式時再入函式的堆疊空間
IF IBPSTACK <> 0 ; 使用再入堆疊的情況，使用者自己在程式中定義函式的儲存模式。
; C51定義了三個全域性變數，?C_IBP,?C_XBP,?C_PBP來儲存再入堆疊的棧頂地址
EXTRN DATA (?C_IBP) ; 宣告本模組使用的外部全域性符號，符號的段型別限制了符號的使用範圍，
; 而符號本身則代表的是一個RAM單元的地址址
MOV ?C_IBP,#LOW IBPSTACKTOP
ENDIF
;--- 設定使用LARGE儲存器模式時再入函式的堆疊空間
IF XBPSTACK <> 0 ;函式是Large儲存模式的時候，儲存再入堆疊的區域。
EXTRN DATA (?C_XBP)
MOV ?C_XBP,#HIGH XBPSTACKTOP
MOV ?C_XBP+1,#LOW XBPSTACKTOP
ENDIF
;--- 設定使用COMPACT儲存器模式時再入函式的堆疊空間
IF PBPSTACK <> 0 ;函式是Compact模式的時候，儲存再入堆疊棧頂地址的儲存單元和棧的利用空間
EXTRN DATA (?C_PBP)
MOV ?C_PBP,#LOW PBPSTACKTOP
ENDIF
;--- 設定堆疊的起始地址
MOV SP,#?STACK-1 ;定義的硬體棧的常數。區別再入堆疊和硬體棧。定義的段符號代表該段的首地址
; This code is required if you use L51_BANK.A51 with Banking Mode 4
EXTRN CODE (?B_SWITCH0)
CALL ?B_SWITCH0 ; init bank mechanism to code bank 0
; 程式從第一組bank 0 塊開始執行，跳轉到使用者程式MAIN函式
LJMP ?C_START ; 把執行的權力交給C主函式。也就是說指定函式的入口點。改句話結束以後將跳入C的main函式開始執行。
END
;------------------------------------------------------------------------------
; This file is part of the C51 Compiler package
; Copyright (c) 1988-2001 Keil Elektronik GmbH and Keil Software, Inc.
;------------------------------------------------------------------------------
; STARTUP.A51: This code is executed after processor reset.
;
; To translate this file use A51 with the following invocation:
;
; A51 STARTUP.A51
;
; To link the modified STARTUP.OBJ file to your application use the following
; BL51 invocation:
;
; BL51 <your object file list>, STARTUP.OBJ <controls>
; --- BL51是Keil使用的連結器(Linker),這是命令列的使用格式，一般不用,使用IDE環境,用project管理,有相應的按鈕可以實現該功能.
;
;--------------------------------------------------------------------------------------------------------------------
;
; User-defined Power-On Initialization of Memory --- 初始化RAM單元
;
; With the following EQU statements the initialization of memory --- 用下面的EQU宣告初始化ram單元
; at processor reset can be defined:
;
; ; the absolute start-address of IDATA memory is always 0
IDATALEN EQU 80H ; the length of IDATA memory in bytes.
; --- 根據你選用的晶片可以適當的修改這些值 。IDATALEN 只是一個標號，EQU只是做巨集一樣的替換，類似於C語言中的
; --- #define uint (unsigned int) ，以上的程式碼使得程式以後在碰到IDATALEN時替換成80H
;
XDATASTART EQU 0H ; the absolute start-address of XDATA memory --以下兩項根據目標系統的外設配置和連線自己修改
XDATALEN EQU 0H ; the length of XDATA memory in bytes.
;
PDATASTART EQU 0H ; the absolute start-address of PDATA memory
PDATALEN EQU 0H ; the length of PDATA memory in bytes.
;
; Notes: The IDATA space overlaps physically the DATA and BIT areas of the
; 8051 CPU. At minimum the memory space occupied from the C51
; run-time routines must be set to zero.
;------------------------------------------------------------------------------------------------------------------------
;
; Reentrant Stack Initilization ;-- 再入堆疊初始化
; --- 注意：再入堆疊的方向區別於晶片自帶的堆疊的生長方式，自頂向下生長的！而SP是是自底向上的。
; --- 且再入堆疊是由編譯器自己管理的，一般不必去關心，只是在有再入函式的時候，根據函式的儲存器模式使用相應的RAM空間做為再入堆疊。
;
; The following EQU statements define the stack pointer for reentrant
; functions and initialized it:
; --- Keil C預設情況不是用堆疊來傳遞引數的，所以造成函式不可重入，Keil要求使用者顯示宣告函式是否具有可重入屬性，以便為C函式呼叫初始化棧。
;
; Stack Space for reentrant functions in the SMALL model.
IBPSTACK EQU 0 ; set to 1 if small reentrant is used.
IBPSTACKTOP EQU 0FFH+1 ; set top of stack to highest location+1.
;
; Stack Space for reentrant functions in the LARGE model.
XBPSTACK EQU 0 ; set to 1 if large reentrant is used.
XBPSTACKTOP EQU 0FFFFH+1 ; set top of stack to highest location+1.
;
; Stack Space for reentrant functions in the COMPACT model.
PBPSTACK EQU 0 ; set to 1 if compact reentrant is used.
PBPSTACKTOP EQU 0FFFFH+1 ; set top of stack to highest location+1.
;
; --- 不同記憶體模式下的堆疊。Keil 編譯器中有三種模式設定：
; --- Small：所有的變數都放在內部RAM區
; --- Compact：所有變數在預設情況下都會放在外部RAM的低256位元組中(可由R0定址)
; --- Large：所有變數都放在外部RAM中(DPTR定址)
; --- 這是由51處理器繁多的定址模式導致的，不同的定址模式有不同的效率
;
;------------------------------------------------------------------------------------------------------------------------------
;
; Page Definition for Using the Compact Model with 64 KByte xdata RAM
; --- 使用COMPACT儲存器模式時64K位元組XDATA儲存器空間的分頁定義
;
; The following EQU statements define the xdata page used for pdata
; variables. The EQU PPAGE must conform with the PPAGE control used
; in the linker invocation.
;--- 以下用EQU指令定義PDATA型別變數在XDATA儲存器空間的頁地址
;--- 使用EQU指令定義PFAGE時必須與L51連線定位器PDATA指令的控制引數一致
;
PPAGEENABLE EQU 0 ; set to 1 if pdata object are used.
PPAGE EQU 0 ; define PPAGE number.
PPAGE_SFR DATA 0A0H ; SFR that supplies uppermost address byte
; --- (most 8051 variants use P2 as uppermost address byte) 很多的外部頁面定址以P2口為高位地址的數值，有使用外部頁面RAM的情況
; --- 對PPAGEENABLE 設定為1 ，根據硬體連線修改PPAGE的值。
;
;------------------------------------------------------------------------------
; Standard SFR Symbols required in XBANKING.A51 ;--- 標準的SFR符號
ACC DATA 0E0H ;--- 關鍵字DATA A51偽指令定義微控制器內部資料儲存器位元組地址的符號
B DATA 0F0H
SP DATA 81H
DPL DATA 82H
DPH DATA 83H
NAME ?C_STARTUP ;--- 定義當前程式模組的目標模組名
?C_C51STARTUP SEGMENT CODE ;-- 定義一個可再定位的段符號名和段所在的儲存空間，彙編器產生的這個段符號名在BL51/L51連線定位時用
?STACK SEGMENT IDATA ;-- 定義一個IDATA段，段名?STACK ,符合C51編譯器的命名規則 （SEGMENT 用於定義一個段）
RSEG ?STACK ;-- 聲明當前段是IDATA段，段中保留空間。RSEG偽指令用於選擇一個事先用SEGMENT偽指令宣告的普通段
DS 1 ; DS是預留空間定義指令
EXTRN CODE (?C_START) ;宣告本模組引用的外部全域性符號，用於和C相連線在.src檔案中可以看到這個符號
PUBLIC ?C_STARTUP ;宣告可被其他模組使用的全域性符號，由.src檔案中可以看出這個符號的作用。
CSEG AT 0 ;結束當前的IDATA段，產生一個位於CODE中新段，起始地址是0000H。程式碼段的起始點
?C_STARTUP: LJMP STARTUP1 ;C編譯器編譯源程式後，晶片復位之後的復位程式碼第一個就是執行這條語句。
RSEG ?C_C51STARTUP ;選擇段名為?C_C51STARTUP的CODE段為當前段，儲存程式程式碼。
STARTUP1:
;--- 微控制器上電IDATA記憶體清零。如果不需要上電清零IDATA，
;--- 可以登出IF到IFEDN之間的話句或者修改IDTALEN的長度
IF IDATALEN <> 0 ;如果IDATALEN不等於0 條件彙編指令，有IDATA區的話，清IDATA區。
MOV R0,#IDATALEN - 1 ;區域為0——IDATALEN-1
CLR A
IDATALOOP:
MOV @R0,A
DJNZ R0,IDATALOOP
ENDIF
;（一）如果上面idatalen＝80H，那麼是對0～7FH清零；如果你的程式是改寫成：IDATALEN EQU 0100H ;就是對0～FFH清零。
;（二）如何按你意願載入這段程式
;一般考慮到這個往往是你的設計中要區分上電覆位和程式復位。有時候當程式復位時你不希望一些記憶體單元被清零了，
;那麼你不對startup.a51作點修改，就不行了。
;預設是自動載入這段startup.a51的。
;所以你要這樣做：把lib目錄下的原始startup.a51檔案拷到你的專案所在目錄下，再把你專案目錄下的這個startup.a51加入到你的專案中
;比如改成：IDATALEN EQU 00H ; the length of IDATA memory in bytes.
;然後編譯連結。這樣你的程式中就不會包含對idata清零的內碼了。
;為什麼？上面提到的IF語句的作用呀！當定義IDATALEN＝0時，清零程式碼被跳過！
;--- 微控制器上電XDATA記憶體清零。如果不需要上電清零XDATA，
;--- 可以登出IF到IFEDN之間的話句或者修改XDATALEN的長度
IF XDATALEN <> 0 ;如果有外部資料區，則把外部資料區中從XDATASTART到XDATASTART+ XDATALEN的區域清零
MOV DPTR,#XDATASTART
MOV R7,#LOW (XDATALEN)
IF (LOW (XDATALEN)) <> 0
MOV R6,#(HIGH (XDATALEN)) +1 ;如果低地址是零，一個高地址就代表256位元組
ELSE
MOV R6,#HIGH (XDATALEN)
ENDIF
CLR A
XDATALOOP:
MOVX @DPTR,A
INC DPTR
DJNZ R7,XDATALOOP
DJNZ R6,XDATALOOP
ENDIF
IF PPAGEENABLE <> 0 ;清外部頁RAM區域
MOV P2,#PPAGE ;給P2口賦相應的值，根據使用者自己的目標系統。
ENDIF
;--- 微控制器上電XDATA記憶體清零。如果不需要上電清零XDATA，
;--- 可以登出IF到IFEDN之間的話句或者修改XDATALEN的長度
IF PDATALEN <> 0 ;清外部頁RAM區域
MOV R0,#PDATASTART
MOV R7,#LOW (PDATALEN)
CLR A
PDATALOOP:
MOVX @R0,A
INC R0
DJNZ R7,PDATALOOP
ENDIF
;--- 設定使用SMALL儲存器模式時再入函式的堆疊空間
IF IBPSTACK <> 0 ; 使用再入堆疊的情況，使用者自己在程式中定義函式的儲存模式。
; C51定義了三個全域性變數，?C_IBP,?C_XBP,?C_PBP來儲存再入堆疊的棧頂地址
EXTRN DATA (?C_IBP) ; 宣告本模組使用的外部全域性符號，符號的段型別限制了符號的使用範圍，
; 而符號本身則代表的是一個RAM單元的地址址
MOV ?C_IBP,#LOW IBPSTACKTOP
ENDIF
;--- 設定使用LARGE儲存器模式時再入函式的堆疊空間
IF XBPSTACK <> 0 ;函式是Large儲存模式的時候，儲存再入堆疊的區域。
EXTRN DATA (?C_XBP)
MOV ?C_XBP,#HIGH XBPSTACKTOP
MOV ?C_XBP+1,#LOW XBPSTACKTOP
ENDIF
;--- 設定使用COMPACT儲存器模式時再入函式的堆疊空間
IF PBPSTACK <> 0 ;函式是Compact模式的時候，儲存再入堆疊棧頂地址的儲存單元和棧的利用空間
EXTRN DATA (?C_PBP)
MOV ?C_PBP,#LOW PBPSTACKTOP
ENDIF
;--- 設定堆疊的起始地址
MOV SP,#?STACK-1 ;定義的硬體棧的常數。區別再入堆疊和硬體棧。定義的段符號代表該段的首地址
; This code is required if you use L51_BANK.A51 with Banking Mode 4
EXTRN CODE (?B_SWITCH0)
CALL ?B_SWITCH0 ; init bank mechanism to code bank 0
; 程式從第一組bank 0 塊開始執行，跳轉到使用者程式MAIN函式
LJMP ?C_START ; 把執行的權力交給C主函式。也就是說指定函式的入口點。改句話結束以後將跳入C的main函式開始執行。
END