問題描述

有個資料庫使用者經常被鎖，Unlock之後沒幾秒就會被鎖住，因為涉及的專案太多，很難做到逐一排查，不知道是哪個專案用錯密碼，導致賬戶被鎖。後面排查日誌沒有發現登入失敗的日誌，故在網上查詢相關資料，發現可以建立一個觸發器可將相關日誌記錄下來。

解決方案

用dba賬戶建立如下觸發器即可。

CREATE OR REPLACE TRIGGER logon_denied_to_alert
  AFTER servererror ON DATABASE
DECLARE
  message   VARCHAR2(168);
  ip        VARCHAR2(15);
  v_os_user VARCHAR2(80);
  v_module  VARCHAR2(50);
  v_action  VARCHAR2(50);
  v_pid     VARCHAR2(10);
  v_sid     NUMBER;
  v_program VARCHAR2(48);
BEGIN
  IF (ora_is_servererror(1017)) THEN
    -- get ip FOR remote connections :
    IF upper(sys_context('userenv', 'network_protocol')) = 'TCP' THEN
      ip := sys_context('userenv', 'ip_address');
    END IF;
    SELECT sid INTO v_sid FROM sys.v_$mystat WHERE rownum < 2;
    SELECT p.spid, v.program
      INTO v_pid, v_program
      FROM v$process p, v$session v
     WHERE p.addr = v.paddr
       AND v.sid = v_sid;
    v_os_user := sys_context('userenv', 'os_user');
    dbms_application_info.read_module(v_module, v_action);
    message := to_char(SYSDATE, 'YYYY-MM-DD HH24:MI:SS') ||
               ' Password Erro: logon denied from ' || nvl(ip, 'localhost') || ' ' ||
               v_pid || ' User:' || v_os_user || ' with ' || v_program || '    ' ||
               v_module || ' ' || v_action||' dbuser:'||USER;
    sys.dbms_system.ksdwrt(2, message);
  END IF;
END;
 

參考來源

https://www.modb.pro/db/25539