新建一個Standard Surface Shader，將其命名為Glass

1、開啟Glass，將其名稱改為"PACKT/Glass"

2、在Subshader下面，找到Tags一行，將Opaque改為Transparent（即從“不透明”改為“透明”）

3、找到著色器的編譯指令程式碼#pragma surface surf Standard fullforwardshadows，並在其後面新增關鍵字alpha，此關鍵字使得著色器支援透明，透明度由著色器的顏色屬性的alpha通道決定

此時的著色器可以使得外表面有高光效果

出於對執行效率的考慮，Unity預設忽略物體的背面，只渲染正面

可以在Subshader程式碼塊中，在LOD一行的下面新增Cull off，此時正面和背面均會被渲染，但因Cull off指令使得正面和背面在同一道繪製呼叫裡被渲染，因此偶爾會出現由於順序錯誤而導致的渲染錯誤。

因此可以通過用兩塊Cg程式碼分兩次渲染正面和背面來提高畫面質量，即多遍渲染

1、首先在Properties程式碼塊中新增_Thickness ("Thickness", Range(-1,1)) = 0.5

     _Thickness 表示厚度，用來控制在其中一遍渲染中，模型被放大或縮小的程度

2、將Cull off改為Cull Back（即剔除背面，只渲染正面）

3、往下找到ENDCG一行，在該行下新增

Cull Front//剔除正面（即只渲染背面）
		CGPROGRAM
		//指令vertex:vert使得我們可以向著色器插入自定義的頂點處理程式碼
		#pragma surface surf Standard fullforwardshadows alpha vertex:vert
		struct Input {
			float2 uv_MainTex;
		};
		float _Thickness;
		//頂點處理程式碼
		//以_Thickness屬性的值為移動距離，將模型的每一個頂點沿著表面的法線移動，從而便可實現模型的縮放
		void vert(inout appdata_full v) {
			v.vertex.xyz += v.normal * _Thickness;
		}

		sampler2D _MainTex;
		half _Glossiness;
		half _Metallic;
		fixed4 _Color;

		void surf(Input IN, inout SurfaceOutputStandard o) {
			fixed4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;
			o.Albedo = c.rgb;
			o.Metallic = _Metallic;
			o.Smoothness = _Glossiness;
			o.Alpha = c.a;
		}
		ENDCG
 

此部分為渲染背面的程式碼

綜上，該shader檔案的完整程式碼如下

Shader "PACKT/Glass" {
	Properties {
		_Color ("Color", Color) = (1,1,1,1)
		_MainTex ("Albedo (RGB)", 2D) = "white" {}
		_Glossiness ("Smoothness", Range(0,1)) = 0.5
		_Metallic ("Metallic", Range(0,1)) = 0.0
		_Thickness ("Thickness", Range(-1,1)) = 0.5//厚度，用來控制在其中一遍渲染中，模型被放大或縮小的程度
	}
	SubShader {
		Tags { "RenderType"="Transparent" }
		LOD 200
		//Cull off//關閉剔除，使得正面和背面在同一道繪製呼叫裡被渲染，可能會導致渲染錯誤
		
		Cull Back//剔除背面（即只渲染正面）		
		CGPROGRAM
		// Physically based Standard lighting model, and enable shadows on all light types
		#pragma surface surf Standard fullforwardshadows alpha

		// Use shader model 3.0 target, to get nicer looking lighting
		#pragma target 3.0

		sampler2D _MainTex;

		struct Input {
			float2 uv_MainTex;
		};

		half _Glossiness;
		half _Metallic;
		fixed4 _Color;

		void surf (Input IN, inout SurfaceOutputStandard o) {
			// Albedo comes from a texture tinted by color
			fixed4 c = tex2D (_MainTex, IN.uv_MainTex) * _Color;
			o.Albedo = c.rgb;
			// Metallic and smoothness come from slider variables
			o.Metallic = _Metallic;
			o.Smoothness = _Glossiness;
			o.Alpha = c.a;
		}
		ENDCG


		Cull Front//剔除正面（即只渲染背面）
		CGPROGRAM
		//指令vertex:vert使得我們可以向著色器插入自定義的頂點處理程式碼
		#pragma surface surf Standard fullforwardshadows alpha vertex:vert
		struct Input {
			float2 uv_MainTex;
		};
		float _Thickness;
		//頂點處理程式碼
		//以_Thickness屬性的值為移動距離，將模型的每一個頂點沿著表面的法線移動，從而便可實現模型的縮放
		void vert(inout appdata_full v) {
			v.vertex.xyz += v.normal * _Thickness;
		}

		sampler2D _MainTex;
		half _Glossiness;
		half _Metallic;
		fixed4 _Color;

		void surf(Input IN, inout SurfaceOutputStandard o) {
			fixed4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;
			o.Albedo = c.rgb;
			o.Metallic = _Metallic;
			o.Smoothness = _Glossiness;
			o.Alpha = c.a;
		}
		ENDCG
	}
	FallBack "Diffuse"
}