@echo off
:ks
cls
color 1f
title 批量（隨機）按順序重新命名 
setlocal enabledelayedexpansion
set "n=1000"
echo ==============================================================================
echo 功能：本操作將對當前目錄下的指定型別檔案，批量（隨機）按順序重新命名！
echo ==============================================================================
echo 使用方法：請在下面輸入檔案的副檔名，如：mp3 flv txt 等，根據情況可自定義！
echo ==============================================================================
set /p lx=請輸入檔案型別
if exist *.%lx% (goto zhhb) else echo.
echo ==============================================================================
echo 提示：當前目錄下，沒有找到你輸入的檔案型別:%lx% 操作無法繼續，回車重新輸入！
echo ==============================================================================
pause>nul
goto ks
:zhhb
for /f "delims=" %%a in ('dir/a/b *.%lx%') do call :a "%%a"
for /f "delims=" %%a in ('dir/a/b/on *.%lx%') do set/a "n+=1"&ren "%%a" "!n:~-3!%%~xa"
cls
echo ==============================================================================
echo 恭喜！您指定的操作,已經成功完成。按任意鍵退出...
echo ==============================================================================
pause>nul & exit
:a
ren "%~1" "%random%%~x1" || goto a

＝＝＝＝＝（注意我是分隔符，不要複製我！）下面是 按修改時間 重新命名批理＝＝＝＝＝＝＝＝＝

@echo off
:ks
cls
color 1f
title 按修改時間重新命名並排序
setlocal enabledelayedexpansion
set "n=1000"
echo ==============================================================================
echo 功能：本操作將對當前目錄下的指定型別檔案，按修改時間重新命名並排序！
echo ==============================================================================
echo 使用方法：請在下面輸入檔案的副檔名，如：mp3 flv txt 等，根據情況可自定義！
echo ==============================================================================
set /p lx=請輸入檔案型別
cls
if exist *.%lx% (goto zhhb) else echo.
echo ==============================================================================
echo 提示：當前目錄下，沒有找到你輸入的檔案型別:%lx% 操作無法繼續，回車重新輸入！
echo ==============================================================================
pause>nul
goto ks
:zhhb
for /f "delims=" %%a in ('dir /b /od *.%lx%') do (
set/a n+=1&call ren "%%a" %%n:~-3%%.%lx% )
cls
echo ==============================================================================
echo 恭喜！您指定的操作,已經成功完成。按任意鍵退出...
echo ==============================================================================
pause>nul & exit