本章的程式碼和上一章實現的是同樣的功能，但是本章採用更合理的技巧去組織程式碼，使程式碼更通用、易懂。具體程式碼貼在下面，

         ;程式碼清單6-1
         ;檔名：c06_mbr.asm
         ;檔案說明：硬碟主引導扇區程式碼
         ;建立日期：2011-4-12 22:12 
      
         jmp near start
         
  mytext db 'L',0x07,'a',0x07,'b',0x07,'e',0x07,'l',0x07,' ',0x07,'o',0x07,\
            'f',0x07,'f',0x07,'s',0x07,'e',0x07,'t',0x07,':',0x07
  number db 0,0,0,0,0
  
  start:
         mov ax,0x7c0                  ;設定資料段基地址 
         mov ds,ax
         
         mov ax,0xb800                 ;設定附加段基地址 
         mov es,ax
         
         cld
         mov si,mytext                 
         mov di,0
         mov cx,(number-mytext)/2      ;實際上等於 13
         rep movsw
     
         ;得到標號所代表的偏移地址
         mov ax,number
         
         ;計算各個數位
         mov bx,ax
         mov cx,5                      ;迴圈次數 
         mov si,10                     ;除數 
  digit: 
         xor dx,dx
         div si
         mov [bx],dl                   ;儲存數位
         inc bx 
         loop digit
         
         ;顯示各個數位
         mov bx,number 
         mov si,4                      
   show:
         mov al,[bx+si]
         add al,0x30
         mov ah,0x04
         mov [es:di],ax
         add di,2
         dec si
         jns show
         
         mov word [es:di],0x0744

         jmp near $

  times 510-($-$$) db 0
                   db 0x55,0xaa
 

實驗現象：

實驗體會：

有了王爽《組合語言》的基礎，讀第二部分8086模式的程式碼沒有任何難度，有幾個地方需要說明

a）

jns show 當顯示完最後一個數位後， SI 的內容是零。執行 dec si 指令後，由於產生了借位，實際的運算結果是 0xffff（SI 只能容納 16 個位元），因其最高位是“1”，故處理器將標誌位 SF 置“1”，表明當前 SI 中的結果可以理解為一個負數（－1）。於是，執行 jns show 時，條件不滿足，接著執行後面第 51 行的指令。

b）

jmp near $ 整個程式到此結束。為了使處理器還有事做，源程式第 53 行，是一個無限迴圈。 NASM編譯器ᨀ供了一個標記“$”，該標記等同於標號，你可以把它看成是一個隱藏在當前行行首的標號。因此， jmp near $的意思是，轉移到當前指令繼續執行，它和infi: jmp near infi是一樣的，沒有區別，但不需要使用標號，更不必為給標號起一個有意義的名字而傷腦筋。

c）

times 510-($-$$) db 0

db 0x55,0xaa

源程式第 55 行，用於重複偽指令“db 0”若干次。重複的次數是由 510-($-$ $)得到的，除去 0x55 和 0xAA 後，剩餘的主引導扇區內容是 510 位元組；$是當前行的彙編地址； $ $是 NASM編譯器ᨀ供的另一個標記，代表當前彙編節（段）的起始彙編地址。當前程式沒有定義節或段， 就預設地自成一個彙編段，而且起始的彙編地址是 0（程式起始處）。這樣，用當前彙編地址減去程式開頭的彙編地址（0），就是程式實體的大小。再用 510 減去程式實體的大小，就是需要填充的位元組數。就像處理器把記憶體劃分成邏輯上的分段一樣，源程式也應當按段來組織，劃分成獨立的程式碼段、資料段等。