一、 CMD檔案基本概念及語法
CMD的專業名稱叫連結器配置檔案，是存放連結器的配置資訊的，我們簡稱為命令檔案。從其名稱可以看出，該檔案的作用是指明如何連結程式的。
那麼我們知道，在編寫TI DSP程式時，是可以將程式分為很多段，比如text、bss等，各段的作用均不相同。實際在片中執行時，所處的位置也不相同。比如text程式碼一般應該放在flash內，而bss的變數應該放在ram內。等等。但是對於不同的晶片，其各儲存器的起止地址都是不一樣的，而且，使用者希望將某一段，尤其是自定義段，放在什麼儲存器的什麼位置，這也是連結器不知道的。為了告訴連結器，即將使用的晶片其內部儲存空間的分配和程式各段的具體存放位置，這就需要編寫一個配置檔案，即CMD檔案了。
所以，CMD檔案裡面最重要的就是兩段，即由MEMORY和SECTIONS兩個偽指令指定的兩段配置。簡單的說，MEMORY就是用來建立目標儲存器的模型，而SECTIONS指令就是根據這個模型來安排各個段的位置。
MEMORY 偽指令

#pragma DATA_SECTION(全域性變數名,"使用者自定義在資料空間的段名");
#pragma CODE_SECTION(函式名,"使用者自定義在程式空間的段名");

CODE_SECTION用來定義程式碼段
DATA_SECTION用來定義資料段
例如：在c檔案中定義了一個data段my_sect和一個code段ramfuncs，如下：

#pragma DATA_SECTION(bufferB, ”my_sect”)
char bufferB[512];
#pragma CODE_SECTION(dragon_update,"ramfuncs");
Uint16 dragon_update(UPDATE_SOURCE_TYPE *update_flag)
{
    。。。
}

然後再在cmd檔案中指定這兩個section的位置就可以了。
如果想在彙編中指定段,使用方法,在程式碼前用.sect “XXX”開始則標示接下來的一段程式碼都是在xxx的程式碼段中。
例子：

PieVectTableFile : > PIE_VECT,   PAGE = 1            // nonBIOS. cmd
#pragma DATA_SECTION(PieVectTable,"PieVectTableFile");   // globalVariableDefs.c
struct PIE_VECT_TABLE PieVectTable;                     // globalVariableDefs.c

注意：
不能再函式體內宣告#pragma；
必須在符號被定義和使用之前宣告#pragma

#pragma 可以阻止對未呼叫的函式的優化

備註：
CMD 檔案中還可以寫上註釋，用“/”和“/”包圍起來，但不允許用“//” ，這一點和 C 語言不同。
可以直接在CMD檔案中寫編譯命令，如：
-l rts2800_ml.lib 連線系統檔案rts2800_ml.lib
-o filename.out 最終生成的二進位制檔案命名為filename.out
-m filename.map 生成對映檔案filename.map
二、DSP 28035的記憶體對映圖如下：


三、 燒寫FLASH的CMD檔案示例及註解（F28035.cmd）

//###########################################################################
// 檔案:  F28035.cmd
// 說明:  F28035連線命令檔案
//###########################################################################
/* 
定義F28035記憶體塊的起始地址及長度
PAGE 0 為程式碼段
PAGE 1 為資料段
注意:
F2803x的記憶體塊對於PAGE 0和PAGE 1是共用的。
同一個記憶體塊不能同時定義為PAGE 0和PAGE 1。會造成程式的混亂。
L0記憶體塊是被映象的：可以在高地址記憶體或都低地址記憶體被訪問。
在這裡只使用低地址記憶體。當需要一片很大的的記憶體塊時，SARAM記憶體塊
或者FLASH段可以連線在一起。
*/
MEMORY
{
PAGE 0:    /* 程式記憶體塊 */
   RAML0       : origin = 0x008000, length = 0x000800     /* 片上 RAM block L0 */
   RAML1       : origin = 0x008800, length = 0x000400     /* 片上 RAM block L1 */
   OTP         : origin = 0x3D7800, length = 0x000400     /* 片上 OTP */
   FLASHH      : origin = 0x3E8000, length = 0x002000     /* 片上 FLASH */
   FLASHG      : origin = 0x3EA000, length = 0x002000     /* 片上 FLASH */
   FLASHF      : origin = 0x3EC000, length = 0x002000     /* 片上 FLASH */
   FLASHE      : origin = 0x3EE000, length = 0x002000     /* 片上 FLASH */
   FLASHD      : origin = 0x3F0000, length = 0x002000     /* 片上 FLASH */
   FLASHC      : origin = 0x3F2000, length = 0x002000     /* 片上 FLASH */
   FLASHA      : origin = 0x3F6000, length = 0x001F80     /* 片上 FLASH */
   CSM_RSVD    : origin = 0x3F7F80, length = 0x000076     
   /* FLASHA的一部分.  Program with all 0x0000 when CSM is in use. */
   BEGIN       : origin = 0x3F7FF6, length = 0x000002
   /* FLASHA的一部分.  使用了啟動引導FLASH模式 */
   CSM_PWL_P0  : origin = 0x3F7FF8, length = 0x000008     
   /* FLASHA的一部分.  CSM password locations in FLASHA */
/*
說明
CSM_RSVD是Code Security Module_reserved的意思，
是指當使用程式碼 安全模組時，origin = 0x3F7F80, length = 0x000076
這個記憶體塊是受保留的reserved。不能放程式程式碼或者資料塊。且必須初始化為0x0000.
CSM_PWL是password locations的意思，即存放密碼的地方
BEGIN是程式啟動的開始地址。
*/
   IQTABLES    : origin = 0x3FE000, length = 0x000B50     /* 在引導ROM中的IQ數學表  */
   IQTABLES2   : origin = 0x3FEB50, length = 0x00008C     /* 在引導ROM中的IQ數學表  */
   IQTABLES3   : origin = 0x3FEBDC, length = 0x0000AA     /* 在引導ROM中的IQ數學表  */

   ROM         : origin = 0x3FF27C, length = 0x000D44     /* 啟動引導 ROM */
   RESET       : origin = 0x3FFFC0, length = 0x000002     
   /* 啟動引導 ROM的一部分 復位地址BROM向量  */
   VECTORS     : origin = 0x3FFFC2, length = 0x00003E
   /* 啟動引導 ROM的一部分  BROM向量*/

PAGE 1 :   /* 資料記憶體塊 */
   BOOT_RSVD   : origin = 0x000000, length = 0x000050 
       /* M0的一部分, 預留給啟動引導 ROM時的棧空間 */
   RAMM0       : origin = 0x000050, length = 0x0003B0     /* 片上 RAM  M0 */
   RAMM1       : origin = 0x000400, length = 0x000400     /* 片上 RAM M1 */
   RAML2       : origin = 0x008C00, length = 0x000400     /* 片上 RAM L2 */
   RAML3       : origin = 0x009000, length = 0x001000     /* 片上 RAM L3 */
   FLASHB      : origin = 0x3F4000, length = 0x002000     /* 片上 FLASH */
}
/* 
將各個段分配到記憶體塊.
注意:  codestart段在 DSP28_CodeStartBranch.asm中被定義，用於引導FLASH時，重定向程式碼。
ramfuncs段內的函式會從FLASH被轉移到RAM中執行。
*/
SECTIONS
{
   .cinit    : > FLASHA   PAGE = 0  /* 初始化的全域性變數和static變量表*/
   .pinit    : > FLASHA   PAGE = 0  /* 全域性物件的建構函式表  C++範疇*/
   .text     : > FLASHA   PAGE = 0  /* 可執行程式碼和常數段 */
   codestart : > BEGIN    PAGE = 0  /* 程式碼啟動段 */
   ramfuncs  : LOAD = FLASHD, /* 將定義到段ramfuncs上的程式碼，載入到FLASHD */
       RUN = RAML0,  /* 定義到ramfuncs上的程式碼，複製到RAML0上執行 */
       LOAD_START(_RamfuncsLoadStart), /* 所要載入程式在Flash裡的初始地址 */
       LOAD_END(_RamfuncsLoadEnd), /* 所要載入程式在Flash裡的結束地址 */
       RUN_START(_RamfuncsRunStart),     /* 程式執行的起始地址 */
       PAGE = 0
   csmpasswds: > CSM_PWL_P0  PAGE = 0    /* 密碼段 */
   csm_rsvd  : > CSM_RSVD    PAGE = 0/* 使用程式碼安全模組時，需要預留的段  */

   /* 未初始化資料段: */
   .stack    : > RAMM0       PAGE = 1    /* 棧空間*/
   .ebss     : > RAML2 | RAML3  PAGE = 1
   /* 長呼叫的全域性或static變數,初始化和未初始化變數*/
   .esysmem  : > RAML2 | RAML3  PAGE = 1

   /* 已初始化的段 */
   .econst   : > FLASHA      PAGE = 0   
   /* 字串常量和far const定義的全域性和靜態變數（static const）*/
   .switch   : > FLASHA      PAGE = 0
   /* 存放switch語句產生的常數表格*/
   /* 分配 IQ 數學表區域  : */
   IQmath    : > FLASHA      PAGE = 0            /* Math Code */
   IQmathTables   : > IQTABLES,   PAGE = 0, TYPE = NOLOAD  /* 不載入*/
/*
.reset是由編譯器使用的。它包含了C程式碼的開始地址_c_int00。
使用啟動引導ROM的這部分和CPU向量表是不需要的。預設的型別被設定為dsect
*/
   .reset    : > RESET,      PAGE = 0, TYPE = DSECT 
   /* DSECT 說明這一塊地址並不會真的載入資料，只是連結一下symbol。*/
   vectors   : > VECTORS     PAGE = 0, TYPE = DSECT
}
/*說明
編譯器生成的包含程式碼和資料的多個部分，稱為段。這個段被分為兩個不同的組：初始化了的和沒被初始化的。
初始化的部分是由所有的程式碼，常量和初始化表組成的。下面列出了由編譯器產生的初始化段。
                            初始化段
段名      內容                                           限制
.cinit  初始化的全域性變數和static變量表                     程式碼
.const  初始化的全域性const變數和static const變數和字串常量 不超過64K長度
.econst 長呼叫的常量                                      資料中的任何地方
.pinit  全域性物件的建構函式表                               程式碼
.switch switch語句產生的表                                程式碼或者資料
.text   可執行程式碼和常數                                  程式碼
沒初始化的段是由未初始化的變數，堆疊和malloc產生的記憶體。下表列出了由編譯器產生的沒初始化段。
                            沒初始化段
段名          內容                      限制
.bss        全域性變數和static變數         不超過64K長度
.ebss       長呼叫的全域性變數和static變數   資料中的任何地方
.stack      棧空間                      不超過64K長度
.sysmem     malloc函式產生的記憶體         不超過64K長度
.esysmem    far_malloc函式產生的記憶體      資料中的任何地方

已初始化的段：.text,.cinit,.const,.econst,.pinit和.switch..
.text：所有可以執行的程式碼和常量
.cinit:全域性變數和static變數的C初始化記錄，
包含未用const宣告的外部（extern）或靜態（static）資料表
.const：包含字串常量和const定義的全域性和static變數
.econst：包含字串常量和初始化的全域性變數和static變數（由far const）
的初始化和說明，與.const不同的是.const分配範圍被限制在低64K 
16位資料區，而.econst的分配範圍是4M 22位資料區
.pinit：全域性構造器（C++）程式列表,注意是全域性的構造器。
.switch：包含大switch段宣告的列表。Jump tables for large switch statements。
非初始化的段：.bss,.ebss,.stack,.sysmem,和esysmem.
.bss: 為全域性變數和區域性變數保留的空間，在程式上電時.cinit空間中的資料複製出來並存儲在.bss空間中。
.ebss：為使用大暫存器模式時的全域性變數和靜態變數預留的空間，在程式上電時，
cinit空間中的資料複製出來並存儲在.ebss中，與.ebss不同的是.bss分配範圍被限制在低64K 16位資料區，
而.ebss的分配範圍是4M 22位資料區
.stack:為系統堆疊保留的空間，用於和函式傳遞變數或為區域性變數分配空間。
.sysmem:為動態儲存分配保留的空間。如果有巨集函式，此空間被巨集函式佔用，如果沒有的話，此空間保留為0
.esysmem:為動態儲存分配保留的空間。如果有far函式，此空間被相應的佔用，如果沒有的化，此空間保留為0.
ramfuncs: LOAD = FLASHD,表示ramfuncs段的裝載在PAGA0的FLASHD中。
RUN = RAML0,表示ramfuncs段的執行地址在PAGE0的RAML0中
LOAD_START(_RamfuncsLoadStart),
令編譯器建立了一個變數RamfuncsLoadStart，該變數指向段
ramfuncs的裝載地址的首地址。 
LOAD_END(_RamfuncsLoadEnd),
令編譯器建立了一個變數RamfuncsLoadEnd，該變數指向段ramfuncs的裝載地址的末地址。
RUN_START(_RamfuncsRunStart),
令編譯器建立了一個變數RamfuncsRunStart，該變數指向段ramfuncs的執行地址的首地址。
解釋一下什麼叫長呼叫，指的是程式指令的尋指範圍。
上面說了絕對呼叫的尋指範圍是16位資料區，長呼叫的尋指範圍是22位資料區 。
*/