一、二維碼簡介

1 . 型別多樣，常見的有QR Code二維碼、 Data Matrix二維碼等。

2．高密度編碼，資訊容量大。

3．容錯能力強，具有糾錯功能：二維碼因穿孔、汙損等引起區域性損壞時，照樣可以正確得到識讀，損毀面積達50％仍可恢復資訊。

4．譯碼可靠性高：它比普通條碼譯碼錯誤率百萬分之二要低得多，誤位元速率不超過千萬分之一。

5．可引入加密措施：保密性、防偽性好。

二、影象預處理和二維碼增強

對比度太低：scale_image（或使用外部程式scale_image_range），增強影象的對比度。

影象模糊：emphasize銳化影象，使二維碼看起來更清晰。

三、解碼涉及的主要運算元

read_image ：讀圖

create_data_code_2d_model ：建立二維碼模型

find_data_code_2d ：查詢二維碼

clear_data_code_2d_model ：清除二維碼模型

還有幾個運算元也值得注意一下：

set_data_code_2d_param ：設定解碼時的引數

get_data_code_2d_param ：獲取解碼時的引數（如果沒有設定過，則獲得的是預設值）

get_data_code_2d_results ：獲得解碼後的一些結果

四、提高解碼能力的其他措施

如果二維碼影象預處理以後，仍舊解碼困難或者解位元速率不高，那麼可以通過以下措施進一步提高解碼能力：

1、如果整張圖資訊太多，則可以先把二維碼區域挖出來，使用reduce_domain和crop_domain運算元，這樣不僅可以降低解碼難度，還可以減少解碼時間。

2、當二維碼很小的時候，可以嘗試用zoom_image_factor放大了二維碼影象。

3、create_data_code_2d_model ('QR Code', [], [], DataCodeHandleQR)

建立模型時，[ ]中不填內容，實際預設屬性名是‘default_parameters’，預設屬性值是‘standard_recognition’。

如果想大幅度提高解碼成功率，可以將屬性值置為‘enhanced_recognition’或者‘maximum_recognition’。注意：解碼能力越強，解碼時間越長

4、find_data_code_2d (Image, SymbolXLDs, DataCodeHandle, 'train', 'all', ResultHandles, DecodedDataStrings)

該運算元中的GenParamNames、GenParamValues預設是空的，就是說直接找，找不到拉倒。如果是'train'，就是一面找一面調整模板引數。

預設情況下，它只會最多找到1個二維碼。如果想找出更多的二維碼（例如3個），可以這樣：

find_data_code_2d (Image2, SymbolXLDs, DataCodeHandle,'stop_after_result_num', 3, ResultHandles, DecodedDataStrings)

5、如果對於質量很差的二維碼，可以模擬日常手機掃碼時的操作，即多次改變曝光，多次解碼的方式，參考文章：

https://www.cnblogs.com/xh6300/p/9809692.html

6、通過set_data_code_2d_param運算元設定解碼時的引數，可以有效提高解碼能力。（見下文）

五、set_data_code_2d_param運算元的引數解析

下面用一個完整的例子來演示一下：

 1 *提高解位元速率的設定項：
 2 *1、'default_parameters', ''enhanced_recognition''
 3 *2、'polarity', 'dark_on_light'
 4 *3、['module_size_min','module_size_max']
 5 *4、挖出二維碼區域，挖得越精確越好（周圍最好不要有其他黑色畫素塊干擾）,這一部分我現在只是粗略挖了一下
 6 *5、增強影象對比度，我設計的函式enhanced_contrast （將影象色階從0-255重新對映到Min到Max之間）
 7 
 8 * create_data_code_2d_model ('QR Code', 'default_parameters', 'enhanced_recognition', DataCodeHandleQR) 
 9 create_data_code_2d_model ('QR Code', [], [], DataCodeHandleQR) 
10 
11 set_data_code_2d_param (DataCodeHandleQR, 'default_parameters', 'enhanced_recognition')
12 set_data_code_2d_param (DataCodeHandleQR, 'timeout', 200)
13 set_data_code_2d_param (DataCodeHandleQR, 'polarity', 'dark_on_light')
14 
15 * 碼粒個數設定(有幾種二維碼設定這個引數非法)
16 * set_data_code_2d_param(DataCodeHandleQR,'symbol_size_max', 11)
17 * set_data_code_2d_param(DataCodeHandleQR,'symbol_size_max', 31)
18 
19 count := 0
20 dev_set_line_width (3)
21 dev_set_draw('margin')
22 
23 list_files ('OK_NG', ['files','follow_links','recursive'], ImageFiles)
24 tuple_regexp_select (ImageFiles, ['\\.(tif|tiff|gif|bmp|jpg|jpeg|jp2|png|pcx|pgm|ppm|pbm|xwd|ima|hobj)$','ignore_case'], ImageFiles)
25 for i:= 0 to |ImageFiles|-1 by 1       
26     read_image(Image,ImageFiles[i])  
27     
28     *挖出條碼區域，提高解位元速率和解碼速度
29     gen_rectangle1 (Rectangle, 50, 100, 560, 700)  
30     reduce_domain (Image, Rectangle, ImageReduced)
31     crop_domain (ImageReduced, ImagePart)
32     
33     *增強影象對比度（後文有該函式說明）
34     enhanced_contrast (ImagePart, Image2, 40, 180)
35    
36     * 碼粒畫素設定
37     set_data_code_2d_param(DataCodeHandleQR, ['module_size_min','module_size_max'], [12,40])
38     
39     *如果GenParamNames, GenParamValues不填，那麼預設只找一個二維碼，將'stop_after_result_num'設定為3指最多找3個
40 *     find_data_code_2d (Image2, SymbolXLDs, DataCodeHandleQR, [], [], ResultHandles, DecodedDataStrings)
41     find_data_code_2d (Image2, SymbolXLDs, DataCodeHandleQR, 'stop_after_result_num', 3, ResultHandles, DecodedDataStrings)
42 
43     tuple_length (DecodedDataStrings, Length)
44     
45     *找不到的話，改一下引數再找一遍
46     if (Length == 0)
47         set_data_code_2d_param (DataCodeHandleQR, ['module_size_min','module_size_max'], [20,40])
48         find_data_code_2d (Image2, SymbolXLDs, DataCodeHandleQR, [], [], ResultHandles, DecodedDataStrings)
49     endif
50     
51     tuple_length (DecodedDataStrings, Length)
52     if (Length > 0 )
53         count := count + 1
54     endif
55     
56     *這個運算元好像並不能評價質量
57     get_data_code_2d_results (DataCodeHandleQR, 'all_candidates', 'quality_isoiec15415_labels', ResultValues)
58     get_data_code_2d_param (DataCodeHandleQR, 'polarity', GenParamValues)
59     dev_display(SymbolXLDs)
60     disp_message (3600, '解碼結果：' + DecodedDataStrings, 'image', 20, 50, 'black', 'true')
61     disp_message (3600, '解碼成功率：' + count + '/' +|ImageFiles| , 'image', 40, 50, 'black', 'true')
62 *      stop ()
63 endfor

函式enhanced_contrast (ImagePart, Image2, 40, 180)的具體實現是：

Mult := 255.0 / (Max - Min)
Add := -Mult * Min
scale_image (Image, Image2, Mult, Add)
return ()

執行結果：

參考資料：

1、halcon例程學習筆記（11） 一維碼、二維碼識別

2、淺談Halcon二維碼識別技巧