環境

OSX
AndroidStudio 1.0

多渠道設置

渠道號

以友盟SDK為例，打包多渠道：GooglePlay，小米，友盟，360，豌豆莢，應用寶。
在AndroidManifest.xml中加入渠道區分標識

<meta-data 
    android:name="UMENG_CHANNEL"
    android:value="${UMENG_CHANNEL_VALUE}" />

然後在build.gradle(Module: app)中加入渠道打包替換對應的UMENG_CHANNEL_VALUE代碼

// 渠道Flavors，配置不同的渠道
    productFlavors {
        GooglePlay {}
        xiaomi {}
        umeng {}
        qihu360 {}
        wandoujia {}
        yingyongbao {}
        //其他...
    }

    // 批量配置渠道
    productFlavors.all {
        flavor -> flavor.manifestPlaceholders = [UMENG_CHANNEL_VALUE: name]
    }
 

apk名字

我們還可以指定不同渠道號生成的apk的名字，這樣方便打包出來區別哪個apk是對應哪個渠道的。以下的例子生成的命名格式 app_v(版本號)_打包時間_渠道號.apk

android{

        applicationVariants.all { variant ->
            variant.outputs.each { output ->
                def outputFile = output.outputFile
                if (outputFile != null && outputFile.name.endsWith(‘.apk‘)) {
                    File outputDirectory = new File(outputFile.parent);
                    def fileName
                    if (variant.buildType.name == "release") {
                        fileName = "app_v${defaultConfig.versionName}_${packageTime()}_${variant.productFlavors[0].name}.apk"
                    } else {
                        fileName = "app_v${defaultConfig.versionName}_${packageTime()}_beta.apk"
                    }
                    output.outputFile = new File(outputDirectory, fileName)
                }
            }
        }

    }
 

打包

簽名文件

生成簽名文件可用命令行生成，也可以直接用AndroidStudio的Build -> Generate signed apk -> create new 生成新證書即可。然後為了方便，這裏我把證書放到 項目 -> app 目錄下。

簽名配置

gradle支持直接簽名打包，只需要設置一下證書的路徑和對應密碼一鍵打包出正式可以發布的apk。
在signingConfigs裏面寫上對應的storeFile，storePassword，keyAlias，keyPassword
一般地，為了保護簽名文件，這些信息不應該寫入到版本庫中，我這裏把它們寫在local.properties

//這裏是讀取local.properties文件，提供給下方代碼用來提取keystroe_storeFile等key的值
Properties properties = new Properties()
properties.load(project.rootProject.file(‘local.properties‘).newDataInputStream())

signingConfigs {

        release {
            // relase簽名
            storeFile file(properties.getProperty("keystroe_storeFile"))
            storePassword properties.getProperty("keystroe_storePassword")
            keyAlias properties.getProperty("keystroe_keyAlias")
            keyPassword properties.getProperty("keystroe_keyPassword")
        }
    }

在local.properties文件中加入

keystroe_storeFile=keystore.jks  //對應自己實際的證書路徑和名字，因為我上面提到 把證書放在 項目的app目錄下，所以不用寫絕對路徑。
keystroe_storePassword=123456
keystroe_keyAlias=alias
keystroe_keyPassword=123456

打包apk

在終端窗口，或者可以使用AndroidStudio工具欄下面提供的終端 Terminal ，cd 到 項目根目錄下執行:

// 打包出上面所有渠道apk
./gradlew build
// 下面這行例子是單獨打包wandoujia渠道的apk
// ./gradlew assembleWandoujia

對應渠道的apk就會自動在 項目/app/build/outputs/apk/ 目錄下按照上面指定的命名格式生成了。

產品定制

ApplicationId，版本號

Android 應用都有自己的包名。包名是設備上每個應用程序的唯一標識，同樣也是在各個下載平臺的唯一標識。就是說，假如你已經使用某個包名來發布應用，就不能再去改變應用的包名，因為這樣做會導致你的應用被視為一個全新的應用，你現有的用戶也不會收到應用的更新通知。
有時候我們需要發布不同的版本，例如 pro，hd 版本，支持用戶可以下載安裝不同的版本。那麽我們需要設置不同的ApplicationId和對應的版本號， 同時要與 PackageName 解耦合。

• 代碼中引用的 R 類要保持不變；

• 在構建不同版本的應用時，對應的（引用了 R 的） .java 源文件也不能改動。

那麽我們只需要在productFlavors對應的渠道中指定applicationId和versionCode，versionName，例我們指定GooglePlay的applicationId：

productFlavors {
        GooglePlay {
            //指定這個渠道的版本號
            versionCode 2
            versionName "2.0"
            //指定區別於其他渠道的 applicationId
            applicationId "com.bigkoo.gradledemo.hd"
        }
        xiaomi {}
        umeng {}
        qihu360 {}
        wandoujia {}
        yingyongbao {}
        //其他...
    }

BuildConfig

Gradle會在generateSources階段為flavor生成一個BuildConfig.java文件。BuildConfig類默認提供了一些常量字段，比如應用的版本名（VERSION_NAME），應用的包名（PACKAGE_NAME）等。更強大的是，開發者還可以添加自定義的一些字段。下面的示例假設debug版開啟LOG功能，使用test的api，而發布版則使用不開啟LOG和使用發布時的api：

buildTypes {
        debug {
            // debug模式下，顯示log
            buildConfigField("boolean", "LOG_DEBUG", "true")
            buildConfigField ("String", "API_HOST", "\"http://api.test.com\"")//API Host
        }
        release {
            // release模式下，不顯示log
            buildConfigField("boolean", "LOG_DEBUG", "false")
            buildConfigField("String", "API_HOST", "\"http://api.release.com\"")//API Host
        }
    }

那麽代碼中就可以使用 BuildConfig.LOG_DEBUG 和 BuildConfig.API_HOST 了。
甚至可以在productFlavors對應的渠道號進行區別，例如豌豆莢版默認禁止版本自動更新：

android {
    defaultConfig {
        buildConfigField "boolean", "AUTO_UPDATES", "true"
    }

    productFlavors {
        wandoujia {
            buildConfigField "boolean", "AUTO_UPDATES", "false"
        }        
    }

}

資源

通常對於不同渠道，我們會區別不同的資源。例如我們一款應用需要在360發布，而應用圖標和歡迎界面要一個360標誌的圖，那麽這個時候就需要按渠道打包對應的應用圖標和歡迎圖片了。Gradle在構建應用時，會優先使用flavor所屬dataSet中的同名資源。所以，在flavor的dataSet中添加同名的字符串資源，以覆蓋默認的資源。
上面我們已經有針對360的渠道了，就是qihu360，我們只需要在 app/src/ 目錄下添加渠道對應的文件夾qihu360，然後覆蓋對應要覆蓋的內容。下面是定制應用圖標的步驟：

• 添加qihu360文件夾，那麽在 app/src/ 目錄下面就有 main , androidTest , qihu360 這三個文件夾了。main 目錄是通用正常渠道包目錄，qihu360是我們需要定制資源的渠道包目錄。

• 仿main的目錄，添加 res/drawable/ic_launcher.png 圖片以覆蓋對應在 main裏面的res/drawable/ic_launcher.png

通過以上例子，舉一反三。定制其他資源，包括strings.xml ， styles.xml 甚至AndroidManifest.xml 也都是可以的。

第三方庫

有些渠道需要加入廣告，應用墻推薦，而有些則不上廣告，我們常常也會遇到這樣的問題吧。那麽現在來說說怎麽對於第三方庫進行渠道區分打包。
這裏以我的開源項目 為例，其他庫或廣告SDK同理：

dependencies {
    compile fileTree(dir: ‘libs‘, include: [‘*.jar‘])
    compile ‘com.android.support:appcompat-v7:21.0.3‘
    //參與編譯but不參與打包
    provided ‘com.bigkoo:alertview:1.0.1‘
    //指定qihu360這個渠道可以打包這個庫
    qihu360Compile ‘com.bigkoo:alertview:1.0.1‘
}

然後在代碼中進行反射判斷是否有這個庫存在，如果有就使用，沒有就不使用。（或者用上面提及的BuildConfig方式設置一個渠道常量來判斷也可以）

public class MainActivity extends Activity {

    private boolean useAlertView;
    @Override
    protected void onCreate(Bundle savedInstanceState) {
        super.onCreate(savedInstanceState);
        setContentView(R.layout.activity_main);

        try {
            Class.forName("com.bigkoo.alertview.AlertView");
            useAlertView = true;
        } catch (ClassNotFoundException ignored) {

        }
    }

    public void showAlertView(View view) {
        if(useAlertView) {
            new AlertView("標題", "內容", null, new String[]{"確定"}, null, this, AlertView.Style.Alert, null).show();
        }
    }
}

總結

常用的多渠道打包方式已經介紹完了，基本能滿足日常大部分多渠道打包開發使用。如果你想更深入了解，請看Groovy，自己來定制一些任務。

本文參考

Gradle
美團Android自動化之旅—適配渠道包
安卓集成發布詳解（二）

源碼

本文例子的源碼放在我的Github上了，地址：GradleDemo (PS:例子為了提供完整的演示，沒有在.gitigonore裏面加入 /local.properties 排除，實際是要加入的，另外簽名文件也一並附上了，也實際是需要排除的。)

多渠道打包