Cypher是圖形資料庫Neo4j的宣告式查詢語言。
Cypher語句規則和具備的能力:
Cypher通過模式匹配圖資料庫中的節點和關係，來提取資訊或者修改資料。
Cypher語句中允許使用變數，用來表示命名、繫結元素和引數。
Cypher語句可以對節點、關係、標籤和屬性進行建立、更新和刪除操作。
Cypher語句可以管理索引和約束。

運算子
常規運算 DISTINCT, ., []
算數運算 +, -, *, /, %, ^
比較運算 =, <>, <, >, <=, >=, IS NULL, IS NOT NULL
邏輯運算 AND, OR, XOR, NOT
字串操作 +
List操作 +, IN, [x], [x .. y]

CREATE (n {name:"張三"})
例子2:批量建立節點並且分配屬性

UNWIND [{name:"李四"},{name:"張三"}] AS mynodes CREATE (n) SET n = mynodes
例3:建立節點時分配屬性和標籤

CREATE ( n:Person{name:"李四"} )
例4:建立一個關係，給兩個節點建立關係指定關係型別、方向和繫結一個變數。

CREATE ({name:"李四"})-[r:have]->({bookname:"設計模式"})

CREATE ({name:"李四"})-[:LOVES{since:"2017"}]->({name:"小花"})
例6:給已經存在的兩個節點建立一個關係。

MATCH (a:Person),(b:Person) WHERE a.name = '張三' AND b.name = 李四' CREATE (a)-[r:FRIEND]->(b) RETURN r

2.匹配語句
Cypher的MATCH語句和SQL的SELECT語句類似,都是查詢資料的表示式.而Cypher語句中的WHERE和SQL語句中的WHERE語句由這相同的作用,其作用是用來過濾匹配結的,在Cypher語句中WHERE是在MATCH、OPTIONAL MATCH、WITH或START語句中使用的過濾限定語句

匹配語句結構
[MATCH WHERE]
[OPTIONAL MATCH WHERE]
[WITH [ORDER BY] [SKIP] [LIMIT]]
RETURN [ORDER BY] [SKIP] [LIMIT]

例1:根據屬性匹配節點資訊。

MATCH (n{name:"張三"}) RETURN n
例2:根據標籤和屬性匹配節點資訊。

MATCH (n:Person{name:"李四"}}) RETURN n
例3:任意匹配，返回任意節點資訊。
Cypher語句允許任意匹配，任意匹配可以匹配任何與cypher表示式相符合的所有節點.
1.匹配任意節點

//該語句會匹配任意節點，並返回
MATCH (n) RETURN n
2.任意關係

//該語句是匹配出有任意關係的兩個節點
MATCH p = (n)-[r]->(m) RETURN p
3.可選匹配

//匹配結果集中如果有丟的部分，則會用null來補充
OPTIONAL MATCH (n)-[r]->(m) RETURN m
例4:匹配節點時指定標籤、屬性和關係型別

MATCH (n:Person)-[:FRIEND]->(m:Person) WHERE n.name = '張三'
例5:根據標籤過濾

//從圖資料庫中,過濾出Person標籤
MATCH (n) WHERE n:Person RETURN n
例6:根據節點屬性過濾

MATCH (n) WHERE n.name = "李思思" RETURN n
例7:根據關係屬性過濾

MATCH (n)-[k:KNOWS]->(f) WHERE k.since < 2000 RETURN f
例8:字串匹配
字串首尾可以使用STARTS WITH 和 ENDS WITH,去匹配定位字串，字串匹配還可以使用AONTAINS來匹配字串中包含的自字串。
1.匹配字串的開頭
匹配圖中的所有節點，返回節點中包含name屬性，且屬性值以”張”開頭的所有節點

MATCH (n) WHERE n.name STARTS WITH '張' RETURN n
2.匹配字串的末尾
匹配圖中的所有節點，返回節點中包含name屬性，且屬性值以”三”開頭的所有節點

MATCH (n) WHERE n.name ENDS WITH '三' RETURN n
3.匹配字串的包含匹配
匹配圖中的所有節點，返回節點中包含name屬性，且屬性值中任意位置包含”小”字串的節點

MATCH (n) WHERE n.name CONTAINS '三' RETURN n
4.字串排除匹配
在字串匹配的時候可以使用NOT關鍵字來排除匹配到的結果，得到相反的結果

//匹配圖中的所有節點，返回節點中包含name屬性，且不是姓張的所有節點
MATCH (n) WHERE NOT n.name STARTS WITH '張' RETURN n
例9:字串正則表示式
Cypher支援使用正則表示式進行過濾。 正則表示式語法從Java正則表示式繼承過來的。這包括支援改變字串匹配的標誌，包括不區分大小寫(?i)，多行(?m)和逗點(?s),在這裡正則表示式使用的解析符號是=~。

1.模糊匹配，類似sql語句中的like

//類似like ‘%小%’

MATCH (n) WHERE n.name =~ '.*小.*' RETURN n
2.不去分大小寫正則匹配

//不區分大小寫匹配，名字中以”ANDR”開頭的節點
MATCH (n) WHERE n.name =~ '(?i)ANDR.*' RETURN n
例10:WHERE句子中使用路徑匹配
1.使用邏輯運算子號和路徑作為過濾條件

//在圖中匹配名稱為”李四”或”王五”與”張三”有任何關係的節點，並返回符合匹配條件的節點資訊
MATCH (n { name: '張三' }),(m) WHERE m.name IN ['李四', '王五'] AND (n)<--(m) RETURN m
2.關係匹配使用NOT邏輯運算子號

//匹配和張三沒有關係的人
MATCH (persons),(zhangsan { name: '張三' }) WHERE NOT (persons)-->(zhangsan) RETURN persons
3.關係型別匹配，並使用正則表示式

//在圖中匹配張三節點和所有節點的關係型別以F開頭的所有關係
MATCH (n)-[r]->() WHERE n.name='張三' AND type(r)=~ 'F.*' RETURN r
例11:使用”或”邏輯匹配關係

//返回任意關係為KNOWS和LOVES的所有節點關係
MATCH p=(n)-[:KNOWS|:LOVES]->(m) RETURN p
例12:關係深度匹配
1.匹配從n到m，任意關係，深度1到5的節點

MATCH p=(n)-[*1..5]->(m) RETURN p
2.匹配從n到m，任意關係、任意深度的節點

MATCH p=(n)-[*]->(m) RETURN p
例13:匹配分頁返回

MATCH (n) WHERE n.productName='蘋果' RETURN n SKIP 10 LIMIT 10
例14:匹配去重返回

MATCH (n) WHERE n.productName='蘋果' RETURN DISTINCT n
例15:匹配分組返回值

MATCH (n) WHERE n.productName='蘋果' RETURN n ORDER BY n.price DESC
例16:別名返回

MATCH (n) WHERE n.productName=~'.*蘋果.*' RETURN n.productName AS name
例17:WITH語句使用使用示例
WITH語句是將第一部分匹配的輸出作為下一部分匹配的輸入。
1.查詢有十個以上朋友的張姓男子

MATCH (user)-[:FRIEND]-(friend) WHERE user.name =~ '張.*' WITH user, count(friend) AS friends WHERE friends > 10 RETURN user
2.WITH語句中使用ORDER BY、SKIP 和 LIMIT 語句示例。

MATCH (user)-[:FRIEND]-(friend) WITH user, count(friend) AS friends ORDER BY friends DESC SKIP 1 LIMIT 3 RETURN user
例17:UNION語句使用使用示例
1.使用UNION結果去重，求並集

MATCH (a)-[:KNOWS]->(b) RETURN b.name UNION MATCH (a)-[:LOVES]->(b) RETURN b.name
2.使用UNION ALL結果不去重, 求和集

MATCH (a)-[:KNOWS]->(b) RETURN b.name UNION ALL MATCH (a)-[:LOVES]->(b) RETURN b.name
例17:start語句匹配節點資訊
1.匹配所有節點

START n=node(*) RETURN n
2.根據節點的具體id匹配

//在node函式中的值，是節點在圖中的id
START n=node(1) RETURN n
3.節點更新和刪除
例1:更新和新增一個屬性

//1.建立一個節點，只有一個屬性name=’張三’
CREATE ({name:'張三'})

//2.給建立的”張三”節點，新增一個屬性age=20，修改name屬性值為”李四”
MATCH (n {name:'張三'}) SET n.name='李四' SET n.age=20 RETURN n
例2: 修改節點資訊,覆蓋節點屬性

//該語句會直接刪除掉name屬性，新增age屬性
MATCH (n {name:'張三'}) SET n={age:20}
例3:修改節點資訊,新增節點屬性

//該語句不會刪除掉name屬性，而是在節點中新增age屬性
MATCH (n {name:'張三'}) SET n += {age:20} RETURN n
例4:刪除節點屬性

MATCH (n{name:'張三'}) remove n.age RETURN n
例5:為節點新增新標籤

//新增一個標籤
MATCH (n{name:'張三'}) SET n:Person RETURN n
//新增多個標籤
MATCH (n{name:'張三'}) SET n:Person:Student RETURN n
例6:刪除節點標籤

MATCH (n{name:'張三'}) REMOVE n:Person RETURN n
例7:為已經存在的兩個節點新增關係

MATCH (a:Person {name: "張三"}), (b:Person {name: "李四"}) MERGE (a)-[r:FRIENDS]->(b)
例8:匹配一個節點，更新屬性如果屬性不存在則建立該屬性

MERGE (n:Person {name: "張三"}) ON CREATE SET n.created = timestamp() ON MATCH SET n.counter = coalesce(n.counter, 0) + 1, n.accessTime = timestamp()
例9:匹配一個節點為他建立一個新的關係

//如果沒有”王五”節點則建立一個新的
MATCH (a:Person {name: "張三"}) MERGE (a)-[r:KNOWS]->(b:Person {name: "王五"})
例10:刪除一個節和關係

MATCH (a)-[r:KNOWS]->(b) DELETE r,b
例11:級聯刪除

//刪除”王五”節點之後，將與王五節點建立關係也刪除掉
MATCH (n{name: "王五"}) DETACH DELETE n
4.索引和約束
例1:建立索引

//為”Person”標籤的name屬性建立索引
CREATE INDEX ON :Person(name)
例2:刪除索引

//刪除”Person”標籤的name屬性的索引
DROP INDEX ON :Person(name)
例3:匹配條件中使用索引

MATCH (n:Person) WHERE n.name = 'Andres' RETURN n
例4:建立節點屬性唯一約束
建立一個唯一約束保證圖資料庫中同一個標籤內的節點的屬性值不重複。
注意：不可以為已經建立索引的屬性建立唯一約束

CREATE CONSTRAINT ON (n:Person) ASSERT n.name IS UNIQUE
例5:建立節點屬性唯一約束

DROP CONSTRAINT ON (n:Person) ASSERT n.name IS UNIQUE