模擬滑鼠鍵盤操作，含硬體模擬技術。
鍵盤是我們使用計算機的一個很重要的輸入裝置了，即使在滑鼠大行其道的今天，很多程式依然離不開鍵盤來操作。但是有時候，一些重複性的，很繁瑣的鍵盤操作總會讓人疲憊，於是就有了用程式來代替人們按鍵的方法，這樣可以把很多重複性的鍵盤操作交給程式來模擬，省了很多精力，按鍵精靈就是這樣的一個軟體。那麼我們怎樣才能用VB來寫一個程式，達到與按鍵精靈類似的功能呢？那就讓我們來先了解一下windows中響應鍵盤事件的機制。
     當用戶按下鍵盤上的一個鍵時，鍵盤內的晶片會檢測到這個動作，並把這個訊號傳送到計算機。如何區別是哪一個鍵被按下了呢？鍵盤上的所有按鍵都有一個編碼，稱作鍵盤掃描碼。當你按下一個鍵時，這個鍵的掃描碼就被傳給系統。掃描碼是跟具體的硬體相關的，同一個鍵，在不同鍵盤上的掃描碼有可能不同。鍵盤控制器就是將這個掃描碼傳給計算機，然後交給鍵盤驅動程式。鍵盤驅動程式會完成相關的工作，並把這個掃描碼轉換為鍵盤虛擬碼。什麼是虛擬碼呢？因為掃描碼與硬體相關，不具有通用性，為了統一鍵盤上所有鍵的編碼，於是就提出了虛擬碼概念。無論什麼鍵盤，同一個按鍵的虛擬碼總是相同的，這樣程式就可以識別了。簡單點說，虛擬碼就是我們經常可以看到的像VK_A,VK_B這樣的常數，比如鍵A的虛擬碼是65，寫成16進位制就是&H41，注意，人們經常用16進位制來表示虛擬碼。當鍵盤驅動程式把掃描碼轉換為虛擬碼後，會把這個鍵盤操作的掃描碼和虛擬碼還有其它資訊一起傳遞給作業系統。然後作業系統則會把這些資訊封裝在一個訊息中，並把這個鍵盤訊息插入到訊息列隊。最後，要是不出意外的話，這個鍵盤訊息最終會被送到當前的活動視窗那裡，活動視窗所在的應用程式接收到這個訊息後，就知道鍵盤上哪個鍵被按下，也就可以決定該作出什麼響應給使用者了。這個過程可以簡單的如下表示：
使用者按下按鍵-----鍵盤驅動程式將此事件傳遞給作業系統-----作業系統將鍵盤事件插入訊息佇列-----鍵盤訊息被髮送到當前活動視窗
明白了這個過程，我們就可以程式設計實現在其中的某個環節來模擬鍵盤操作了。在VB中，有多種方法可以實現鍵盤模擬，我們就介紹幾種比較典型的。 
1.區域性級模擬

     從上面的流程可以看出，鍵盤事件是最終被送到活動視窗，然後才引起目標程式響應的。那麼最直接的模擬方法就是：直接偽造一個鍵盤訊息發給目標程式。哈哈，這實在是很簡單，windows提供了幾個這樣的API函式可以實現直接向目標程式傳送訊息的功能，常用的有SendMessage和PostMessage，它們的區別是PostMessage函式直接把訊息仍給目標程式就不管了，而SendMessage把訊息發出去後，還要等待目標程式返回些什麼東西才好。這裡要注意的是，模擬鍵盤訊息一定要用PostMessage函式才好，用SendMessage是不正確的(因為模擬鍵盤訊息是不需要返回值的，不然目標程式會沒反應)，切記切記！PostMessage函式的VB宣告如下：
Declare Function PostMessage Lib "user32" Alias "PostMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
引數hwnd 是你要傳送訊息的目標程式上某個控制元件的控制代碼，引數wMsg 是訊息的型別，表示你要傳送什麼樣的訊息，最後wParam 和lParam 這兩個引數是隨訊息附加的資料，具體內容要由訊息決定。
再來看看wMsg 這個引數，要模擬按鍵就靠這個了。鍵盤訊息常用的有如下幾個：
WM_KEYDOWN      表示一個普通鍵被按下
WM_KEYUP        表示一個普通鍵被釋放
WM_SYSKEYDOWN   表示一個系統鍵被按下，比如Alt鍵
WM_SYSKEYUP     表示一個系統鍵被釋放，比如Alt鍵
如果你確定要傳送以上幾個鍵盤訊息，那麼再來看看如何確定鍵盤訊息中的wParam 和lParam 這兩個引數。在一個鍵盤訊息中，wParam 引數的含義較簡單，它表示你要傳送的鍵盤事件的按鍵虛擬碼，比如你要對目標程式模擬按下A鍵，那麼wParam 引數的值就設為VK_A ,至於lParam 這個引數就比較複雜了，因為它包含了多個資訊，一般可以把它設為0，但是如果你想要你的模擬更真實一些，那麼建議你還是設定一下這個引數。那麼我們就詳細瞭解一下lParam 吧。lParam 是一個long型別的引數，它在記憶體中佔4個位元組，寫成二進位制就是00000000 00000000 00000000 00000000   一共是32位，我們從右向左數，假設最右邊那位為第0位(注意是從0而不是從1開始計數)，最左邊的就是第31位，那麼該引數的的0-15位表示鍵的傳送次數等擴充套件資訊，16-23位為按鍵的掃描碼，24-31位表示是按下鍵還是釋放鍵。大家一般習慣寫成16進位制的，那麼就應該是&H00 00 00 00 ，第0-15位一般為&H0001，如果是按下鍵，那麼24-31位為&H00，釋放鍵則為&HC0,那麼16-23位的掃描碼怎麼會得呢？這需要用到一個API函式MapVirtualKey，這個函式可以將虛擬碼轉換為掃描碼，或將掃描碼轉換為虛擬碼，還可以把虛擬碼轉換為對應字元的ASCII碼。它的VB宣告如下：
Declare Function MapVirtualKey Lib "user32" Alias "MapVirtualKeyA" (ByVal wCode As Long, ByVal wMapType As Long) As Long
引數wCode 表示待轉換的碼，引數wMapType 表示從什麼轉換為什麼，如果是虛擬碼轉掃描碼，則wMapType 設定為0，如果是虛擬掃描碼轉虛擬碼，則wMapType 設定為1，如果是虛擬碼轉ASCII碼，則wMapType 設定為2.相信有了這些，我們就可以構造鍵盤事件的lParam引數了。下面給出一個構造lParam引數的函式：
Declare Function MapVirtualKey Lib "user32" Alias "MapVirtualKeyA" (ByVal wCode As Long, ByVal wMapType As Long) As Long

Function MakeKeyLparam(ByVal VirtualKey As Long, ByVal flag As Long) As Long
'引數VirtualKey表示按鍵虛擬碼,flag表示是按下鍵還是釋放鍵，用WM_KEYDOWN和WM_KEYUP這兩個常數表示
     Dim s As String
     Dim Firstbyte As String     'lparam引數的24-31位
     If flag = WM_KEYDOWN   Then '如果是按下鍵
         Firstbyte = "00"
     Else
         Firstbyte = "C0"        '如果是釋放鍵
     End If
     Dim Scancode As Long
     '獲得鍵的掃描碼
     Scancode = MapVirtualKey(VirtualKey, 0)
     Dim Secondbyte As String    'lparam引數的16-23位，即虛擬鍵掃描碼
     Secondbyte = Right("00" & Hex(Scancode), 2)
     s = Firstbyte & Secondbyte & "0001"   '0001為lparam引數的0-15位，即傳送次數和其它擴充套件資訊
     MakeKeyLparam = Val("&H" & s)
End Function

這個函式像這樣呼叫，比如按下A鍵，那麼lParam=MakeKeyLparam(VK_A,WM_KEYDOWN) ，很簡單吧。值得注意的是，即使你傳送訊息時設定了lParam引數的值，但是系統在傳遞訊息時仍然可能會根據當時的情況重新設定該引數，那麼目標程式收到的訊息中lParam的值可能會和你傳送時的有所不同。所以，如果你很懶的話，還是直接把它設為0吧，對大多數程式不會有影響的，呵呵。
     好了，做完以上的事情，現在我們可以向目標程式傳送鍵盤訊息了。首先取得目標程式接受這個訊息的控制元件的控制代碼，比如目標控制代碼是12345，那麼我們來對目標模擬按下並釋放A鍵，像這樣：(為了簡單起見，lParam這個引數就不構造了，直接傳0)
PostMessage 12345，WM_KEYDOWN，VK_A，0&    '按下A鍵
PostMessage 12345，WM_UP，VK_A，0&         '釋放A鍵
好了，一次按鍵就完成了。現在你可以迫不及待的開啟記事本做實驗，先用FindWindowEx這類API函式找到記事本程式的控制代碼，再向它傳送鍵盤訊息，期望記事本里能詭異的自動出現字元。可是你馬上就是失望了，咦，怎麼一點反應也沒有？你欺騙感情啊~~~~~~~~~~55555555555555   不是的哦，接著往下看啊。
一般目標程式都會含有多個控制元件，並不是每個控制元件都會對鍵盤訊息作出反應，只有把鍵盤訊息傳送給接受它的控制元件才會得到期望的反應。那記事本來說，它的編輯框其實是個edit類，只有這個控制元件才對鍵盤事件有反應，如果只是把訊息發給記事本的窗體，那是沒有用的。現在你找出記事本那個編輯框的控制代碼，比如是54321，那麼寫如下程式碼：
PostMessage 54321，WM_KEYDOWN，VK_F1，0&    '按下F1鍵
PostMessage 54321，WM_UP，VK_F1，0&         '釋放F1鍵
怎麼樣，是不是打開了記事本的“幫助”資訊？這說明目標程式已經收到了你發的訊息，還不錯吧~~~~~~~~
可以馬上新問題就來了，你想模擬向記事本按下A這個鍵，好在記事本里自動輸入字元，可是，沒有任何反應！這是怎麼一回事呢？
原來，如果要向目標程式傳送字元，光靠WM_KEYDOWN和WM_UP這兩個事件還不行，還需要一個事件：WM_CHAR，這個訊息表示一個字元，程式需靠它看來接受輸入的字元。一般只有A，B，C等這樣的按鍵才有WM_CHAR訊息，別的鍵(比如方向鍵和功能鍵)是沒有這個訊息的，WM_CHAR訊息一般發生在WM_KEYDOWN訊息之後。WM_CHAR訊息的lParam引數的含義與其它鍵盤訊息一樣，而它的wParam則表示相應字元的ASCII編碼(可以輸入中文的哦^_^)，現在你可以寫出一個完整的向記事本里自動寫入字元的程式了，下面是一個例子，並附有這些訊息常數的具體值：
Declare Function PostMessage Lib "user32" Alias "PostMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Declare Function MapVirtualKey Lib "user32" Alias "MapVirtualKeyA" (ByVal wCode As Long, ByVal wMapType As Long) As Long

Public Const WM_KEYDOWN = &H100
Public Const WM_KEYUP = &H101
Public Const WM_CHAR = &H102
Public Const VK_A = &H41

Function MakeKeyLparam(ByVal VirtualKey As Long, ByVal flag As Long) As Long
     Dim s As String
     Dim Firstbyte As String     'lparam引數的24-31位
     If flag = WM_KEYDOWN   Then '如果是按下鍵
         Firstbyte = "00"
     Else
         Firstbyte = "C0"        '如果是釋放鍵
     End If
     Dim Scancode As Long
     '獲得鍵的掃描碼
     Scancode = MapVirtualKey(VirtualKey, 0)
     Dim Secondbyte As String    'lparam引數的16-23位，即虛擬鍵掃描碼
     Secondbyte = Right("00" & Hex(Scancode), 2)
     s = Firstbyte & Secondbyte & "0001"   '0001為lparam引數的0-15位，即傳送次數和其它擴充套件資訊
     MakeKeyLparam = Val("&H" & s)
End Function

Private Sub Form_Load()
     dim hwnd as long
     hwnd = XXXXXX   'XXXXX表示記事本編輯框的控制代碼
     PostMessage hwnd,WM_KEYDOWN，VK_A，MakeKeyLparam(VK_A,WM_KEYDOWN)   '按下A鍵
     PostMessage hwnd,WM_CHAR，ASC("A"),MakeKeyLparam(VK_A,WM_KEYDOWN)   '輸入字元A
     PostMessage hwnd,WM_UP，VK_A，MakeKeyLparam(VK_A,WM_UP)        '釋放A鍵
End Sub

這就是通過區域性鍵盤訊息來模擬按鍵。這個方法有一個極大的好處，就是：它可以實現後臺按鍵，也就是說他對你的前臺操作不會有什麼影響。比如，你可以用這個方法做個程式在遊戲中模擬按鍵來不斷地執行某些重複的操作，而你則一邊喝茶一邊與QQ上的MM們聊得火熱，它絲毫不會影響你的前臺操作。無論目標程式是否獲得焦點都沒有影響，這就是後臺模擬按鍵的原理啦~~~~

2.全域性級模擬

     你會發現，用上面的方法模擬按鍵並不是對所有程式都有效的，有的程式啊，你向它發了一大堆訊息，可是它卻一點反應也沒有。這是怎麼回事呢？這就要看具體的情況了，有些程式(特別是一些遊戲)出於某些原因，會禁止使用者對它使用模擬按鍵程式，這個怎麼實現呢？比如可以在程式中檢查一下，如果發現自己不是活動視窗，就不接受鍵盤訊息。或者仔細檢查一下收到的鍵盤訊息，你會發現真實的按鍵和模擬的按鍵訊息總是有一些小差別，從這些小差別上，目標程式就能判斷出：這是假的！是偽造的！！因此，如果用PostMessage傳送區域性訊息模擬按鍵不成功的話，你可以試一試全域性級的鍵盤訊息，看看能不能騙過目標程式。
模擬全域性鍵盤訊息常見的可以有以下一些方法：
(1) 用API函式keybd_event，這個函式可以用來模擬一個鍵盤事件，它的VB宣告為：
Declare Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)
引數bVk表示要模擬的按鍵的虛擬碼，bScan表示該按鍵的掃描碼(一般可以傳0)，dwFlags表示是按下鍵還是釋放鍵(按下鍵為0，釋放鍵為2)，dwExtraInfo是擴充套件標誌，一般沒有用。比如要模擬按下A鍵，可以這樣：
Const KEYEVENTF_KEYUP = &H2
keybd_event VK_A, 0, 0, 0    '按下A鍵
keybd_event VK_A, 0, KEYEVENTF_KEYUP, 0    '釋放A鍵
注意有時候按鍵的速度不要太快，否則會出問題，可以用API函式Sleep來進行延時，宣告如下：
Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
引數dwMilliseconds表示延時的時間，以毫秒為單位。
那麼如果要模擬按下功能鍵怎麼做呢？比如要按下Ctrl+C實現拷貝這個功能，可以這樣：
keybd_event VK_Ctrl, 0, 0, 0    '按下Ctrl鍵
keybd_event VK_C, 0, 0, 0       '按下C鍵
Sleep 500             '延時500毫秒
keybd_event VK_C, 0, KEYEVENTF_KEYUP, 0    '釋放C鍵
keybd_event VK_Ctrl, 0, KEYEVENTF_KEYUP, 0    '釋放Ctrl鍵
好了，現在你可以試試是不是可以騙過目標程式了，這個函式對大部分的視窗程式都有效，可是仍然有一部分遊戲對它產生的鍵盤事件熟視無睹，這時候，你就要用上bScan這個引數了。一般的，bScan都傳0，但是如果目標程式是一些DirectX遊戲，那麼你就需要正確使用這個引數傳入掃描碼，用了它可以產生正確的硬體事件訊息，以被遊戲識別。這樣的話，就可以寫成這樣：
keybd_event VK_A, MapVirtualKey(VK_A, 0), 0, 0    '按下A鍵
keybd_event VK_A, MapVirtualKey(VK_A, 0), KEYEVENTF_KEYUP, 0    '釋放A鍵
以上就是用keybd_event函式來模擬鍵盤事件。除了這個函式，SendInput函式也可以模擬全域性鍵盤事件。SendInput可以直接把一條訊息插入到訊息佇列中，算是比較底層的了。它的VB宣告如下：
Declare Function SendInput Lib "user32.dll" (ByVal nInputs As Long, pInputs As GENERALINPUT, ByVal cbSize As Long) As Long
引數： 
nlnprts：定義plnputs指向的結構的數目。
plnputs：指向INPUT結構陣列的指標。每個結構代表插人到鍵盤或滑鼠輸入流中的一個事件。
cbSize：定義INPUT結構的大小。若cbSize不是INPUT結構的大小，則函式呼叫失敗。
返回值：函式返回被成功地插人鍵盤或滑鼠輸入流中的事件的數目。若要獲得更多的錯誤資訊，可以呼叫GetlastError函式。
備註：Sendlnput函式將INPUT結構中的事件順序地插入鍵盤或滑鼠的輸入流中。這些事件與使用者插入的（用滑鼠或鍵盤）或呼叫keybd_event，mouse_event，或另外的Sendlnput插人的鍵盤或滑鼠的輸入流不相容。
嗯，這個函式用起來蠻複雜的，因為它的引數都是指標一類的東西。要用它來模擬鍵盤輸入，先要構造一組資料結構，把你要模擬的鍵盤訊息裝進去，然後傳給它。為了方便起見，把它做在一個過程裡面，要用的時候直接呼叫好了，程式碼如下：
Declare Function SendInput Lib "user32.dll" (ByVal nInputs As Long, pInputs As GENERALINPUT, ByVal cbSize As Long) As Long
Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (pDst As Any, pSrc As Any, ByVal ByteLen As Long)
Type GENERALINPUT
    dwType As Long
    xi(0 To 23) As Byte
End Type

Type KEYBDINPUT
wVk As Integer
   wScan As Integer
   dwFlags As Long
   time As Long
   dwExtraInfo As Long
End Type

Const INPUT_KEYBOARD = 1

Sub MySendKey(bkey As Long)
'引數bkey傳入要模擬按鍵的虛擬碼即可模擬按下指定鍵
Dim GInput(0 To 1) As GENERALINPUT
Dim KInput As KEYBDINPUT
KInput.wVk = bkey   '你要模擬的按鍵
KInput.dwFlags = 0 '按下鍵標誌
GInput(0).dwType = INPUT_KEYBOARD
CopyMemory GInput(0).xi(0), KInput, Len(KInput) '這個函式用來把記憶體中KInput的資料複製到GInput
KInput.wVk = bkey 
KInput.dwFlags = KEYEVENTF_KEYUP   ' 釋放按鍵
GInput(1).dwType = INPUT_KEYBOARD ' 表示該訊息為鍵盤訊息
CopyMemory GInput(1).xi(0), KInput, Len(KInput)
'以上工作把按下鍵和釋放鍵共2條鍵盤訊息加入到GInput資料結構中
SendInput 2, GInput(0), Len(GInput(0))     '把GInput中存放的訊息插入到訊息列隊
End Sub

     除了以上這些，用全域性鉤子也可以模擬鍵盤訊息。如果你對windows中訊息鉤子的用法已經有所瞭解，那麼你可以通過設定一個全域性HOOK來模擬鍵盤訊息，比如，你可以用WH_JOURNALPLAYBACK這個鉤子來模擬按鍵。WH_JOURNALPLAYBACK是一個系統級的全域性鉤子，它和WH_JOURNALRECORD的功能是相對的，常用它們來記錄並回放鍵盤滑鼠操作。WH_JOURNALRECORD鉤子用來將鍵盤滑鼠的操作忠實地記錄下來，記錄下來的資訊可以儲存到檔案中，而WH_JOURNALPLAYBACK則可以重現這些操作。當然亦可以單獨使用WH_JOURNALPLAYBACK來模擬鍵盤操作。你需要首先宣告SetWindowsHookEx函式，它可以用來安裝訊息鉤子：
Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" (ByVal idHook As Long,ByVal lpfn As Long, ByVal hmod As Long, ByVal dwThreadId As Long) As Long
先安裝WH_JOURNALPLAYBACK這個鉤子，然後你需要自己寫一個鉤子函式，在系統呼叫它時，把你要模擬的事件傳遞給鉤子引數lParam所指向的EVENTMSG區域，就可以達到模擬按鍵的效果。不過用這個鉤子模擬鍵盤事件有一個副作用，就是它會鎖定真實的滑鼠鍵盤，不過如果你就是想在模擬的時候不會受真實鍵盤操作的干擾，那麼用用它倒是個不錯的主意。
3.驅動級模擬

     如果上面的方法你都試過了，可是你發現目標程式卻仍然頑固的不接受你模擬的訊息，寒~~~~~~~~~還好，我還剩下最後一招，這就是驅動級模擬：直接讀寫鍵盤的硬體埠！
     有一些使用DirectX介面的遊戲程式，它們在讀取鍵盤操作時繞過了windows的訊息機制，而使用DirectInput.這是因為有些遊戲對實時性控制的要求比較高，比如賽車遊戲，要求以最快速度響應鍵盤輸入。而windows訊息由於是佇列形式的，訊息在傳遞時會有不少延遲，有時1秒鐘也就傳遞十幾條訊息，這個速度達不到遊戲的要求。而DirectInput則繞過了windows訊息，直接與鍵盤驅動程式打交道，效率當然提高了不少。因此也就造成，對這樣的程式無論用PostMessage或者是keybd_event都不會有反應，因為這些函式都在較高層。對於這樣的程式，只好用直接讀寫鍵盤埠的方法來模擬硬體事件了。要用這個方法來模擬鍵盤，需要先了解一下鍵盤程式設計的相關知識。
     在DOS時代，當用戶按下或者放開一個鍵時，就會產生一個鍵盤中斷(如果鍵盤中斷是允許的)，這樣程式會跳轉到BIOS中的鍵盤中斷處理程式去執行。開啟windows的裝置管理器，可以檢視到鍵盤控制器由兩個埠控制。其中&H60是資料埠，可以讀出鍵盤資料，而&H64是控制埠，用來發出控制訊號。也就是，從&H60號埠可以讀此鍵盤的按鍵資訊，當從這個埠讀取一個位元組，該位元組的低7位就是按鍵的掃描碼，而高1位則表示是按下鍵還是釋放鍵。當按下鍵時，最高位為0，稱為通碼，當釋放鍵時，最高位為1，稱為斷碼。既然從這個埠讀資料可以獲得按鍵資訊，那麼向這個埠寫入資料就可以模擬按鍵了！用過QbASIC4.5的朋友可能知道，QB中有個OUT命令可以向指定埠寫入資料，而INP函式可以讀取指定埠的資料。那我們先看看如果用QB該怎麼寫程式碼：
假如你想模擬按下一個鍵，這個鍵的掃描碼為&H50，那就這樣
OUT &H64,&HD2    '把資料&HD2傳送到&H64埠。這是一個KBC指令，表示將要向鍵盤寫入資料
OUT &H60,&H50    '把掃描碼&H50傳送到&H60埠，表示模擬按下掃描碼為&H50的這個鍵
那麼要釋放這個鍵呢？像這樣，傳送該鍵的斷碼：
OUT &H64,&HD2    '把資料&HD2傳送到&H64埠。這是一個KBC指令，表示將要向鍵盤寫入資料
OUT &H60,(&H50 OR &H80)    '把掃描碼&H50與資料&H80進行或運算，可以把它的高位置1，得到斷碼，表示釋放這個鍵
     好了，現在的問題就是在VB中如何向埠寫入資料了。因為在windows中，普通應用程式是無權操作埠的，於是我們就需要一個驅動程式來幫助我們實現。在這裡我們可以使用一個元件WINIO來完成讀寫埠操作。什麼是WINIO？WINIO是一個全免費的、無需註冊的、含源程式的WINDOWS2000埠操作驅動程式元件(可以到http://www.internals.com/上去下載)。它不僅可以操作埠，還可以操作記憶體；不僅能在VB下用，還可以在DELPHI、VC等其它環境下使用，效能特別優異。下載該元件，解壓縮後可以看到幾個資料夾，其中Release資料夾下的3個檔案就是我們需要的，這3個檔案是WinIo.sys(用於win xp下的驅動程式)，WINIO.VXD(用於win 98下的驅動程式)，WinIo.dll(封裝函式的動態連結庫)，我們只需要呼叫WinIo.dll中的函式，然後WinIo.dll就會安裝並呼叫驅動程式來完成相應的功能。值得一提的是這個元件完全是綠色的，無需安裝，你只需要把這3個檔案複製到與你的程式相同的資料夾下就可以使用了。用法很簡單，先用裡面的InitializeWinIo函式安裝驅動程式，然後就可以用GetPortVal來讀取埠或者用SetPortVal來寫入埠了。好，讓我們來做一個驅動級的鍵盤模擬吧。先把winio的3個檔案拷貝到你的程式的資料夾下，然後在VB中新建一個工程，新增一個模組，在模組中加入下面的winio函式宣告:

Declare Function MapPhysToLin Lib "WinIo.dll" (ByVal PhysAddr As Long, ByVal PhysSize As Long, ByRef PhysMemHandle) As Long
Declare Function UnmapPhysicalMemory Lib "WinIo.dll" (ByVal PhysMemHandle, ByVal LinAddr) As Boolean
Declare Function GetPhysLong Lib "WinIo.dll" (ByVal PhysAddr As Long, ByRef PhysVal As Long) As Boolean
Declare Function SetPhysLong Lib "WinIo.dll" (ByVal PhysAddr As Long, ByVal PhysVal As Long) As Boolean
Declare Function GetPortVal Lib "WinIo.dll" (ByVal PortAddr As Integer, ByRef PortVal As Long, ByVal bSize As Byte) As Boolean
Declare Function SetPortVal Lib "WinIo.dll" (ByVal PortAddr As Integer, ByVal PortVal As Long, ByVal bSize As Byte) As Boolean
Declare Function InitializeWinIo Lib "WinIo.dll" () As Boolean
Declare Function ShutdownWinIo Lib "WinIo.dll" () As Boolean
Declare Function InstallWinIoDriver Lib "WinIo.dll" (ByVal DriverPath As String, ByVal Mode As Integer) As Boolean
Declare Function RemoveWinIoDriver Lib "WinIo.dll" () As Boolean

' ------------------------------------以上是WINIO函式宣告-------------------------------------------

Declare Function MapVirtualKey Lib "user32" Alias "MapVirtualKeyA" (ByVal wCode As Long, ByVal wMapType As Long) As Long

'-----------------------------------以上是WIN32 API函式宣告-----------------------------------------

再新增下面這個過程：
Sub KBCWait4IBE()    '等待鍵盤緩衝區為空
Dim dwVal As Long
   Do
   GetPortVal &H64, dwVal, 1
'這句表示從&H64埠讀取一個位元組並把讀出的資料放到變數dwVal中
'GetPortVal函式的用法是GetPortVal 埠號,存放讀出資料的變數,讀入的長度
   Loop While (dwVal And &H2)
End Sub
上面的是一個根據KBC規範寫的過程，它的作用是在向鍵盤埠寫入資料前等待一段時間，後面將會用到。
然後再新增如下過程，這2個過程用來模擬按鍵：

Public Const KBC_KEY_CMD = &H64     '鍵盤命令埠
Public Const KBC_KEY_DATA = &H60    '鍵盤資料埠

Sub MyKeyDown(ByVal vKeyCoad As Long)   
'這個用來模擬按下鍵，引數vKeyCoad傳入按鍵的虛擬碼
Dim btScancode As Long
btScancode = MapVirtualKey(vKeyCoad, 0)

     KBCWait4IBE    '傳送資料前應該先等待鍵盤緩衝區為空
     SetPortVal KBC_KEY_CMD, &HD2, 1      '傳送鍵盤寫入命令
'SetPortVal函式用於向埠寫入資料，它的用法是SetPortVal 埠號,欲寫入的資料，寫入資料的長度
     KBCWait4IBE
     SetPortVal KBC_KEY_DATA, btScancode, 1   '寫入按鍵資訊,按下鍵
    
End Sub