寫在前面

    文章來源為http://blog.csdn.net/blinkseed
        大概已經有兩個星期沒寫文章了，中間又搞了幾個效果，但完全沒時間總結
        本人入行時間比較奇葩，本來新人都是一開始搞NGUI的，但我一開始就是搞實景，導致幾乎對NGUI沒了解，開始接觸介面時順水推舟就開始研究剛出生UGUI了。
        但NGUI依舊比較重要，在維護以前的Unity專案來說:-)

效果預覽

    NGUI自帶的透明shader效果：

    本文所教授的shader效果：

（高光在左上）

（高光在右上）

  原始碼說明

    原始碼的shader部分是由NGUI所提供的Unlit/Transparent Colored修改的，你可以看到幾乎一模一樣的頂點著色器

Shader "Custom/Rimlight" 
{
	Properties
	{
		_MainTex ("Base (RGB), Alpha (A)", 2D) = "black" {}
		_angle("angle" , Range(0, 1)) = 0 //高光角度
		_RimLightColor("Rim Light Color",Color) = (1,1,1,0)//高光顏色
	}
	
	SubShader
	{
		LOD 200

		Tags
		{
			"Queue" = "Transparent"
			"IgnoreProjector" = "True"
			"RenderType" = "Transparent"
		}
		
		Pass
		{
			Cull Off
			Lighting Off
			ZWrite Off
			Fog { Mode Off }
			Offset -1, -1
			Blend SrcAlpha OneMinusSrcAlpha

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag			
			#include "UnityCG.cginc"

			sampler2D _MainTex;
			float4 _MainTex_ST;
			half4 _MainTex_TexelSize;
	        fixed _angle;
	        half4 _RimLightColor;
			struct appdata_t
			{
				float4 vertex : POSITION;
				float2 texcoord : TEXCOORD0;
				fixed4 color : COLOR;
			};
	
			struct v2f
			{
				float4 vertex : SV_POSITION;
				half2 texcoord : TEXCOORD0;
				fixed4 color : COLOR;
			};
	
			v2f o;

			v2f vert (appdata_t v)
			{
				o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
				o.texcoord = v.texcoord;
				o.color = v.color;
				return o;
			}
				
			fixed4 frag (v2f IN) : COLOR
			{
			    fixed4 c = tex2D(_MainTex, IN.texcoord);
			    fixed2 TexOffset = _MainTex_TexelSize.xy;
			    c = c * IN.color;
			    //================遮罩部分============================
			    //座標運算轉為螢幕中心做二維座標原點
			    float2 uv = IN.texcoord - float2(0.5,0.5);
                // 遮罩角度
                _angle = 6.284*(_angle-0.5); 
                //反算出畫素點角度的Tan值
                float TanAngle = atan2(uv.y, uv.x);
                //角度與高光角度的差距
                float AngleDis = 1-saturate(abs(_angle - TanAngle));
                AngleDis += 1-saturate(abs(_angle - TanAngle-6.284));
                AngleDis += 1-saturate(abs(_angle - TanAngle+6.284));
                //尋找圖片的邊緣值，即alpha的邊緣
                fixed a0 = tex2D(_MainTex, IN.texcoord + TexOffset ).a;
                fixed a1 = tex2D(_MainTex, IN.texcoord + TexOffset * fixed2 ( 1 , -1 ) ).a;
                fixed a2 = tex2D(_MainTex, IN.texcoord + TexOffset * fixed2 ( -1 , 1 ) ).a;
                fixed a3 = tex2D(_MainTex, IN.texcoord + TexOffset * fixed2 ( -1 , -1 ) ).a;
                fixed finala = abs(c.a * 4 - ( a0 + a1 + a2 + a3 ));
                AngleDis *= finala;
                // 打高光
                c += fixed4(_RimLightColor.rgb*AngleDis, 0);
				return c;
			}
			ENDCG
		}
	}

	SubShader
	{
		LOD 100

		Tags
		{
			"Queue" = "Transparent"
			"IgnoreProjector" = "True"
			"RenderType" = "Transparent"
		}
		
		Pass
		{
			Cull Off
			Lighting Off
			ZWrite Off
			Fog { Mode Off }
			Offset -1, -1
			ColorMask RGB
			Blend SrcAlpha OneMinusSrcAlpha
			ColorMaterial AmbientAndDiffuse
			
			SetTexture [_MainTex]
			{
				Combine Texture * Primary
			}
		}
	}
}
 

using UnityEngine;
using System.Collections;

public class ControlAngle : MonoBehaviour {
	public Material mat;//帶有高光的材質球
	public float Rate = 0;//運轉速率
	float NextTime = 0;//下一次輪迴時間
	float angle;//運轉角度
	// Use this for initialization
	void Start () 
	{
	   
	}
	
	// Update is called once per frame
	void Update () 
	{
	   if (NextTime <= Time.time) 
	   {
			NextTime = Time.time + Rate;
			angle = 0;
	   } 
	   else 
	   {
			angle = (NextTime - Time.time)/Rate;
	   }
		mat.SetFloat ("_angle",angle);
	}
}