=>WikiEditor.mxml

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009" 
   xmlns:s="library://ns.adobe.com/flex/spark" 
   xmlns:mx="library://ns.adobe.com/flex/mx" minWidth="955" minHeight="600"
   creationComplete="creationCompleteHandler(event)">
<fx:Script>
<![CDATA[
import com.cen.programmingas3.wikiEditor.CurrencyConverter;
import com.cen.programmingas3.wikiEditor.URLParser;
import com.cen.programmingas3.wikiEditor.WikiParser;

import mx.events.FlexEvent;

/*轉換類*/
private var wikiParser:WikiParser;

protected function creationCompleteHandler(event:FlexEvent):void
{
/*初始化_wikiParser示例已經包含原始資料*/
wikiParser = new WikiParser();

inputText.text = wikiParser.wikiData;

outputText.text = wikiParser.parseWikiString(inputText.text);
}

protected function testButton_clickHandler(event:MouseEvent):void
{
var outStr:String;
outStr = wikiParser.parseWikiString(inputText.text);

if(dollarToEuro.selected) {
outStr = CurrencyConverter.usdToEuro(outStr);
}

if(urlToATag.selected) {
outStr = URLParser.urlToATag(outStr);
}

outputText.text = outStr;
}

]]>
</fx:Script>
<!--wiki解析程式-->
<s:VGroup width="650" height="450" verticalAlign="middle" verticalCenter="0" horizontalAlign="center"
  horizontalCenter="0">
<s:Panel width="100%" height="100%" title="解析程式_原始字串">
<s:VGroup width="100%" height="100%">
<s:TextArea id="inputText" width="100%" height="100%"/>
<s:HGroup width="100%" horizontalAlign="right">
<s:CheckBox id="dollarToEuro" label="$ to €"/>
<s:CheckBox id="urlToATag" label="URLs to &lt;a&gt;"/>
<s:Button id="testButton" label="轉換" click="testButton_clickHandler(event)"/>
</s:HGroup>
</s:VGroup>
</s:Panel>

<s:Panel width="100%" height="100%" title="HTML文字">
<s:TextArea id="outputText" width="100%" height="100%"/>
</s:Panel>
</s:VGroup>
</s:Application>

=>WikiParser .as

package com.cen.programmingas3.wikiEditor
{
/**
 * wiki解析類
 * - 使用正則表示式將wiki字串轉換成HTML文字；
 */ 
public class WikiParser {

/**
 * 屬性*/
/**
 * wiki字串
 */
public var wikiData:String; 

/**
 * 建構函式：使用原始資料初始化wikiData屬性；
 */
public function WikiParser() {
wikiData = setWikiData();
}

/**
 * 返回原始wiki資料
 */
private function setWikiData():String {
/*原始資料*/
var str:String = "'''Test wiki data'''\n" +// 加粗字型；
"\n" +
"This is a test. This is ''only'' a test.\n" +// 斜體；
"Basic rules:\n" +
"* 3 single quote marks indicates '''bold'''.\n" +
"* 2 single quote marks indicates ''italics''.\n" +
"* An asterisk creates a bulleted list item.\n" +
"* Use blank lines as paragraph separators.\n" +
"\n" +
"You can convert a dollar value like this: $9.95.\n" +
"\n" +
"Here's a URL to convert: http://www.adobe.com.\n" +
"\n" +
"Here's an e-mail address to convert: mailto:

[email protected]";

return str;
}

/**
 * 轉換方法：
 * 轉換wiki字串為HTML文字;
 */
public function parseWikiString (wikiString:String):String {
// 粗體處理
var result:String = parseBold(wikiString);

// 斜體處理
result = parseItalic(result);

// 段落處理
result = linesToParagraphs(result);

// 專案符號處理
result = parseBullets(result);

return result;
}

/**
 * 粗體處理：將'''foo'''轉換成<b>foo</b>
 */
private function parseBold(input:String):String {
var pattern:RegExp = /'''(.*?)'''/g;// 有限匹配；
return input.replace(pattern, "<b>$1</b>");
}

/**
 * 斜體處理：將''foo''轉換成<i>foo</i>；
 */
private function parseItalic(input:String):String {
var pattern:RegExp = /''(.*?)''/g;
return input.replace(pattern, "<i>$1</i>");
}

/**
 * 專案符號；將* foo轉換成<li>foo</li>；
 */
private function parseBullets(input:String):String {
var pattern:RegExp = /^\*(.*)/gm;
return input.replace(pattern, "<li>$1</li>");
}

/**
 * 段落處理：使用<p>HTML標籤替換空行；
 */
private function linesToParagraphs(input:String):String {

/**
 * Strips out(剔除) empty lines(空行), which match /^$/gm
 */
var pattern:RegExp = /^$/gm;
var result:String = input.replace(pattern, "");

/**
 * 除了專案列表項外，其他都加上<P>標籤；
 */
pattern = /^([^*].*)$/gm;
return result.replace(pattern, "<p>$1</p>");
}  
}
}

=>URLParser.as

package com.cen.programmingas3.wikiEditor
{

/**
 * 實用類：轉換URL字串
 * _ such as "http://www.adobe.com" to HTML anchor links, such as "<a href='http://www.adobe.com'>http://www.adobe.com</a>;
 * 
 * 特別說明:在此說明的例子中，url以及ftp正則表示式不是正規、嚴謹的，這裡只是便於說明；
 */
public class URLParser
{
/**
 * Converts HTTP and FTP URLs to anchor links. This function assembles(組裝) a 
 * RegExp pattern out of multiple parts: protocol(協議), urlPart, and optionalUrlPart.
 */
public static function urlToATag(input:String):String {

/**
 * 協議部分_http://
 * Matches either http:// or ftp://. (?: indicates that the interior group
 * is not a capturing group.(不捕獲組)
 */
var protocol:String = "((?:http|ftp)://)";

/** 
 * www.adobe
 */
var urlPart:String = "([a-z0-9_-]+\.[a-z0-9_-]+)";// matches foo.example;

/**
 * .com
 */
var optionalUrlPart:String = "(\.[a-z0-9_-]*)";

/**
 * 組裝正則表示式
 * Assembles the pattern from its component parts.
 */
var urlPattern:RegExp = new RegExp (protocol + urlPart + optionalUrlPart, "ig");

/**
 * Replaces matching URL strings with a replacement string. The call to 
 * the replace() method uses references to captured groups (such as $1) 
 * to assemble the replacement string.
 */
var result:String = input.replace(urlPattern, "<a href='$1$2$3'><u>$1$2$3</u></a>");// <u>新增下劃線；

/** 
 * Next, find e-mail patterns and replace them with <a> hyperlinks.
 * 轉換郵件地址
 */
result = emailToATag(result); 
return result;
}

/**
 * 如：mailto:[email protected]；
 * Replaces an e-mail pattern with a corresponding(相對應的) HTML anchor hyperlink.
 * Like the urlToATag() method, this method assembles a regular expression out of constituent(組成) parts.
 */
public static function emailToATag(input:String):String {
/**
 * mailto:
 */
var protocol:String = "(mailto:)"; // $1;

/**
 * 姓名
 * Matches the name and @ symbol, such as [email protected]
 */
var name:String = "([a-z0-9_-]+(?:\.[a-z0-9_-])*@)";// $2;

/**
 * For the e-mail pattern [email protected], matches 
 * mail.example. (including the trailing dot).
 */
var domain:String = "((?:[a-z0-9_-].)*)";// $3;

/**
 * Matches the superdomain, such as com, uk, or org., which is 2 - 4 letters.
 */
var superDomain:String = "([a-z]{2,4})";// $4;

/**
 * Assembles(組裝) the matching regular expression out of constituent parts.
 */
var emailPattern:RegExp = new RegExp (protocol + name + domain + superDomain, "ig");

/**
 * Replaces matching e-mail strings with a replacement string. The call to 
 * the replace() method uses references to captured groups (such as $1) 
 * to assemble the replacement string.
 */
var result:String = input.replace(emailPattern, "<a href='$1$2$3$4'><u>$1$2$3$4</u></a>"); 

return result;
}
}
}

=>CurrencyConverter .as

package com.cen.programmingas3.wikiEditor
{

/**
 * 美元轉換成歐元類
 */
public class CurrencyConverter {
/**
 * 美元轉換成歐元
 * Converts strings of US dollar values (such as "$9.95") 
 * to Euro strings (such as "8.24 €".
 */
public static function usdToEuro(input:String):String {

/**
 * 美元正則表示式模式
 */
var usdPrice:RegExp = /\$([\d][\d,]*\.\d+)/g;

/**
 * Replaces the matching dollar strings with the Euro equivalent string.
 * The second parameter defines a function, used to define the 
 * replacement string.
 */
return input.replace(usdPrice, usdStrToEuroStr); 
}

/**
 * 如果replace()方法第二個引數：為函式，則會向其傳遞如下引數：
 * - (1)、匹配部分：The matching portion(部分) of the string, such as "$9.95";
 * - (2)、括號匹配項：The parenthetical(括號) match, such as "9.95";
 * - (3)、匹配開始下標：The index position in the string where the match begins;
 * - (4)、原始字串：The complete string;
 * 
 * This method takes the second parameter (args[1]), converts it to
 * a number, and then converts it to a Euro string, by applying a
 * conversion factor and then appending the € character.
 */
private static function usdStrToEuroStr(...args):String {
// 美元數值：
var usd:String = args[1];

// 去除逗號：
usd = usd.replace(",", "");

// 美元轉換成歐元匯率：
var exchangeRate:Number = 0.828017;

// 歐元值：
var euro:Number = Number(usd) * exchangeRate;

// 歐元符號：
const euroSymbol:String = String.fromCharCode(8364);

return euro.toFixed(2) + " " + euroSymbol;
}
}
}