用applescript實現讀取配置檔案，選擇登入的ssh 使用者名稱與密碼，實現自動終端登入

年前入手macbook，由於工作需要通過ssh連線遠端伺服器，win系統經常用SecureCRT，mac也有，裝了還需破解，不清楚是mac 系統的原因還是什麼問題，經常掛掉，重啟也可以執行，而且字型調整快捷鍵沒找到如何修改，煩人的command與雙指觸控板滑動。
mac欄位的終端也還可以，挺好用，只是ssh的遠端使用者名稱與密碼需要一次一次的貼上複製，發現有applescript指令碼，心血來潮，實現讀取配置檔案，展示選擇要ssh的主機，自動貼上使用者名稱與密碼，實現自動登入

密碼檔案

#註釋資訊，xxx伺服器
#顯示選擇的資訊  tab間隔   使用者@ip=密碼
#例如
#[email protected]192.168.1.71  [email protected]192.168.1.71=pwd
[email protected]192.168.1.72   [email protected]192.168.1.72=h112314
[email protected]192.168.1.73   [email protected]192.168.1.73=h212321
[email protected]
 
192.168.1.74   [email protected]192.168.1.74=h324231
192.168.1.70    [email protected]192.168.1.70=hca13

applescript 原始碼

(*  
    ssh auto login
    用於讀取密碼配置檔案，選擇需要登入的遠端伺服器，實現自動登入
    @date:2016年02月03日00:11:49
    @auth Jeff Zhang
*)


(*
open Terminal
case terminal exist,open new tab
case terminal not exist,open new terminal
*)
 

on makeNewTerminal()
    tell application "System Events"
        try
            set terminal to application process "Terminal"
            set newBoo to false
        on error the error_message number the error_number
            tell application "Terminal" to launch
            --  set newTab to do script "" -- create a new window with no initial command
            --  set current settings of newTab to settings set "Grass"
            -- end tell
            delay 0.5
            set newBoo to true
        end try

        set terminal to application process "Terminal"
        set frontmost of terminal to true
        delay 0.5
        -- keystroke "n" using command down

        if newBoo then
            keystroke "n" using command down
        else
            keystroke "t" using command down
        end if
    end tell
end makeNewTerminal


(*
login ssh
If the speed of network is slow，you can use command + v to paste password .
because in this program delay 1s
*)
on sshLogin(uname, pwd)

    makeNewTerminal()
    beep
    set sshCommand to "ssh " & uname & "
"
    set the clipboard to sshCommand
    tell application "System Events"
        (* Note that the input method is not English *)
        keystroke "v" using command down
        delay 1
        set sshPwd to pwd & "
"
        set the clipboard to sshPwd
        keystroke "v" using command down
        -- set the clipboard to pwd
    end tell
end sshLogin
-- sshLogin("[email protected]", "password")

on selectItems(itemList)
    if itemList = null or length of itemList = 0 then
        display dialog "empty ssh information list" buttons {"OK"} default button 1
        return false
    end if
    set itemKeys to {}
    repeat with i in itemList
        set end of itemKeys to key1 of i
    end repeat
    set theSelected to choose from list itemKeys with prompt "Pick a ssh connect:"
    if theSelected ≠ false then
        set selectdValue to first item of theSelected
        repeat with i in itemList
            set k to key1 of i
            if k is equal to selectdValue then
                set r to key2 of i
                log "you choose result value is " & r
                return r
            end if
        end repeat
    end if
    return theSelected
end selectItems

on test()
    set FoldersList to {}
    set end of FoldersList to {key1:"RAA", key2:"Research:Journals:RAA11111:"}
    set end of FoldersList to {key1:"Project", key2:"Research:Project:"}
    set end of FoldersList to {key1:"MYSELF", key2:"MYSELF:"}
    set end of FoldersList to {key1:"DoctorPHD", key2:"MYSELF:DoctorPHD"}
    set end of FoldersList to {key1:"Photos", key2:"MYSELF:Photos"}
    set end of FoldersList to {key1:"Journals", key2:"Research:Journals"}
    set end of FoldersList to {key1:"Personal", key2:"Research:Personal"}
    set sresult to selectItems(FoldersList)

    if sresult ≠ false then
        set KeyWordSelected to item 1 of sresult
        log "result " & sresult & "  " & KeyWordSelected
    end if
end test

on readSshPropFile(filePath)
    set rs to {}
    try
        set file2content to read POSIX file filePath as «class utf8»
    on error the error_message number the error_number
        display dialog "Error: " & filePath & " not exist" buttons {"Cancel"} default button 1
        return false
    end try

    set theLines to paragraphs of file2content
    set AppleScript's text item delimiters to " "

    repeat with linestr in theLines
        if linestr starts with "#" then
        else
            set file2s to every text item of linestr
            if length of file2s = 2 then
                set key1 to first item of file2s
                set key2 to item 2 of file2s
                if key2 contains "=" then
                    set end of rs to {key1:key1, key2:key2}
                else
                    log key2 & " not right"
                end if
            end if
        end if
    end repeat
    return rs
end readSshPropFile


on main(thefilePath)
    set sshInfoList to readSshPropFile(thefilePath)
    log sshInfoList
    if sshInfoList ≠ false then
        set selectValue to selectItems(sshInfoList)
        if selectValue ≠ false then
            set AppleScript's text item delimiters to "="
            set file2s to every text item of selectValue
            set uname to item 1 of file2s
            set pwd to item 2 of file2s
            log uname & "=" & pwd
            sshLogin(uname, pwd)
        end if
    end if
end main

on run argv
    -- 遠端主機使用者資訊檔案
    set thefilePath to "/Users/zhanghl/Library/Scripts/Applications/Terminal/pwd.prop"
    if length of argv = 1 then
        set thefilePath to item 1 of argv
    end if 

    main(thefilePath)
end run

mac 工具 Automator ，新增一個服務，執行shell 指令碼

echo "applescript auto login ssh"
#這裡可以知道密碼檔案位置
filePath="/Users/zhanghl/Library/Scripts/Applications/Terminal/pwd.prop"
osascript /Users/zhanghl/Library/Scripts/Applications/Terminal/autoSsh.scpt $filePath
exit 0

設定啟動快捷鍵，我這裡用command+shift+0

執行結果

執行快捷鍵 command+shift+0
需注意：當前游標所在的程式的快捷鍵衝突

1. 選擇登陸的主機
   
2. 選擇好後，會自動開啟終端，並貼上使用者與密碼，可能網路不好，ssh會慢點，密碼在剪下板中，手動貼上即可，程式中延遲1s貼上密碼