4、靜態import

我是最早在.net framework 3.5上使用類似import static這種語法的，用起來相當方便的說，但JDK一直沒有引入這玩意兒，按道理說加上這麼個小功能是很容易實現的。不過Groovy倒是帶來來功能更強大的import static語法，用起來也很方便：

package plswg.edu.groovy.basic


// 將Integer類的MAX_VALUE靜態成員變數引入
import static Integer.MAX_VALUE

// 將Double類的parseDoubl靜態成員方法引入
import static Double.parseDouble

// 給靜態引入賦予別名
import static Boolean.TRUE  as T		// 將Boolean.TRUE取名為T
import static Boolean.FALSE as F		// 將Boolean.FALSE取名為F

// 給靜態引入的方法賦予別名
import static Calendar.getInstance as now


// 程式碼中凡是用到MAX_VALUE, 指的都是Integer.MAX_VALUE
println MAX_VALUE


// 程式碼中凡是用到parseDouble, 指的都是Double.parseDouble
s = "123.123"
println parseDouble(s);	


// 程式碼中凡是使用T的地方表示true，使用F的地方表示false
println T
println !T
println F


// 程式碼中凡是使用now的地方表示Calendar.getInstance
println now().get(Calendar.HOUR)
 

      這玩意兒的主要作用就是避免重複書寫哪些又臭又長的類名，隨著JDK類庫的不斷增加，類名字是越來越長，像造句一樣，import static恰好解決了這一問題，還是很貼心的。

5、分支結構語句

Groovy的結構化語句仍舊是三種：順序結構、分支結構和迴圈結構，其中分支結構和迴圈結構增加了很多意想不到的功能，先看分支結構：

package plswg.edu.groovy.basic

// groovy中if條件分支的新規定

// groovy中，非0的數值可以表示true
int num = 0
if (num) {
	println "True"
} else {
	println "False"
}

println (++num ? "True" : "False")

if (!!num) {		// !!運算子可以將num轉化為boolean型別
	println "num=${num}為${!!num}"
}
println ""


// 引用為null時，表示false
Object o = null
if (o) {
	println "True"
} else {
	println "False"
}
o = new Date()
if (o) {
	println "True"
} else {
	println "False"
}
println ""


// 字串為""時，表示false
String s = ""
if (s) {
	println "True"
} else {
	println "False"
}
s += "hello"
if (s) {
	println "True"
} else {
	println "False"
}
println ""


// 集合為空時，表示False
ArrayList array = new ArrayList()
if (array) {
	println "True"
} else {
	println "False"
}
array.add(100)
if (array) {
	println "True"
} else {
	println "False"
}
println ""


// groovy中switch選擇分支的新規定

// switch對字串型別的支援

print "Please input your words: "
s = new BufferedReader(new InputStreamReader(System.in)).readLine()

switch (s) {
case "how are you":
	println "fine, thank you"
	break;
case "how do you do":
	println "how do you do too"
	break;
default:
	println "nice to meet you"
}


// switch對集合和範圍的支援
n = new Random().nextInt(101)
print "you got ${n} point, "
switch (n) {
case [98, 99, 100]:		// n為98, 99, 100這三個數字時
	println "very good!!"
	break;
case 90 .. 97:			// n為90-97之間時
	println "nice job!!"
	break;
case 70 .. 89:			// n為70-89之間時
	println "good"
	break;
case 60 .. 79:			// n為60-79之間時
	println "can be better"
	break;
case {it > 0 && it < 60}:	// n比0大且比60小時
	println "too bad"
	break;
case 0:					// n為0時
	println "nothing to say"
	break;
}
 

       首先，Groovy對boolean型別放寬了限制：

• 常量true和false分別表示“真”和“假”；
• null表示false，非null表示true；
• 空字串""表示false，非空字串表示true；
• 0表示false，非0表示true；
• 空集合表示false，非空集合表示true；

      好了，從這一角度上，Groovy確實和Javascript或者PHP非常相似了，用起來非常方便。

      Groovy中對於switch語句的修改也是非常誇張的，這讓我甚至有些懷疑Groovy中的switch是否還能達到O1的執行效率，因為Groovy的swtich表現的太像巢狀的if...else if了，在例子中，switch的case後面可以跟隨如下幾種玩意兒：

• 常量，在Groovy中，case後的常量包括數值型常量或字串型別常量，方便很多了，JDK7中新增加了使用字串常量的case語句，而在.net framework 1.1中早就有了，諸如Basic，PHP，Python，Javascript等指令碼，更是一開始就支援字串常量的case語句；
• Range：即範圍，語法 n1 .. n2 表示n1和n2之間的所有數值n（n1 <= n <= n2）；
• Collection：集合，語法 [a1, a2, a3, ... , an]，表示由中括號中的n個元素構成的集合，其中各個元素型別不必統一；
• 閉包：由 { 語句 } 構成的匿名函式體，這個後面會重點講述，這裡只要知道，一旦case之後的閉包返回true，則冒號之後的程式碼將會執行；

      總之Groovy對分支語句的改造，讓其更符合主流動態語言的特點，目前大家都在玩動態語言，就算強型別語言例如C#也在向動態語言方向靠攏，C++有泛型可以一直淡定，Java也有泛型，但那就不是個玩意兒。Groovy這下改的徹底，該有的全都有了！