一、計算2^12儲存在AX中（王爽組合語言第二版p100）：

		mov  	cx,12		;迴圈12次
		mov     ax,1		;初始化AX
s:		add		ax,ax
		loop  	s			;執行完loop後，要顯示的數字2^12 已經在暫存器AX

二、AX暫存器以顯示說明：

本例中,2^12=4096,故AX=1000H

則輸出字元為4096。

原理：
ax為十六位暫存器，所以輸出十進位制數範圍為0 - 65535，最大五位數，故設定CX=5,LOOP語句實現演算法:
4096/10000= 商0  餘數4096    ; 根據十進位制書寫習慣，不輸出前面的0字元 ，需要在輸出迴圈裡判斷

4096/1000= 商4  餘數96         ；輸出4
96/100= 商0  餘數96              ；輸出0
96/10=  商9  餘數6                 ；輸出9
6/1=  商6  餘數0                     ；輸出6
把每次所得商加上48即可得到相應數字的ASCII碼，

三、完整程式碼：

code segment
assume cs:code,ds:data,ss:stack
start:
        mov     ax,data
        mov     ds,ax
		
	mov  	cx,12		;迴圈12次
	mov     ax,1		;初始化AX
s:	add		ax,ax
	loop  	s			;執行完loop後，要顯示的數字2^12 已經在暫存器AX

        mov     si, offset divisors
        mov     di, offset results                     
        mov     cx,5   
aa:
        mov     dx,0            
        div     word ptr [si]   ;除法指令的被除數是隱含運算元，此處為dx:ax，商ax,餘數dx
        add     al,48           ;商加上48即可得到相應數字的ASCII碼
        mov     byte ptr [di],al        
        inc     di                                
        add     si,2                           
        mov     ax,dx                        
        loop    aa
        mov     cx,4    
        mov     di, offset results 
bb:
        cmp     byte ptr [di],'0'   ;不輸出前面的0字元    
        jne     print
        inc     di                           
        loop    bb
print:
        mov     dx,di                       
        mov     ah,9
        int     21h                   
        mov     ax,4C00h       
        int     21h
code ends
data    segment
divisors        DW 10000, 1000, 100, 10, 1
results          DB 0,0,0,0,0,"$"        ;存放五位數ASCII碼
data ends
stack segment STACK
stack ends
end start
 

四、DOSBOX執行截圖（dosbox已安裝masm611，並真確設定環境變數）

相關推薦