2. 程式人生 > >unity官方API的Surface Shader examples一些shader的例子

unity官方API的Surface Shader examples一些shader的例子

阿新 • • 發佈：2018-12-06

下面是一些表面材質的例子

在術語表。下面的例子著重於使用內建的照明模型;關於如何實現自定義照明模型的例子在表面陰影照明的例子。

 

簡單的

我們將從一個非常簡單的著色器開始並使用在他上邊,這裡有一個著色器將表面顏色設定為“白色”.它使用的是內建的Lambert (漫反射)光照模型

 Shader "Example/Diffuse Simple" {
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float4 color : COLOR;
      };
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = 1;
      }
      ENDCG
    }
    Fallback "Diffuse"
  }

這是一個有兩個燈的模型:

紋理

一個純白色的物體是相當無聊的，所以讓我們新增一個紋理。我們將新增一個屬性塊到材質，所以我們在材質中有一個材質選擇器。其他更改在下面粗體顯示。

 Shader "Example/Diffuse Texture" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
      };
      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

法線貼圖

讓我們新增一些法線對映:

 Shader "Example/Diffuse Bump" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
        float2 uv_MainTex;
        float2 uv_BumpMap;
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      void surf (Input IN, inout SurfaceOutput o) {
        o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
        o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

邊緣高光

現在，嘗試新增一些邊緣高光來突出遊戲物件的邊緣。我們將根據表面法線和檢視方向的夾角新增一些發射光。為此，我們將使用內建的viewDir表面著色器變數。

Shader "Example/Rim" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
      _RimColor ("Rim Color", Color) = (0.26,0.19,0.16,0.0)
      _RimPower ("Rim Power", Range(0.5,8.0)) = 3.0
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float2 uv_BumpMap;
          float3 viewDir;
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      float4 _RimColor;
      float _RimPower;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
          half rim = 1.0 - saturate(dot (normalize(IN.viewDir), o.Normal));
          o.Emission = _RimColor.rgb * pow (rim, _RimPower);
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

詳細的結構

對於不同的效果，讓我們新增一個細節紋理與基本紋理相結合。細節紋理通常使用相同的UVs，但不同的貼圖在材料中，所以我們需要使用不同的輸入UV座標。

Shader "Example/Detail" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
      _Detail ("Detail", 2D) = "gray" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float2 uv_BumpMap;
          float2 uv_Detail;
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      sampler2D _Detail;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          o.Albedo *= tex2D (_Detail, IN.uv_Detail).rgb * 2;
          o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

使用紋理檢查器並不總是很實用，但是在這個例子中，它被用來說明發生了什麼:

細節紋理在螢幕空間

在螢幕空間中，一個細節紋理對於士兵頭部模型沒有實際意義，但在這裡，它用來說明如何使用內建的螢幕pos輸入:

 Shader "Example/ScreenPos" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _Detail ("Detail", 2D) = "gray" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float4 screenPos;
      };
      sampler2D _MainTex;
      sampler2D _Detail;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          float2 screenUV = IN.screenPos.xy / IN.screenPos.w;
          screenUV *= float2(8,6);
          o.Albedo *= tex2D (_Detail, screenUV).rgb * 2;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

法線貼圖已經從上面的陰影中移除，只是為了使它更短:

Cubemap反射

這裡有一個著色器，使用內建的worldRefl輸入做立方體反射。它與內建的反射/擴散著色器非常相似:

 Shader "Example/WorldRefl" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _Cube ("Cubemap", CUBE) = "" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float3 worldRefl;
      };
      sampler2D _MainTex;
      samplerCUBE _Cube;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb * 0.5;
          o.Emission = texCUBE (_Cube, IN.worldRefl).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

因為它把反射的顏色指定為發射，我們得到了一個讓人閃瞎眼的士兵:

如果您希望進行受法線貼圖影響的反射，則需要稍微複雜一點:需要將INTERNAL_DATA新增到輸入結構中，並在編寫了法線輸出後使用WorldReflectionVector函式計算每個畫素的反射向量。

Shader "Example/WorldRefl Normalmap" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
      _Cube ("Cubemap", CUBE) = "" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float2 uv_BumpMap;
          float3 worldRefl;
          INTERNAL_DATA
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      samplerCUBE _Cube;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb * 0.5;
          o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
          o.Emission = texCUBE (_Cube, WorldReflectionVector (IN, o.Normal)).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

這是一個普通的士兵:

切片通過世界空間位置

這裡有一個著色器，通過丟棄畫素來“分割”遊戲物件。
近水平環。它通過使用clip() Cg/HLSL函式基於畫素的世界位置來實現這一點。我們將使用內建的worldPos表面著色器變數。

Shader "Example/Slices" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      Cull Off
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float2 uv_BumpMap;
          float3 worldPos;
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      void surf (Input IN, inout SurfaceOutput o) {
          clip (frac((IN.worldPos.y+IN.worldPos.z*0.1) * 5) - 0.5);
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

這是一個被切條的士兵

帶有頂點修改器的正常擠壓

可以使用“頂點修飾符”函式來修改頂點著色器中輸入的頂點資料。這可以用於程式化動畫和沿著法線擠壓。表面著色器編譯指令頂點:functionName用於此，函式接受inout appdata_full引數。
這裡有一個著色器，按材質中指定的數量沿其法線移動頂點:

Shader "Example/Normal Extrusion" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _Amount ("Extrusion Amount", Range(-1,1)) = 0.5
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert vertex:vert
      struct Input {
          float2 uv_MainTex;
      };
      float _Amount;
      void vert (inout appdata_full v) {
          v.vertex.xyz += v.normal * _Amount;
      }
      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

沿著它們的法線移動頂點會得到一個胖胖噠士兵:

自定義資料計算種每個頂點都具備的

使用頂點修飾符函式，還可以在頂點著色器中計算自定義資料，然後將其傳遞給每個畫素的表面著色器函式。使用相同的編譯指令頂點:functionName，但是函式應該包含兩個引數:inout appdata_full和out Input。您可以在其中填充任何非內建值的輸入成員。
注意:使用這種方式的自定義輸入成員不能以“uv”開頭，否則不能正常工作。
下面的示例定義了一個自定義的float3 customColor成員，該成員在頂點函式中計算:

Shader "Example/Custom Vertex Data" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert vertex:vert
      struct Input {
          float2 uv_MainTex;
          float3 customColor;
      };
      void vert (inout appdata_full v, out Input o) {
          UNITY_INITIALIZE_OUTPUT(Input,o);
          o.customColor = abs(v.normal);
      }
      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          o.Albedo *= IN.customColor;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

在本例中，customColor被設定為normal的絕對值:

更實際的用途可能是計算內建輸入變數不提供的每個頂點的資料;或優化材質計算。例如，可以在GameObject的頂點處計算Rim照明，而不是在每個畫素的表面著色器中。

最終顏色修改器

可以使用“最終顏色修改器”函式來修改由著色器計算的最終顏色。表面著色器編譯指令finalcolor:functionName用於此，函式接受輸入，SurfaceOutput o, inout fixed4顏色引數。這裡有一個簡單的著色器，適用於最後的顏色。這與只對表面反照色進行著色是不同的:這種著色也會影響來自Lightmaps的任何顏色、光探測器和類似的額外的來源。

Shader "Example/Tint Final Color" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _ColorTint ("Tint", Color) = (1.0, 0.6, 0.6, 1.0)
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert finalcolor:mycolor
      struct Input {
          float2 uv_MainTex;
      };
      fixed4 _ColorTint;
      void mycolor (Input IN, SurfaceOutput o, inout fixed4 color)
      {
          color *= _ColorTint;
      }
      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
           o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

自定義霧與最後的顏色修改

使用最終顏色修飾符(見上面)的一個常見情況是在正向渲染中實現完全自定義的Fog。霧需要影響最終計算的畫素著色器顏色，這正是最終顏色修飾器所做的。這是一個基於距離螢幕中心的距離的著色器。這將頂點修飾符與自定義頂點資料(fog)以及最終的顏色修飾符組合在一起。當用於正向渲染時。新增劑通過後，霧需要逐漸變黑。這個示例處理這個問題，並對UNITY_PASS_FORWARDADD進行檢查。

Shader "Example/Fog via Final Color" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _FogColor ("Fog Color", Color) = (0.3, 0.4, 0.7, 1.0)
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert finalcolor:mycolor vertex:myvert
      struct Input {
          float2 uv_MainTex;
          half fog;
      };
      void myvert (inout appdata_full v, out Input data)
      {
          UNITY_INITIALIZE_OUTPUT(Input,data);
          float4 hpos = UnityObjectToClipPos(v.vertex);
          hpos.xy/=hpos.w;
          data.fog = min (1, dot (hpos.xy, hpos.xy)*0.5);
      }
      fixed4 _FogColor;
      void mycolor (Input IN, SurfaceOutput o, inout fixed4 color)
      {
          fixed3 fogColor = _FogColor.rgb;
          #ifdef UNITY_PASS_FORWARDADD
          fogColor = 0;
          #endif
          color.rgb = lerp (color.rgb, fogColor, IN.fog);
      }
      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
           o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

線性霧

Shader "Example/Linear Fog" {
  Properties {
    _MainTex ("Base (RGB)", 2D) = "white" {}
  }
  SubShader {
    Tags { "RenderType"="Opaque" }
    LOD 200
    
    CGPROGRAM
    #pragma surface surf Lambert finalcolor:mycolor vertex:myvert
    #pragma multi_compile_fog

    sampler2D _MainTex;
    uniform half4 unity_FogStart;
    uniform half4 unity_FogEnd;

    struct Input {
      float2 uv_MainTex;
      half fog;
    };

    void myvert (inout appdata_full v, out Input data) {
      UNITY_INITIALIZE_OUTPUT(Input,data);
      float pos = length(UnityObjectToViewPos(v.vertex).xyz);
      float diff = unity_FogEnd.x - unity_FogStart.x;
      float invDiff = 1.0f / diff;
      data.fog = clamp ((unity_FogEnd.x - pos) * invDiff, 0.0, 1.0);
    }
    void mycolor (Input IN, SurfaceOutput o, inout fixed4 color) {
      #ifdef UNITY_PASS_FORWARDADD
        UNITY_APPLY_FOG_COLOR(IN.fog, color, float4(0,0,0,0));
      #else
        UNITY_APPLY_FOG_COLOR(IN.fog, color, unity_FogColor);
      #endif
    }

    void surf (Input IN, inout SurfaceOutput o) {
      half4 c = tex2D (_MainTex, IN.uv_MainTex);
      o.Albedo = c.rgb;
      o.Alpha = c.a;
    }
    ENDCG
  } 
  FallBack "Diffuse"
}

貼花

貼花通常用於在執行時向材料新增細節(例如，子彈撞擊)。它們在延遲渲染中特別有用，因為它們在GBuffer被點亮之前進行修改，因此可以節省效能。在典型的場景中，貼花應該在不透明的物件之後呈現，而不應該是陰影投射器，就像在ShaderLab中看到的那樣下面示例中的“標記”。

Shader "Example/Decal" {
  Properties {
    _MainTex ("Base (RGB)", 2D) = "white" {}
  }
  SubShader {
    Tags { "RenderType"="Opaque" "Queue"="Geometry+1" "ForceNoShadowCasting"="True" }
    LOD 200
    Offset -1, -1
    
    CGPROGRAM
    #pragma surface surf Lambert decal:blend
    
    sampler2D _MainTex;
    
    struct Input {
      float2 uv_MainTex;
    };
    
    void surf (Input IN, inout SurfaceOutput o) {
        half4 c = tex2D (_MainTex, IN.uv_MainTex);
        o.Albedo = c.rgb;
        o.Alpha = c.a;
      }
    ENDCG
    }
}

 

 

 

相關推薦

unity官方API的Surface Shader examples一些shader的例子

下面是一些表面材質的例子 在術語表。下面的例子著重於使用內建的照明模型;關於如何實現自定義照明模型的例子在表面陰影照明的例子。   簡單的 我們將從一個非常簡單的著色器開始並使用在他上邊,這裡有一個著色器將表面顏色設定為“白色”.它使用的是內建的Lambert (漫反射)光

Unity3D Shader官方教程翻譯(十八)----Shader語法 另外一些命令（分類）

Category 分類 Category is a logical grouping of any commands below it. This is mostly used to "inherit" rendering state. For example, your shader might hav

Unity Shader 灰度Shader(支持UGUI Mask裁剪)

tag end clu mask tags mode turn com over Unity Shader 灰度Shader(支持UGUI Mask裁剪) shader源碼如下 其中支持mask裁剪部分（註意 有兩處地方需要添加）的代碼同樣適合其他自定義shader Sh

[unity] 5.5.2 Standard Specular shader 真機上程式碼調整半透明無效問題。

專案需要，角色進入草叢要半透明。 已用了 untiy 自帶shader （Standard Specular）的Fade 模式。  用程式碼電腦上除錯沒問題，結果上了真機就無法半透明。 原因是 unity打包時只會打 shader 被引用到的變體。 如果程式碼裡呼叫 Ena

Unity UGUI 圖片矩形圓角+陰影 shader實現

1.新建一個材質球，拖拽給圖片元件 2.在材質球上建一個surface shader，程式碼如下： // Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

【Unity Shader】用shader控制背景的傾斜漸變

07/19更新,修復了之前的問題 07/14更新，這個效果有點不對，因為是按比例取的顏色，所以可以看到右下角明顯偏亮。。。待修改。。。 需要用到一個背景圖是斜著漸變的，且需要不斷地變化背景顏色，所以不適合美術為每一種顏色背景切圖，用shader來控制是最好的

Unity-Shader Sublime 自制shader提示外掛

Unity-Shader 編寫shader,最好還是有一個好的IDE或者編輯器,支援語法高亮和智慧提示的. 最初使用mac ,找了找外掛,沒找到,只能依靠mono的高亮進行編寫,對於習慣了IDE的我來說,太累了. 後來換用windows,找了下vs上的shader外掛,找

【Unity Shaders】學習筆記之Shader簡介(一)

一、Shader簡介  Shader（著色器）實際上就是一小段程式，它負責將輸入的Mesh（網格）以指定的方式和輸入的貼圖或者顏色等組合作用，然後輸出。繪圖單元可以依據這個輸出將影象繪製到螢幕上。輸

解讀Unity中的CG編寫Shader系列2——shader的輸入輸出引數

上一篇文章的例子中我們可以看到頂點著色器的輸出引數可以說是直接作為了片段著色器的形參傳遞過來，那麼不由得一個問題浮現出來，頂點著色器的形參是從何處傳遞過來的？ 頂點著色器的形參是gameObject 的meshRenderer元件將所有的mesh資料按每一幀一次傳遞給Ope

unity修改材質屬性和更換shader

unity通過GetVector，GetColor，GetFloat等獲取。 SetVector,SetColor,SetFloat等設定。 這裡我要修改Transparency_Value的值。

Unity 官方教程 學習

mas variables ber item term media nim als -m Interface & Essentials Using the Unity Interface 1.Interface Overview https://unity3d.co

【小松教你手遊開發】【遊戲渲染】單色shader，紋理shader

無單色shader Shader "ChrisShader/OneColorShader" { Properties { _Color ("color", Color) = (0,0,0,0) } SubShader {

GLSL寫vertex shader和fragment shader

0.一般來說vertex shader處理頂點座標，然後向後傳輸，經過光柵化之後，傳給fragment shader，其負責顏色、紋理、光照等等。 前者處理之後變成裁剪座標系（三維），光柵化之後一般認為變成二維的裝置座標系 1.每個頂點有多個屬性時的頂點著色器： 1 #versi

Unity官方案例教程 —— Space Shooter tutorial

1.Player - PlayerController.cs Clamp Clamps a value between a minimum float and maximum float value. Euler Returns a rotation t

Unity官方案例-Space Shooter學習筆記（1）

本文記錄了筆者在跟著官方視訊製作教程遊戲的過程，僅是個人的學習總結和記錄，不作為任何教材使用。 1、玩家飛船：將Model資料夾中的Player飛船模組拖拽到Hierarchy檢視中，然後首先設定Rigidbody和Collider；Collider選擇M

Unity官方支援中文版啦！！！附教程——無需破解！

Unity安裝官方中文版教程 本文提供全流程，中文翻譯。 Chinar 堅持將簡單的生活方式，帶給世人！（擁有更好的閱讀體驗 —— 高解析度使用者請根據需求調整網頁縮放比例） C

react表單的一些小例子

<!DOCTYPE html> <html lang="en"> <head> <meta charset="UTF-8"> <meta name="viewport" content="

[Unity基礎]對Rotation的一些理解與例項(一)

using UnityEngine; using System.Collections; public class TestRotation : MonoBehaviour{ // Update is called once per frame void Updat

HLSL Effect的vertex shader和pixel shader的引數傳遞 .

HLSL基本以C語言的習慣來寫的，但是如果完全以C語言的角度來看，我個人感覺入門最難理解就是頂點著色器和畫素著色器的兩個函式的引數傳遞了。   下面以最簡單的HLSL中效果框架舉例說下自己的理解。   uniform extern float4x4 gWVP;   str

shader常用函式 shader常用函式

shader常用函式   CG  標準函式庫     和 C 的標準函式庫類似，Cg 提供了一系列內建的標準函式。這些函式用於執行數學上的通用計算或通用演算法（紋理對映等），例如，需要求