1.易語言調用大漠之鼠標操作說明

本節沒什麽特別的只是談了談 大漠鼠標移動 和大漠的右鍵點擊 沒了 也沒什麽特別的兩點

.版本 2
.支持庫 spec

全局大漠.找圖 (0, 0, 2000, 2000, “表情包標誌.bmp”, “202020”, 0.9, 0, intX, intY)
調試輸出 (到文本 (intX) ＋ “:” ＋ 到文本 (intY))
.如果真 (intX ＞ 0 且 intY ＞ 0)
    全局大漠.鼠標移動 (intX, intY)
    輔助延時 (1000)
    全局大漠.鼠標_右鍵單擊 ()
    輔助延時 (1000)
    全局大漠.鼠標_右鍵單擊 ()
    輔助延時 (1000)

2.易語言調用大漠之鼠標移動

小知識：實現鼠標模擬人操作的軌跡 基礎防封手段

老師直接用的是大漠收費版的命令 的確挺好用

.版本 2

全局大漠.鼠標_模擬真實_VIP (1, 100, 40)
全局大漠.鼠標移動 (1334, 748)

後來想了想 練練手 寫了一個子程序實現同樣的功能 僅供參考

.版本 2
.支持庫 spec

.子程序 個人版鼠標模擬真實軌跡, , 公開
.參數 終點x, 整數型
.參數 終點y, 整數型
.參數 移動間隔時間, 整數型, , 毫秒單位
.參數 移動間隔距離, 整數型
.局部變量 鼠標當前x, 整數型
.局部變量 鼠標當前y, 整數型
.局部變量 a, 雙精度小數型
.局部變量 b, 雙精度小數型
.局部變量 軌跡x, 整數型
.局部變量 軌跡y, 整數型

 
‘ 基本思路
‘ =0 對參數進行一點點的檢測和格式化 不寫了 寫起來沒個完了
‘ =1.獲取當前鼠標位置 不要使用易語言自身的獲取鼠標坐標 因為可能沒考慮後臺和前臺的問題 還是用大漠本身的函數
全局大漠.鼠標_取位置 (鼠標當前x, 鼠標當前y)
調試輸出 (“鼠標當前位置” ＋ 到文本 (鼠標當前x) ＋ “:” ＋ 到文本 (鼠標當前y))
‘ =2 計算出當前鼠標位置和終點位置距離 並且計算出一元二次方程式的參數  終點縱坐標=a*終點橫坐標+b 鼠標當前縱坐標=a*鼠標當前橫坐標+b
a ＝ (終點y － 鼠標當前y) ÷ (終點x － 鼠標當前x)
b ＝ (終點y × 鼠標當前x － 終點x × 鼠標當前y) ÷ (鼠標當前x － 終點x)
調試輸出 (“a,b值：” ＋ 到文本 (a) ＋ “:” ＋ 到文本 (b))
 
‘ =3 主循環開始 依次增加間隔距離直到到達終點
‘ ==判斷下從哪個方向移動 橫縱兩個方向 哪個方向上距離大就用哪個方向
.如果 (取絕對值 (終點y － 鼠標當前y) ≥ 取絕對值 (終點x － 鼠標當前x))

    ‘ ====就從縱向走 還要分逆向還是正向
    .如果 (終點y － 鼠標當前y ≥ 0)
        調試輸出 (“縱向走-正向”)
        .變量循環首 (鼠標當前y, 終點y, 移動間隔距離, 軌跡y)
            軌跡x ＝ 到整數 ((軌跡y － b) ÷ a)
            全局大漠.鼠標移動 (軌跡x, 軌跡y)
            輔助延時 (移動間隔時間)
        .變量循環尾 ()

    .否則
        調試輸出 (“縱向走-逆向”)
        .變量循環首 (鼠標當前y, 終點y, －移動間隔距離, 軌跡y)
            軌跡x ＝ 到整數 ((軌跡y － b) ÷ a)
            全局大漠.鼠標移動 (軌跡x, 軌跡y)
            輔助延時 (移動間隔時間)
        .變量循環尾 ()
    .如果結束

.否則
    ‘ ====就從橫向走
    .如果 (終點x － 鼠標當前x ≥ 0)
        調試輸出 (“橫向走-正向”)
        .變量循環首 (鼠標當前x, 終點x, 移動間隔距離, 軌跡x)
            軌跡y ＝ 到整數 (a × 軌跡x ＋ b)
            全局大漠.鼠標移動 (軌跡x, 軌跡y)
            輔助延時 (移動間隔時間)
        .變量循環尾 ()

    .否則
        調試輸出 (“橫向走-逆向”)
        .變量循環首 (鼠標當前x, 終點x, －移動間隔距離, 軌跡x)
            軌跡y ＝ 到整數 (a × 軌跡x ＋ b)
            全局大漠.鼠標移動 (軌跡x, 軌跡y)
            輔助延時 (移動間隔時間)
        .變量循環尾 ()
    .如果結束

.如果結束

‘ =4 移動到終點位置 完成操作 因為前面的間隔移動無法保證最後一定會移動到終點位置
全局大漠.鼠標移動 (終點x, 終點y)
輔助延時 (移動間隔時間)

3.易語言調用大漠之鼠標特征說明及應用

看起來這玩意似乎對於安卓模擬器用處不大

鼠標特征碼用綜合工具來取

用法

.版本 2
.支持庫 spec

.如果真 (全局大漠.圓形漸開線 (“10fb337f”, 186, 494, 12, 10, 10, 100, intX, intY))
    調試輸出 (“鼠標特征碼位置：” ＋ 到文本 (intX) ＋ “:” ＋ 到文本 (intY))

123

[遠航筆記流水賬]易語言調用大漠初級入門(2)