/*
分類變數分析之logistc（一），因變數為二分類變數
資料coronary中ca為二分類因變數，sex、ecg為二分類自變數，所有的二分類變數
用0、1進行區別，構成（0，1）矩陣
*/
data coronary;
   input sex ecg ca count @@;
   datalines;
0 0 0 11 0 0 1 4
0 1 0 10 0 1 1 8
1 0 0 9 1 0 1 9
1 1 0 6 1 1 1 21
;
*scale選項用於對過度離散資料校正； descending,應變數ca按降序排序，
 sas中按y=1的概率建模，即ordered value為1對應y的取值
 output語句設定輸出結果,這裡結果存在predict資料中，預測值為prob
;
proc logistic data=coronary descending;
   freq count;
   model ca=sex ecg / scale=none aggregate;
   output out=predict pred=prob;
run;
proc print data=predict;run;

*ods select:考慮交叉影響的引數估計剝離;
ods select FitStatistics ParameterEstimates;
proc logistic descending;
   freq count;
   model ca=sex ecg sex*ecg;
run;

*二、條件變數，class;
*sentence是二分類因變數，type、prior為二分類字元型自變數;
data sentence;
   input type $ prior $ sentence $ count @@;
   datalines;
nrb some y 42 nrb some n 109
nrb none y 17 nrb none n 75
other some y 33 other some n 175
other none y 53 other none n 359
;
*class：對分類變數進行0-1處理，
 ref= :設定參照水平，這裡ref=first表示some作為參照水平
 scale:指定離散引數估算方法，校正離散情況，給出“偏差和 Pearson 擬合優度統計量” 
 aggregate:設定皮爾遜卡方檢驗統計量
;
proc logistic data=sentence descending;
   class type prior(ref=first) / param=ref;
   freq count;
   model sentence = type prior / scale=none aggregate;
run;
*擬合優度剝離;
ods select GoodnessOfFit;
proc logistic descending;
   class type prior (ref=first) / param=ref;
   freq count;
   model sentence = type / scale=none aggregate=(type prior);
run;
*從sas結果中剝離分類水平、擬合優度、引數估計、似然比情況,單獨顯示;
ods select ClassLevelInfo GoodnessOfFit 
           ParameterEstimates OddsRatios;
proc logistic data=sentence descending;
   class type prior(ref='none');
   freq count;
   model sentence = type prior / scale=none aggregate;
run;

*三、自變數是定性變數;
data uti;
   input diagnosis : $13. treatment $ response $ count @@;
   datalines;
complicated A cured 78 complicated A not 28
complicated B cured 101 complicated B not 11
complicated C cured 68 complicated C not 46
uncomplicated A cured 40 uncomplicated A not 5
uncomplicated B cured 54 uncomplicated B not 5
uncomplicated C cured 34 uncomplicated C not 6
;
run;
ods select FitStatistics;
proc logistic;
   freq count;
   class diagnosis treatment /param=ref;
   model response = diagnosis|treatment;
run;

ods select FitStatistics GoodnessOfFit
           TypeIII OddsRatios;
proc logistic;
   freq count;
   class diagnosis treatment;
   model response = diagnosis treatment /
   scale=none aggregate;
run;

*clodds：計算似然比的置信區間
 clparm: 計算引數的置信區間
;
ods select ClparmPL CloddsPL;
proc logistic;
   freq count;
   class diagnosis treatment;
   model response = diagnosis treatment /
   scale=none aggregate clodds=pl clparm=pl;
run;

*contrast:定製假設檢驗的方式，變數需要是矩陣形式
;
ods select ContrastTest ContrastEstimate;
proc logistic;
   freq count;
   class diagnosis treatment /param=ref;
   model response = diagnosis treatment;
   contrast 'B versus A' treatment -1 1
            / estimate=exp;
   contrast 'A' treatment 1 0;
   contrast 'joint test' treatment 1 0,
                         treatment 0 1;
run;

*四、自變數連續有序的情況;
data coronary;
   input sex ecg age ca @@ ;
   datalines;
0 0 28 0 1 0 42 1 0 1 46 0 1 1 45 0
0 0 34 0 1 0 44 1 0 1 48 1 1 1 45 1
0 0 38 0 1 0 45 0 0 1 49 0 1 1 45 1
0 0 41 1 1 0 46 0 0 1 49 0 1 1 46 1
0 0 44 0 1 0 48 0 0 1 52 0 1 1 48 1
0 0 45 1 1 0 50 0 0 1 53 1 1 1 57 1
0 0 46 0 1 0 52 1 0 1 54 1 1 1 57 1
0 0 47 0 1 0 52 1 0 1 55 0 1 1 59 1
0 0 50 0 1 0 54 0 0 1 57 1 1 1 60 1
0 0 51 0 1 0 55 0 0 2 46 1 1 1 63 1
0 0 51 0 1 0 59 1 0 2 48 0 1 2 35 0
0 0 53 0 1 0 59 1 0 2 57 1 1 2 37 1
0 0 55 1 1 1 32 0 0 2 60 1 1 2 43 1
0 0 59 0 1 1 37 0 1 0 30 0 1 2 47 1
0 0 60 1 1 1 38 1 1 0 34 0 1 2 48 1
0 1 32 1 1 1 38 1 1 0 36 1 1 2 49 0
0 1 33 0 1 1 42 1 1 0 38 1 1 2 58 1
0 1 35 0 1 1 43 0 1 0 39 0 1 2 59 1
0 1 39 0 1 1 43 1 1 0 42 0 1 2 60 1
0 1 40 0 1 1 44 1
;
run;
*擬合logistic模型
 selection用於選擇逐步迴歸方法,包括forward,backward,stepwise
 include:設定每個擬合模型中包含model語句中列的因子的個數
 units :可以設定想要計算的似然比odds ratios
;
proc logistic data=coronary descending;
   model ca=sex ecg age ecg*ecg age*age
         sex*ecg sex*age ecg*age /
         selection=forward include=3 details lackfit;
run;
proc logistic descending;
   model ca=sex ecg age;
   units age=10;
run;

*五、logistic迴歸診斷;
data uti2;
   input diagnosis : $13. treatment $ response trials;
   datalines;
complicated A 78 106
complicated B 101 112
complicated C 68 114
uncomplicated A 40 45
uncomplicated B 54 59
uncomplicated C 34 40
;
*INFLUENCE診斷;
proc logistic data=uti2;
   class diagnosis treatment / param=ref;
   model response/trials = diagnosis treatment/influence;
run;
proc logistic data=uti2;
   class diagnosis treatment / param=ref;
   model response/trials = diagnosis/scale=none 
                                     aggregate=(treatment diagnosis) 
                                     influence 
                                     iplots;
run;

*精確logistic迴歸方法,exact;
data liver;
   input time $ group $ status $ count @@;
   datalines;
early antidote severe 6 early antidote not 12
early control severe 6 early control not 2
delayed antidote severe 3 delayed antidote not 4
delayed control severe 3 delayed control not 0
late antidote severe 5 late antidote not 1
late control severe 6 late control not 0
;
*estimate=both,表示對第一個exact語句中指定的變數進行精確點估計
 joint,表示對第二個exact中time、group進行聯合檢驗
;
proc logistic descending;
   freq count;
   class time(ref='early') group(ref='control') /param=ref;
   model status = time group / scale=none aggregate clparm=wald;
   exact 'Model 1' intercept time group / estimate=both;
   exact 'Joint Test' time group / joint;
run;