While迴圈

有時你可能需要進行這樣的操作：如果某個條件為true的話就一直停在那裡，直到它由true變成false才繼續執行（反過來也可以，開始為false，直到true才繼續）。你可以使用while迴圈來做到這一點。本例向你展示如何使用while迴圈來校準模擬訊號感測器。

在loop中，我們讀取A0口的值，來給9號引腳上的LED調光。 但是當2號引腳上的按鍵被按下時，程式就會去執行calibrate() 函式（函式名意思叫 校準，這是自己定義的函式）。calibrate()會尋找模擬訊號的最大、最小值。當你鬆開按鍵時，loop()中的其他程式碼才會繼續被執行。

本例所展示的技巧能夠讓你在環境光線發生明顯改變時進行人工校準。

完成本例所需的硬體裝置

• Arduino板或Genuino板
• 按鍵或開關
• 光敏電阻或其他模擬訊號感測器
• 2個10kΩ電阻
• 麵包板
• 連線線

電路連線

連線模擬訊號感測器（例如：光敏電阻） 到A2口，並且加一個10kΩ下拉電阻。連線按鍵到數字引腳，並且加一個10kΩ下拉電阻。LED和220Ω電阻串接後連線到9號引腳。

原理圖

例程程式碼

/*
 While迴圈

 本例向你展示while()的使用。

 當按鍵被按下時，工程將會啟動開始校準。
 while迴圈中獲得的感測器資料講被取最大、最小值，然後對光敏電阻進行校準。

 這是校準模擬訊號的另一個例子，之前也介紹過一種方法，不過這次重在演示while迴圈的使用。

 電路搭建:
 * 光敏電阻連線+5V 和A0口
 * 10kΩ電阻連線GND和A0口
 * LED與220Ω電阻串聯，並接到9號引腳
 * 按鍵連線到A2口和+5V
 * 10KΩ電阻連線到A2口到GND

 程式碼公開。
 */
 



// 常亮定義:
const int sensorPin = A2;       // 感測器引腳
const int ledPin = 9;           // LED引腳
const int indicatorLedPin = 13; // 板載LED引腳
const int buttonPin = 2;        // 按鍵引腳


// 變數:
int sensorMin = 1023;  // 感測器最小值
int sensorMax = 0;     // 感測器最大值
int sensorValue = 0;         // 感測器值


void setup() {
  // 將indicatorLedPin設定為OUTPUT模式:
 

  pinMode(indicatorLedPin, OUTPUT);
  pinMode(ledPin, OUTPUT);
  pinMode(buttonPin, INPUT);
}

void loop() {
  // 當按鍵被按下時進行校準:
  while (digitalRead(buttonPin) == HIGH) {
    calibrate();
  }
  // 關閉LED，標誌校準結束
  digitalWrite(indicatorLedPin, LOW);

  // 讀取感測器值:
  sensorValue = analogRead(sensorPin);

  // 運用最大、最小值來校準感測器值
  sensorValue = map(sensorValue, sensorMin, sensorMax, 0, 255);

  // 放置sensorValue超過上下限（正常最小0，最大255）
  sensorValue = constrain(sensorValue, 0, 255);

  // 使用sensorValue給LED調光:
  analogWrite(ledPin, sensorValue);
}

void calibrate() {
  // 將LED開啟，標示校準過程的開始:
  digitalWrite(indicatorLedPin, HIGH);
  // 讀取感測器值:
  sensorValue = analogRead(sensorPin);

  // 記錄最大值
  if (sensorValue > sensorMax) {
    sensorMax = sensorValue;
  }

  // 記錄最小值
  if (sensorValue < sensorMin) {
    sensorMin = sensorValue;
  }
}

相關資料

原文連結

更新程序

譯者：唐家勳
郵箱：[email protected]
QQ：649196486
轉載請註明出處，一切只因為熱愛。
希望您能指出寶貴意見，謝謝。